; Dropbox Screen Shot Uploader
;Uses mirc_ss.dll and dropbox
;Logs each image url in a hash file
;You must have a dropbox account and Dropbox installed and running. As well the dll for this addon to work!!!
;Link to get the dll https://dl.dropbox.com/u/6355058/mIRC-Stuff/mirc_ss.zip

; Dropbox Screen Shot Uploader
;Uses mirc_ss.dll and dropbox
;Logs each image url in a hash file
;You must have a dropbox account and Dropbox installed and running. As well the dll for this addon to work!!!
;Link to get the dll https://dl.dropbox.com/u/6355058/mIRC-Stuff/mirc_ss.zip

on *:start: { 
  hmake db 300
  if ($exists(dropbox.dat)) { hload db dropbox.dat }
}

;F Key change number to what you wish to use. 
alias F8 { screenshot msg }

alias screenshot {
  if (!$hget(db,ID)) { hadd db ID $$?="Please enter your dropbox id ie(6355058):" }
  if (!$hget(db,filepath)) { hadd db filepath $sdir(c:\,Please select a public dropbox folder to save screen shots) }
  $iif($1,$1,echo) $active Taking screenshot, Please hold.
  var %i $+(ss_,$asctime(mmddhhnnsstt),.jpg) , %f $hget(db,filepath) 
  if ($regex(%f,/.*\\Dropbox\\Public\\(.+)?(\\)/i)) { var %d $regml(1) }
  if (!%d) { var %d screenshots , %f = %f $+ %d }
  if (!$isdir(%f)) { mkdir %f }
  var %url $+(https://dl.dropbox.com/u/,$hget(db,ID),/,%d,/,%i)
  hadd db %i %url | hsave db dropbox.dat
  .timer 1 3 dll $findfile($mircdir,mirc_ss.dll,1) takess 099 $+(%f,\,%i)
  .timer 1 5 $iif($1,$1,echo) $active Screenshot taken you can view it here %url
}

menu status,channel,menubar, {
  -
 Dropbox Screen Shot Uploader
  .Update Account ID ( $hget(db,ID) ): hadd db ID $$?="Please enter your dropbox id ie(6355058):"
  .Update File Path: hadd db filepath $sdir(c:\,Please select a public dropbox folder to save screen shots)
  .-
  .Take Screenshot: { var %i $?!="Do you want to msg the url to the room?" |  screenshot $iif(%i == $True,msg) }
  -
}