mBNC is a BNC i made in mIRC first version, so I'm sure there will be bugs... If you guys find any report them here, or at the site: http://mbnc.zzl.org/ (Just set it up today so like no ones there, would be nice to get a small community tho :D xP)

Current features:
(My favorite) Spaces are preserved!
Multiple clients can connect the bnc at the same time
Stays connected even when all clients have disconnected
Scripting Support!

Doesn't have multiple users/networks/servers yet...
load it into a new remote file (alt+r then File>New) After you add it to your remotes you either restart mIRC or type /bnc.start then it will ask you some questions, and you fill in the answers. I'll give you an example:

It's gonna ask you for a nick, ident, full name, server, server port, port to listen on, and a delay in trying to reconnect.

Bob is Steve@this.is.a.hostmask.com * Bill
Bob is the nick mBNC uses (obviously)
Steve is the ident mBNC uses
Bill is the full name mBNC uses

the server port is what mBNC uses to connect to the server (6667 for example)
the listening port is what you use to connect to it

To connect to it type /server
So if your ip is 1.2.3.4.5 and the port to listen on is 12345 the command would be
/server 1.2.3.4.5 12345

Visit the site for details on scripting for it.
Please feel free to post bugs/comments/suggestions/questions/etc either here or at the site :>

Enjoy!

Edit: fixed a minor bug issue

on *:start: {
  bnc.start
}
on *:sockopen:bnc.server: {
  if ($sockerr) { if ($sock(bnc.client*)) { sockwrite -nt bnc.client* :~mBNC PRIVMSG CLIENT :Error trying to connect to server, trying again in $readini(mBNC.ini,settings,delay) seconds... } | bnc.serverclose }
  if (!$sockerr) { bnc.serverinit }
}
on *:sockclose:bnc.*: {
  if (bnc.server == $sockname) { bnc.serverclose }
}
on *:socklisten:bnc.listen: {
  hinc bnc clientnumber
  sockaccept bnc.client $+ $hget(bnc,clientnumber)
  .timerbnc.client $+ $hget(bnc,clientnumber) 1 10 sockwrite -nt bnc.client $+ $hget(bnc,clientnumber) :~mBNC NOTICE CLIENT :You havn't supplied a nick yet, try /NICK <your nick>
}
on *:sockread:bnc.*: {
  if ($sockname == bnc.server) { sockread &bnc.server | bnc.sendclient }
  if (bnc.client* iswm $sockname) { sockread &bnc.client | bnc.sendserver }
}
alias bnc.start {
  if (!$readini(mBNC.ini,settings,nick)) { writeini mBNC.ini settings nick $input(What nick to you want mBNC to use?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,ident)) { writeini mBNC.ini settings ident $input(What ident to you want mBNC to use?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,fullname)) { writeini mBNC.ini settings fullname $input(What full name to you want mBNC to use?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,server)) { writeini mBNC.ini settings server $input(What server to you want mBNC to connect to?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,serverport)) { writeini mBNC.ini settings serverport $input(What port to you want mBNC to connect on?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,port)) { writeini mBNC.ini settings port $input(What port to you want mBNC to listen on?,eoqd,mBNC) }
  if (!$readini(mBNC.ini,settings,delay)) { writeini mBNC.ini settings delay $input(How long (in seconds) do you want mBNC to wait before trying to reconnect?,eoqd,mBNC) }
  if ($hget(bnc)) { hfree bnc }
  hfree -w bnc-*
  sockclose bnc.*
  hmake bnc 1000
  hadd bnc port $readini(mBNC.ini,settings,port)
  hadd bnc clientnumber 0
  hadd bnc chancount 1
  socklisten bnc.listen $hget(bnc,port)
  sockopen bnc.server $readini(mBNC.ini,settings,server) $readini(mBNC.ini,settings,serverport)
}
alias bnc.serverinit {
  if ($sock(bnc.server)) { sockwrite -nt bnc.server NICK $readini(mBNC.ini,settings,nick) $crlf USER $readini(mBNC.ini,settings,ident) " $+ $readini(mBNC.ini,settings,ident) $+ " " $+ $readini(mBNC.ini,settings,server) $+ " : $+ $readini(mBNC.ini,settings,fullname) } 
  .timerbnc.timeoutcheck 0 5 bnc.timeoutcheck
}
alias bnc.timeoutcheck {
  if (!$sock(bnc.server)) { .timerbnc.timeoutcheck off | bnc.serverclose }
}
alias bnc.serverclose {
  .timerbnc.pingserver off
  .timerbnc.timeoutcheck off
  sockclose bnc.server
  hdel -w bnc motd*
  hfree -w bnc-*
  hadd bnc chancount 1
  hdel bnc connect
  hdel bnc me
  hdel bnc umode
  if ($sock(bnc.client*)) { sockwrite -nt bnc.client* :~mBNC PRIVMSG * :Disconnected from server. Attempting to reconnect in $readini(mBNC.ini,settings,delay) seconds... }
  .timer 1 $readini(mBNC.ini,settings,delay) sockopen bnc.server $readini(mBNC.ini,settings,server) $readini(mBNC.ini,settings,serverport)
  .timer 1 $readini(mBNC.ini,settings,delay) if ($sock(bnc.client*)) { sockwrite -nt bnc.client* :~mBNC PRIVMSG * :Connecting to $readini(mBNC.ini,settings,server) on port $readini(mBNC.ini,settings,serverport) $+ ... }
}
alias bnc.clientopen {
  .timer $+ $1 off
  sockwrite -nt $1 :~mBNC NOTICE CLIENT :Welcome to mBNC $sock($1).mark $+ ! If you have any errors please report them to http://mbnc.zzl.org/ thanks.
  if ($hfind(bnc,motd*,0,w) != 0) {
    hadd bnc count 1
    while ($hfind(bnc,motd*,0,w) >= $hget(bnc,count)) {
      bset &bnc.server 1 $hget(bnc,motd $+ $hget(bnc,count))
      sockwrite $1 &bnc.server 
      sockwrite -t $1 $chr(13)
      hinc bnc count
      bunset &bnc.server
    }
    sockwrite -nt $1 $chr(10)
    sockwrite -nt $1 : $+ $hget(bnc,nick) NICK $hget(bnc,me)
    if ($hget(bnc,umode)) && ($hget(bnc,umode) != :+) { sockwrite -nt $1 : $+ $hget(bnc,me) MODE $hget(bnc,me) $hget(bnc,umode) }
    hadd bnc count 1
    while ($hget(bnc,count) <= $hget(0)) {
      if (bnc-* iswm $hget($hget(bnc,count))) {
        hadd bnc count2 1
        if ($gettok($hget($hget(bnc,count),topic),3-,32)) { bset &bnc.server 1 $gettok($hget($hget(bnc,count),topic),3-,32) }
        sockwrite -nt $1 : $+ $hget(bnc,me) JOIN :# $+ $gettok($gettok($hget($hget(bnc,count)),2,45),2,35)
        if ($gettok($hget($hget(bnc,count),topic),1-,32)) {
          bunset &bnc.temp
          bset -t &bnc.temp 1 $gettok($hget($hget(bnc,count),topic),1,32) 332 $hget(bnc,me) $chr(35) $+ $gettok($gettok($hget($hget(bnc,count)),2,45),2,35)
          bset &bnc.temp 1 $bvar(&bnc.temp,1-) 32 $gettok($hget($hget(bnc,count),topic),4-,32) 13 10
          sockwrite $1 &bnc.temp
          sockwrite -nt $1 $gettok($hget($hget(bnc,count),topic),1,32) 333 $hget(bnc,me) $chr(35) $+ $gettok($gettok($hget($hget(bnc,count)),2,45),2,35) $gettok($hget($hget(bnc,count),topic),2-3,32)
        }
        hadd bnc count3 1
        while ($hfind($hget(bnc,count),names-*,0,w) >= $hget(bnc,count3)) {
          sockwrite -nt $1 $hget(bnc,server) 353 $hget(bnc,me) = $chr(35) $+ $gettok($gettok($hget($hget(bnc,count)),2,45),2,35) : $+ $hget($hget(bnc,count),$hfind($hget(bnc,count),names-*,$hget(bnc,count3),w)) $+ $gettok($hfind($hget(bnc,count),names-*,$hget(bnc,count3),w),2-,45)
          hinc bnc count3
        }
        sockwrite -nt $1 $hget(bnc,server) 366 $hget(bnc,me) $chr(35) $+ $gettok($gettok($hget($hget(bnc,count)),2,45),2,35) :End of /NAMES list.
        hinc bnc count2
      }
      hinc bnc count
    }
  }
}
alias bnc.sendclient {
  hadd bnc count 1
  if (!$hget(bnc,motd1)) { hadd bnc count2 1 }
  while ($bvar(&bnc.server,0) >= $hget(bnc,count)) {
    :top
    if ($bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { tokenize 32 $remove($bvar(&bnc.server,$hget(bnc,count) $+ - $+ $bfind(&bnc.server,$calc($hget(bnc,count) +1),13)).text,$chr(13),$chr(10)) }
    if (!$bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { tokenize 32 $remove($bvar(&bnc.server,$hget(bnc,count) $+ -).text,$chr(13),$chr(10)) }
    .signal -n bnc.server $1-
    if ($2 isnum) && ($3 != *) { if ($sock(bnc.client*)) && ($len($2) == 3) && ($hget(bnc,me) !=== $3) && ($hget(bnc,me)) { sockwrite -nt bnc.client* : $+ $hget(bnc,me) NICK $3 } | hadd bnc me $3 }
    if ($2 === NICK) && ($right($gettok($1,1,33),-1) == $hget(bnc,me)) { hadd bnc me $right($3,-1) }
    if ($2 == 433) && ($3 == *) { sockwrite -nt bnc.server NICK _ $+ $4 | bnc.halt }
    if ($1 == PING) { sockwrite -nt bnc.server PONG $2- | bnc.halt }
    if ($hget(bnc,connect) != connected) && ($2 != NOTICE && $1 != NOTICE) && ($1 != PING) && ($2 != 433) {
      if ($2 == 001) { hadd bnc server $1 | hadd bnc nick $3 }
      if (!$hget(bnc,count2)) { hadd bnc count2 1 }
      if ($bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd bnc motd $+ $hget(bnc,count2) $hget(bnc,motd) $bvar(&bnc.server,$hget(bnc,count) $+ - $+ $bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) } 
      if (!$bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd bnc motd $+ $hget(bnc,count2) $hget(bnc,motd) $bvar(&bnc.server,$hget(bnc,count) $+ -) }
      hinc bnc count2
      if ($2 == 376) { hadd bnc connect connected | hdel bnc count2 | if ($sock(bnc.client*)) { sockwrite -nt bnc.client* $chr(10) $+ :~mBNC PRIVMSG CLIENT :Connected! } }
    }
    if ($gettok($remove($1,:),1,33) == $hget(bnc,me)) && ($3 == $hget(bnc,me)) && ($2 == MODE) {
      hadd bnc count3 1
      while ($hget(bnc,count3) <= $len($remove($4,:))) {
        if ($mid($remove($4,:),$hget(bnc,count3),1) == +) { hadd bnc temp + }
        if ($mid($remove($4,:),$hget(bnc,count3),1) == -) { hadd bnc temp - }
        if ($mid($remove($4,:),$hget(bnc,count3),1) != +) && ($mid($remove($4,:),$hget(bnc,count3),1) != -) {
          if ($hget(bnc,temp) == +) { hadd bnc umode $iif($hget(bnc,umode),$hget(bnc,umode),:+) $+ $mid($remove($4,:),$hget(bnc,count3),1) }
          if ($hget(bnc,temp) == -) { hadd bnc umode $removecs($hget(bnc,umode),$mid($remove($4,:),$hget(bnc,count3),1)) }
        }
        hinc bnc count3
      }
      hdel bnc temp
    }
    if ($remove($gettok($1,1,33),:) $2 == $hget(bnc,me) JOIN) && (!$bnc.chan($right($3,-1))) { hmake bnc- $+ $hget(bnc,chancount) $+ $right($3,-1) 100 | sockwrite -nt bnc.server MODE $right($3,-1) | hinc bnc chancount }
    if ($remove($gettok($1,1,33),:) $2 == $hget(bnc,me) PART) && ($bnc.chan($3)) { hfree $bnc.chan($3) }
    if ($remove($gettok($1,1,33),:) !== $hget(bnc,me)) && ($2 == join) && ($bnc.chan($right($3,-1))) { hadd $bnc.chan($right($3,-1)) names- $+ $remove($gettok($1,1,33),:) }
    if ($remove($gettok($1,1,33),:) !== $hget(bnc,me)) && ($2 == part) && ($bnc.chan($3)) { hdel $bnc.chan($3) names- $+ $remove($gettok($1,1,33),:) }
    if ($remove($gettok($1,1,33),:) !== $hget(bnc,me)) && ($2 == quit) {
      hadd bnc count2 1
      while ($hget(bnc,count2) <= $hget(0)) {
        if (bnc-* iswm $hget($hget(bnc,count2))) {
          if ($hfind($hget(bnc,count2),names- $+ $remove($gettok($1,1,33),:))) { hdel $hget($hget(bnc,count2)) names- $+ $remove($gettok($1,1,33),:) }
        }
        hinc bnc count2
      }
    }
    if ($2 == 353) && ($bnc.chan($5)) { 
      hadd bnc count3 1
      while ($hget(bnc,count3) <= $gettok($6-,0,32)) {
        if ($hget($bnc.chan($5),names)) { hdel -w $bnc.chan($5) names* }
        hadd $bnc.chan($5) names- $+ $remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),~,@,&,%,+,:)
        if ($remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),:,$remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),~,@,&,%,+,:))) { hadd $bnc.chan($5) names- $+ $remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),~,@,&,%,+,:) $remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),:,$remove($gettok($gettok($6-,$hget(bnc,count3),32),1,33),~,@,&,%,+,:)) }
        hinc bnc count3
      }
    }
    if ($2 == 366) && ($bnc.chan($4)) { hadd $bnc.chan($4) names End }
    if ($2 == TOPIC) && ($bnc.chan($3)) { bset &bnc.server2 1 $hget(bnc,motd1) | if ($bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd $bnc.chan($3) topic $gettok($bvar(&bnc.server2,1-).text,1,32) $right($1,-1) $ctime $remove($right($bvar(&bnc.server,$bfind(&bnc.server,$hget(bnc,count),32 58) $+ - $+ $bfind(&bnc.server,$calc($hget(bnc,count) +1),13)),-3),$chr(13),$chr(10)) } | if (!$bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd $bnc.chan($3) topic $gettok($bvar(&bnc.server2,1-).text,1,32) $right($1,-1) $ctime $remove($right($bvar(&bnc.server,$bfind(&bnc.server,$hget(bnc,count),32 58) $+ -),-3),$chr(13),$chr(10)) } }
    if ($2 == 332) && ($bnc.chan($4)) { if ($bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd $bnc.chan($4) topic $remove($right($bvar(&bnc.server,$bfind(&bnc.server,$hget(bnc,count),32 58) $+ - $+ $bfind(&bnc.server,$calc($hget(bnc,count) +1),13)),-3),$chr(13),$chr(10)) } | if (!$bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd $bnc.chan($4) topic $remove($right($bvar(&bnc.server,$bfind(&bnc.server,$hget(bnc,count),32 58) $+ -),-3),$chr(13),$chr(10)) } }
    if ($2 == 333) && ($bnc.chan($4)) { hadd $bnc.chan($4) topic $1 $5- $hget($bnc.chan($4),topic) }
    if ($2 == MODE) && ($bnc.chan($3)) {
      hadd bnc count3 1
      while ($hget(bnc,count3) <= $len($4)) {
        if ($mid($4,$hget(bnc,count3),1) == +) { hadd bnc temp + }
        if ($mid($4,$hget(bnc,count3),1) == -) { hadd bnc temp - }
        if ($mid($4,$hget(bnc,count3),1) != +) && ($mid($4,$hget(bnc,count3),1) != -) && ($mid($4,$hget(bnc,count3),1) != q) && ($mid($4,$hget(bnc,count3),1) != a) && ($mid($4,$hget(bnc,count3),1) != o) && ($mid($4,$hget(bnc,count3),1) != h) && ($mid($4,$hget(bnc,count3),1) != v) {
          if ($hget(bnc,temp) == +) { hadd $bnc.chan($3) mode $iif($hget($bnc.chan($3),mode),$hget($bnc.chan($3),mode),+) $+ $mid($4,$hget(bnc,count3),1) }
          if ($hget(bnc,temp) == -) { hadd $bnc.chan($3) mode $removecs($hget($bnc.chan($3),mode),$mid($4,$hget(bnc,count3),1)) }
        }
        if ($mid($4,$hget(bnc,count3),1) == q) || ($mid($4,$hget(bnc,count3),1) == a) || ($mid($4,$hget(bnc,count3),1) == o) || ($mid($4,$hget(bnc,count3),1) == h) || ($mid($4,$hget(bnc,count3),1) == v) {
          if (!$hget(bnc,count4)) { hadd bnc count4 4 }
          if ($hget(bnc,temp) == +) && ($replace($mid($4,$hget(bnc,count3),1),q,~,a,&,o,@,h,%,v,+) !isin $hget($bnc.chan($3),names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2))) { hadd $bnc.chan($3) names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2) $iif($hget($bnc.chan($3),names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2)),$hget($bnc.chan($3),names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2))) $+ $replace($mid($4,$hget(bnc,count3),1),q,~,a,&,o,@,h,%,v,+) }
          if ($hget(bnc,temp) == -) { hadd $bnc.chan($3) names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2) $removecs($hget($bnc.chan($3),names- $+ $eval($eval($,0) $+ $calc($hget(bnc,count4) +1),2)),$replace($mid($4,$hget(bnc,count3),1),q,~,a,&,o,@,h,%,v,+)) }
          hinc bnc count4
        }
        hinc bnc count3
      }
      hdel bnc temp
      hdel bnc count4
    }
    if ($2 == 324) && ($bnc.chan($4)) { hadd $bnc.chan($4) mode $5 }
    if ($2 == 329) && ($bnc.chan($4)) { hadd $bnc.chan($4) modetime $5 }
    if ($sock(bnc.client*)) { if ($hget(bnc,halt)) { hdel bnc halt | goto end } | bset &bnc.line 1 $iif($bfind(&bnc.server,$calc($hget(bnc,count) +1),13),$bvar(&bnc.server,$hget(bnc,count) $+ - $+ $bfind(&bnc.server,$calc($hget(bnc,count) +1),13)),$bvar(&bnc.server,$hget(bnc,count) $+ -)) | sockwrite bnc.client* &bnc.line | bunset &bnc.line }
    :end
    if ($bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) { hadd bnc count $bfind(&bnc.server,$calc($hget(bnc,count) +1),13) }
    if (!$bfind(&bnc.server,$calc($hget(bnc,count) +1),13)) && ($bvar(&bnc.server,0) >= $calc($hget(bnc,count) +1)) && (!$hget(bnc,eol)) { hinc bnc count | hadd bnc eol lol | goto top }
    if ($hget(bnc,eol)) { hdel bnc eol | hadd bnc count $calc($bvar(&bnc.server,0) +1) }
  }
  .timerbnc.pingserver 0 600 sockwrite -nt bnc.server PING :mBNC
  if ($sock(bnc.client*)) && ($bvar(&bnc.server,$bvar(&bnc.server,0)) == 10) { sockwrite bnc.client* $chr(10) }
}
alias bnc.sendserver {
  breplace &bnc.client 10 13
  hadd bnc count 1
  while ($bvar(&bnc.client,0) >= $hget(bnc,count)) {
    :top
    if ($bfind(&bnc.client,$calc($hget(bnc,count) +1),13)) { tokenize 32 $remove($bvar(&bnc.client,$hget(bnc,count) $+ - $+ $bfind(&bnc.client,$calc($hget(bnc,count) +1),13)).text,$chr(13)) }
    if (!$bfind(&bnc.client,$calc($hget(bnc,count) +1),13)) { tokenize 32 $remove($bvar(&bnc.client,$hget(bnc,count) $+ -).text,$chr(13)) }
    .signal -n $sockname $1-
    if (QUIT == $1) { sockclose $sockname | bnc.halt }
    if (NICK == $1) && (!$sock($sockname).mark) { sockmark $sockname $2 | bnc.clientopen $sockname | bnc.halt }
    if (USER == $1) { bnc.halt }
    if (MODE == $1) && ($2) && (!$3) {
      if (!$hget($bnc.chan($2),mode)) && ($hget($bnc.chan($2))) { bnc.halt }
      if ($hget($bnc.chan($2),mode)) { bset &bnc.server2 1 $hget(bnc,motd1) | sockwrite -nt $sockname $gettok($bvar(&bnc.server2,1-).text,1,32) 324 $hget(bnc,me) $2 $hget($bnc.chan($2),mode) | sockwrite -nt $sockname $gettok($bvar(&bnc.server2,1-).text,1,32) 329 $hget(bnc,me) $2 $hget($bnc.chan($2),modetime) | bnc.halt }
    }
    if (PING == $1) { sockwrite -nt $sockname PONG $2- | bnc.halt }
    if ($sock(bnc.server)) && ($sock($sockname).mark) { if ($hget(bnc,halt)) { hdel bnc halt | goto end } | bset &bnc.line 1 $iif($bfind(&bnc.client,$calc($hget(bnc,count) +1),13),$bvar(&bnc.client,$hget(bnc,count) $+ - $+ $bfind(&bnc.client,$calc($hget(bnc,count) +1),13)),$bvar(&bnc.client,$hget(bnc,count) $+ -))  | sockwrite bnc.server &bnc.line | bunset &bnc.line }
    :end
    if ($bfind(&bnc.client,$calc($hget(bnc,count) +1),13)) { hadd bnc count $bfind(&bnc.client,$calc($hget(bnc,count) +1),13) }
    if (!$bfind(&bnc.client,$calc($hget(bnc,count) +1),13)) { hadd bnc count $calc($bvar(&bnc.client,0) +1) }
  }
  if ($sock(bnc.server)) && ($bvar(&bnc.client,$bvar(&bnc.client,0)) == 10) { sockwrite -t bnc.server $chr(10) }
}
alias bnc.chan {
  if ($isid) {
    hadd bnc count5 1
    while ($hget(bnc,count5) <= $hget(0)) {
      if (bnc-* $+ $1 iswm $hget($hget(bnc,count5))) { return $hget($hget(bnc,count5)) }
      hinc bnc count5
    }
    return
  }
}
alias bnc.halt { hadd bnc halt true }