;Image Viewer Script
;Made by nick1
;Last edit March 17 2013

When someone puts an image link in the chat it will open it an mIRC window instead of a browser tab.

Directions: Copy entire code into new remote file. Click on a link to an image and it will open up in a window instead of a browser tab.

Feedback (i.e. comments, questions, concerns, suggestions, jokes, etc.) greatly appreciated.

;Image Viewer Script
;Made by nick1
;Last edit March 17 2013

on $^*:hotlink:/((?:(?:(?:https?)\72\/\/)|(?:www)\.)\S+)(?:(?:jpg|gif|jpeg|png)|(?<=puu\.sh\/)|(?<=my\.jetscreenshot\.com\/)|(?<=imgur\.com\/)(?:\w+))/Sig:*:{
  if ($hotlink(event) == sclick) && (!$sock(getpic)) {
    set %getpic $remove($1,http://,https://)
    ;special link replacement (below) will only work if filetype is JPG
    if ((*puu.sh* iswm %getpic) && (*.* !iswm $remove(%getpic,u.sh))) {
      set %getpic %getpic $+ .jpg
    }
    if ((*imgur.com* iswm %getpic) && (*.* !iswm $remove(%getpic,r.co))) {
      set %getpic $replace($remove(%getpic,/gallery),imgur.com,i.imgur.com) $+ .jpg
    }
    if ((*my.jetscreenshot.com/* iswm %getpic) && (*.* !iswm $remove(%getpic,t.co,y.je))) {
      set %getpic %getpic $+ .jpg
    }
    if (!$file($qt($getdir $+ $gettok(%getpic,-1,47)))) {
      sockopen GetPic $gettok(%getpic,1,47) 80
    }
  }
}
On *:sockopen:getpic:{
  sockwrite -nt $sockname GET $+(/,$gettok(%getpic,2-,47)) HTTP/1.1
  sockwrite -nt $sockname Host: $sock(getpic).addr
  sockwrite -nt $sockname
}
on *:sockread:getpic:{
  if ($sockerr) return
  if (!$sock($sockname).mark) {
    var %SockReader
    sockread %SockReader
    if (%SockReader == $null) { 
      sockmark $sockname 1
      .timerclose $+ $sockname -m 1 3300 imagetimeout
    }
  }
  else {
    sockread -f &picture
    .bwrite $qt($getdir $+ $gettok(%getpic,-1,47)) -1 -1 &picture
  }
}
alias imagetimeout {
  sockclose getpic
  showpic
}
on *:sockclose:getpic: {
  .timerclose $+ $sockname off
  showpic
}
Alias ShowPic {
  var %file $qt($getdir $+ $gettok(%getpic,-1,47))
  var %w $pic(%file).width
  var %h $pic(%file).height
  if (%w == 0) {
    .remove %file
    halt
  }
  else {
    var %win $+(@,$gettok(%getpic,-1,47),-,$chr(40),%w,x,%h,$chr(41))
    window -dCpk0 %win -1 -1 $calc(%w + 17) $calc(%h + 34)
    .timer $+ $gettok(%file,$numtok(%file,32),32) 1 120 .remove %file
    drawpic %win -1 -1 %file
  }
  unset %getpic
}