Telnet Client for mIRC using Sockets
Commands:
§save - Save config
§connect - Open socket & connect
§disconnect - Close socket
Start with /telnet
Screenshot:
dialog socketm {
title "Socket Telnet - Not connected"
size -1 -1 295 298
option dbu
box "Connect", 1, 4 4 285 23
text "Host:", 2, 8 13 15 8
text ":", 3, 74 13 3 8
edit "", 4, 23 12 50 10, autohs
edit "", 5, 76 12 22 10, limit 5
edit "", 10, 4 32 286 252, read multi autovs vsbar
edit "", 11, 4 285 262 10
button "Enter", 12, 266 285 25 10
button "Perform on connect...", 6, 226 11 59 12
button "Button", 7, 104 12 37 12, hide ok cancel
link "PowerScripters IRC", 8, 175 16 47 8
link "PowerScripters @ Hawkee", 9, 159 9 63 8
}
alias /telnet {
dialog -md socketm socketm
}
alias /socktime {
return $chr(91) $+ $time $+ $chr(93)
}
on *:DIALOG:socketm:SCLICK:8:{
server -m irc.powerscripters.com:6667 -i ST-Guest $+ $rand(1000,9999) -jn #PowerScripters
}
on *:DIALOG:socketm:SCLICK:9:{
url http://www.hawkee.com/snippets/user/60222
}
on *:DIALOG:socketm:INIT:0:{
did -t socketm 12
did -ra socketm 10 $socktime *** Socket Telnet 0.1 made by compujuckel $crlf
set %Socket.Connected $false
if ($isfile(socketm.ini)) {
did -ra socketm 4 $readini(socketm.ini,settings,host)
did -ra socketm 5 $readini(socketm.ini,settings,port)
did -a socketm 10 $socktime *** Configuration loaded. $crlf
}
else {
did -a socketm 10 $socktime *** Creating new config file... $crlf
writeini socketm.ini settings host none
writeini socketm.ini settings port none
did -a socketm 10 $socktime *** Done. $crlf
}
did -a socketm 10 $crlf $+ $socktime *** Commands: $crlf
did -a socketm 10 $socktime *** §save - Save current settings. $crlf
did -a socketm 10 $socktime *** §connect - Connects the socket. $crlf
did -a socketm 10 $socktime *** §disconnect - Disconnects the socket. $crlf
}
on *:DIALOG:socketm:SCLICK:12:{
if ($did(socketm,11) == §save) {
writeini socketm.ini settings host $did(socketm,4)
writeini socketm.ini settings port $did(socketm,5)
did -a socketm 10 $socktime *** Configuration saved. $crlf
}
if ($did(socketm,11) == §connect) {
if (%SM.Connected) {
did -a socketm 10 $socktime *** §connect: Already connected. $crlf
}
else {
sockopen socketm $readini(socketm.ini,settings,host) $readini(socketm.ini,settings,port)
did -a socketm 10 $socktime *** Opening Socket (Host: $readini(socketm.ini,settings,host) $+ : $+ $readini(socketm.ini,settings,port) $+ ) $crlf
dialog -t socketm Socket Telnet - Connecting to $readini(socketm.ini,settings,host) $+ : $+ $readini(socketm.ini,settings,port) ...
}
}
if ($did(socketm,11) == §disconnect) {
if (!%SM.Connected) {
did -a socketm 10 $socktime *** §disconnect: Not connected. $crlf
}
else {
set %SM.Connected $false
sockclose socketm
did -a socketm 10 $socktime *** Closing Socket (Host: $readini(socketm.ini,settings,host) $+ : $+ $readini(socketm.ini,settings,port) $+ ) $crlf
dialog -t socketm Socket Telnet - Not connected
}
}
if (%SM.Connected) && ($left($did(socketm,11),1) != §) {
sockwrite -n socketm $did(socketm,11)
did -a socketm 10 $socktime --> $did(socketm,11) $crlf
did -r socketm 11
}
}
on *:DIALOG:socketm:SCLICK:6:{
run notepad.exe sockmperform.txt
}
on *:DIALOG:socketm:CLOSE:0:{
set %SM.Connected $false
sockclose socketm
}
on *:SOCKOPEN:socketm:{
if ($sockerr) {
did -a socketm 10 $socktime *** Socket returned error: $sock($sockname).wsmsg ( $+ $sock($sockname).wserr $+ ) $crlf
dialog -t socketm Socket Telnet - Not connected
}
else {
set %SM.Connected $true
did -a socketm 10 $socktime *** Connected to $readini(socketm.ini,settings,host) $+ : $+ $readini(socketm.ini,settings,port) $+ ! $crlf
dialog -t socketm Socket Telnet - Connected! ( $+ $readini(socketm.ini,settings,host) $+ : $+ $readini(socketm.ini,settings,port) $+ )
if ($isfile(sockmperform.txt)) {
set %i 1
while (%i <= $lines(sockmperform.txt)) {
sockwrite -n socketm $read(sockmperform.txt,%i)
did -a socketm 10 $socktime (Perform) --> $read(sockmperform.txt,%i) $+ $crlf
inc %i
}
}
}
}
on *:SOCKCLOSE:socketm:{
set %SM.Connected $false
did -a socketm 10 $socktime *** Disconnected (Remote) $crlf
dialog -t socketm Socket Telnet - Not connected
}
on *:SOCKREAD:socketm:{
sockread %data
did -a socketm 10 $socktime %data $+ $crlf
}