copy/paste into a new remote. either click ur menubar or in a channel to open.
add ur friends nicks in the halo3 player list or do a quick look up..
i made this dialog for a friend Inprince.

feel free to rip butcher and strip this code how ever you want idc

dialog h3 {
  title "Halo3 Service Record's"
  size -1 -1 182 114
  option dbu
  box "Add/Rem Player", 1, 2 2 67 33
  edit "", 2, 4 12 63 9, autohs
  button "Add", 3, 4 23 31 10, flat
  button "Rem", 4, 36 23 31 10, flat
  box "Halo3 Player List", 5, 2 37 67 53
  list 6, 4 46 63 42, size vsbar
  box "Players Stats", 7, 71 2 109 88
  list 8, 73 11 105 77, size hsbar vsbar
  box "Quick Look Up", 9, 101 91 79 21
  edit "", 10, 103 100 49 9, autohs
  button "Look Up", 11, 154 100 24 10, flat
  box "Functions", 12, 2 91 98 21
  button "Look Up", 13, 3 100 24 10, flat
  button "Echo", 14, 27 100 24 10, flat
  button "Msg", 15, 51 100 23 10, flat
  button "Clear", 16, 74 100 24 10, flat
}
alias -l afree { var %b,%p | %p = $regsub($1-,/[^<]*>|<[^>]*>|<[^>]*/g,$chr(32),%b) | %b = $remove(%b,&nbsp;,&bull;,&lt;,&gt;) | return %b }
alias -l lHalo3 { if (%halo.dat) { did -rza h3 8 Halo 3 Service Record's For $iif($did(h3,6).seltext,$did(h3,6).seltext,$did(h3,10).text) | did -za h3 8 $gettok(%halo.dat,1,124) | did -a h3 8 $gettok(%halo.dat,2,124) | did -a h3 8 %halo.bat | did -a h3 8 %halo.cat | did -a h3 8 %halo.sat | did -a h3 8 %halo.xat | did -a h3 8 %halo.pat | did -a h3 8 $gettok(%halo.wat,1,124) | did -a h3 8 $gettok(%halo.wat,2,124) | did -a h3 8 $gettok(%halo.wat,3,124) | unset %halo.* | .sockclose halo } }
alias -l spam.halo3 { did -za h3 8 $+($chr(160),Welcome to Napa182's Halo3 Service Record) | did -a h3 8 $+($str($chr(160),15),A Script0rs Inc. Production) | did -a h3 8 $+($str($chr(160),18),Powered By Bungie.net) | did -za h3 8 $str($chr(160),6) $+($chr(40),$chr(31),$str($chr(175),3),$chr(176),$chr(32),$chr(171),$chr(164),$chr(88),$chr(167),$chr(199),$chr(174),$chr(238),$chr(254),$chr(116),$chr(48),$chr(174),$chr(167),$chr(88),$chr(164),$chr(187),$chr(32),$chr(176),$str($chr(175),3),$chr(31),$chr(41),$chr(153)) }
menu menubar,channel {
  .Halo3 Service Record's:{ dialog $iif($dialog(h3),-v,-mied) h3 h3 }
}
on *:dialog:h3:edit:10:{ did -r $dname 6,8 | did -e $dname 11 | didtok $dname 6 44 %players.halo3 }
on *:dialog:h3:init:0:{ didtok $dname 6 44 %players.halo3 | $spam.halo3 | did -b $dname 11 }
on *:dialog:h3:sclick:*:{
  if ($did == 6) { did -r $dname 8,10 | did -b $dname 11 }
  if ($did == 3) {
    if (!$did(2).text || $istok(%players.halo3,$did(2).text,44)) { 
      noop $iif(!$did(2).text,$input(Players Name Was Not Entered,udho,Error!),$iif($istok(%players.halo3,$did(2).text,44),$input(Players Name Already Exists,udho,Error!),))
      did -r $dname 2
    }
    else {
      set %players.halo3 $addtok(%players.halo3,$did(2).text,44)
      did -r $dname 2,6
      didtok $dname 6 44 %players.halo3 
    }
  }
  if ($did == 4) { 
    if (!$did(2).text && !$did(6).seltext || $did(2).text && !$did(6).seltext && !$istok(%players.halo3,$did(2).text,44)) { 
      noop $iif(!$did(2).text && !$did(6).seltext,$input(Players Name Was Not Entered Or Selected,udho,Error!),$iif($did(2).text && !$did(6).seltext && !$istok(%players.halo3,$did(2).text,44),$input(Players Name Does Not Exists,udho,Error!),)) 
      did -r $dname 2
    }
    elseif ($did(2).text && !$did(6).seltext && $istok(%players.halo3,$did(2).text,44)) {
      set %players.halo3 $remtok(%players.halo3,$did(2).text,1,44)
      did -r $dname 2,6
      didtok $dname 6 44 %players.halo3
    }
    elseif ($did(6).seltext && !$did(2).text) {
      set %players.halo3 $remtok(%players.halo3,$did(6).seltext,1,44)
      did -r $dname 2,6
      didtok $dname 6 44 %players.halo3
    }
  }
  if ($did == 11) { 
    if (!$did(10).text) { noop $input(Players Name Was Not Entered,udho,Error!) }
    else { 
      if ($sock(halo)) .sockclose halo
      set %halo.user $replace($did(10).text,$chr(32),$chr(43))
      sockopen halo www.bungie.net 80 
      did -zra $dname 8 Looking Up Halo3 Player Stats For $did(10).text Please Wait...
      .timer.halo 1 2 lHalo3
    }
  }
  if ($did == 13) {
    if (!$did(6).seltext) { noop $input(Players Name Was Not Selected,udho,Error!) }
    else { 
      if ($sock(halo)) .sockclose halo
      set %halo.user $replace($did(6).seltext,$chr(32),$chr(43))
      sockopen halo www.bungie.net 80 
      did -zra $dname 8 Looking Up Halo3 Player Stats For $did(6).seltext Please Wait...
      .timer.halo 1 2 lHalo3
    }
  }
  if ($did == 14) { var %^ = $did(8).lines, %@ = 1 | while (%@ <= %^) { | echo 12 -a $did(8,%@).text | inc %@ } }
  if ($did == 15) { var %^ = $did(8).lines, %@ = 1 | while (%@ <= %^) {  msg $active $did(8,%@).text | inc %@ } }
  if ($did == 16) { did -r $dname 8,10,2,6 | did -b $dname 11 | didtok $dname 6 44 %players.halo3 }
}
on *:SOCKOPEN:halo: {
  sockwrite -nt $sockname GET $+(/Stats/Halo3/Default.aspx?player=,%halo.user) HTTP/1.1
  sockwrite -nt $sockname Host: www.bungie.net
  sockwrite -nt $sockname $crlf
}
on *:load: { echo 12 -a You Have Just Loaded Napa182's Halo 3 Service Record Look Up... Made For Inprince | echo 12 -a A Script0rs Inc. Production | echo -a 14,1(14,1¯15,1¯0,1¯0,1º $+($chr(171),$chr(164),$chr(88),$chr(167),$chr(199),$chr(174),$chr(238),$chr(254),$chr(116),$chr(48),$chr(174),$chr(167),$chr(88),$chr(164),$chr(187)) º0,1¯15,1¯14,1¯) $+ $chr(153) }
on *:SOCKREAD:halo: {
  if ($sockerr) { did -rza h3 8 Socket Error: $sockname }
  else {
    var %f
    sockread %f
    if (*Halo 3 Service Record Not Found* iswm %f) { did -zra h3 8 Halo 3 Service Record For $+([,$replace(%halo.user,$chr(43),$chr(32)),]) Not Found | .sockclose halo | unset %halo.* }
    if (*Enemies* iswm %f) { set %halo.bat $afree(%f) }
    if (*Total Games* iswm %f) { set %halo.cat $afree(%f) }
    if (*Matchmade* iswm %f) { set %halo.sat $afree(%f) }
    if (*Player Since* iswm %f) { set %halo.dat $afree(%f) }
    if (*Custom Games* iswm %f) { set %halo.xat $afree(%f) }
    if (*Campaign Missions* iswm %f) { set %halo.pat $afree(%f) }
    if (*<li>Highest Skill:* iswm %f) { set %halo.wat $afree(%f)  }  
  }
}