Ok i know there is a ton of spellcheckers so il add my take on it as well.
copy/paste into a new remote. Right Click either in a channel or in ur menubar to open....

dialog spc {
  title "Spell"
  size -1 -1 79 69
  option dbu
  box "Enter 1 Word To Check:", 1, 2 2 76 20
  edit "", 2, 4 10 48 9, autohs left
  button "Check", 3, 54 10 22 9, flat
  box "Outcome", 4, 2 23 76 45
  list 5, 4 32 48 34, size vsbar
  button "Clear", 6, 54 32 22 9, flat
  button "Copy", 7, 54 44 22 9, flat
  button "Exit", 8, 54 56 22 9, flat ok
}
menu menubar,channel {
  .Spell Checker:dialog $iif($dialog(spc),-v,-md spc) spc
}
on *:load: { 
  echo 12 -a You Have Just Loaded Napa182's SpellChecker Dialog
  echo 12 -a An Irc.EzzyChat.com Production
}
on *:dialog:spc:init:0:{ did -b spc 3,6-7 }
on *:dialog:spc:edit:2:{ 
  did -e spc 3,6-7 
  if ($chr(32) isin $did(2).text) || ($did(2).text !isalpha) { did -r spc 2 | noop $input(Please Enter Only One Word No Space's And No Numbers,uhod,ERROR!) }
}
on *:dialog:spc:sclick:*: {
  if ($did == 3) {
    did -r spc 5
    if ($sock(spell)) sockclose spell
    sockopen spell www.infoplease.com 80
    sockmark spell $+(/spellcheck?word=,$did(2).text,&x=18&y=10) didtok spc 5 32
  }
  if ($did == 6) { did -r spc 2,5 | did -b spc 3,6-7 }
  if ($did == 7) { clipboard $did(5).seltext }
}
on *:sockopen:spell: {
  sockwrite -nt $sockname GET $gettok($sock(spell).mark,1,32) HTTP/1.1
  sockwrite -nt $sockname Host: $+($sock(spell).addr,$str($crlf,2))
}
on *:sockread:spell: {
  var %spell | sockread %spell
  if ($regex(%spell,/<p>(.+spelled correctly)<\/p>/)) { $gettok($sock(spell).mark,2-,32) $regml(1) | sockclose spell }
  if ($regex(%spell,/<li>(\w.+?)(\50.+<\/li>|<\/li>)$/i)) { set -u4 %spell2 $addtok(%spell2,$regml(1),32) }
  if (*</div><!--/ SynList -->* iswm %spell) { $gettok($sock(spell).mark,2-,32) %spell2 | sockclose spell }
}