Tinkered with your code a bit and came up with the below which does the same as yours with less script.

menu * {
  .Color Talker: dialog $iif(!$dialog(ctalker),-m,-va) ctalker ctalker
}
dialog ctalker {
  title "-=Pwnisher3's Color Talker=-"
  size -1 -1 140 62
  option dbu
  text "Color Talker Made By Pwnisher3. the combo box on the right is your Main text color, the combo box on the left is for your Background color. ", 1, 2 2 135 21, center
  button "Set Color Talker", 2, 2 38 135 10
  check "Bold", 3, 4 50 22 10
  check "Underline", 4, 31 50 33 10
  combo 5, 69 50 25 125, size drop
  text ",", 6, 97 51 13 8, center
  combo 7, 112 50 25 125, size drop
  button "Disable All Colors", 8, 2 26 135 10
}
on *:dialog:ctalker:sclick:8:{ unset %ctklr }
on *:dialog:ctalker:sclick:2:{
  set %ctklr $+($iif($did(3).state == 1,$chr(2)),$iif($did(4).state == 1,$chr(31)),$+($chr(3),$did(5),$chr(44),$did(7)))
  dialog -x ctalker ctalker
}
on *:dialog:ctalker:init:*:{
  unset %ctklr
  did -ca ctalker 7 00
  did -a ctalker 5 00
  did -ca ctalker 5 01
  did -a ctalker 7 01
  didtok $dname 5,7 44 02,03,04,05,06,07,08,09,10,11,12,13,14,15
}
on *:INPUT:*: { 
  if ($istok(/ ,$left($1,1),32)) || ($ctrlenter) || ($inpaste) return
  elseif ($istok(NickServ ChanServ HostServ BotServ HelpServ OperServ,$target,32)) return
  elseif ($istok(off talkerat $null,%ctklr,32)) return
  else say %ctklr $+ $1-
  haltdef
}