The design/colors can't be altered in the script, unless you go and do so yourself. You can add in acros, via dialog, by right clicking in the channel and looking under the "Acronyms" section.
I hope you all understand what an acro is, as well x_x
Paste into remotes.
on *:START: {
%acros = off
%xc.version = v1.0
hmake acros
If (!$isfile($scriptdirAcronyms.txt)) { write " $+ $scriptdirAcronyms.txt" }
hload acros " $+ $scriptdirAcronyms.txt"
echo -a $chr(31)
echo -a 3,1.9:15:XCept Acronyms %xc.version - Loaded9:3.
echo -a $chr(31)
}
on *:UNLOAD: { unload.cmds }
on *:EXIT: { unload.cmds }
alias -l unload.cmds {
unset %acros %xc.version
hsave acros " $+ $scriptdirAcronyms.txt"
hfree acros
echo -a $chr(31)
echo -a 3,1.9:15:XCept Acronyms %xc.version - Unloaded9:3.
echo -a $chr(31)
}
alias -l chg {
If (%acros = on) { set %acros off | echo -a 3,1.9:15XCept Acronyms %xc.version - Off9:3. | halt }
If (%acros = off) { set %acros on | echo -a 3,1.9:15XCept Acronyms %xc.version - On9:3. | halt }
}
menu channel {
Acronyms
.$iif(%acros = on,$style(1)) XCept Acronyms %xc.version:/chg
.Open Dialog:/dialog -mdi acros acros
}
dialog acros {
title XCept Acros %xc.version
size -1 -1 148 70
option dbu
list 1, 0 0 148 50, sort size
button "Add Acro", 3, 0 50 37 9
button "Delete Acro", 4, 37 50 37 9
button "Clear Acros", 5, 74 50 37 9
button "Edit Acro", 6, 111 50 37 9
edit "", 2, 0 59 148 11
}
on *:DIALOG:acros:init:0: {
%i = 1
While ($hget(acros,%i).item) {
did -a acros 1 $hget(acros,%i).item
inc %i
}
unset %i
}
on *:DIALOG:acros:sclick:1: {
did -ra acros 2 $hget(acros,$did(acros,1).seltext)
}
on *:DIALOG:acros:sclick:3: {
%xadd = $input(Acronym to add? IE: Lol,gqveoau,XCept Acronyms %xc.version,<Place Acronym here.>)
%xadd.full = $input(Full Acronym? IE: Laughing Out Loud,gqveoau,XCept Acronyms %xc.version,<Place Acronym here.>)
If ($chr(32) isin %xadd) {
echo -a $chr(31)
echo -a 3,1.9:15XCept Acronyms %xc.version $+ . There can be no spaces in the Acronym9:3.
echo -a $chr(31)
goto end
}
If (!%xadd) || (!%xadd.full) {
echo -a $chr(31)
echo -a 3,1.9:15XCept Acronyms %xc.version $+ : Error9:3.
echo -a $chr(31)
goto end
}
hadd -m acros %xadd %xadd.full
did -a acros 1 %xadd
did -ra acros 2 $hget(acros,$did(acros,1).seltext)
:end
unset %xadd %xadd.full
}
on *:DIALOG:acros:sclick:4: {
If (!$did(acros,1).seltext) { halt }
%Y/N = $input(Are you sure you want to delete $did(acros,1).seltext your Acronym list?,auwvyd,XCept Acronyms %xc.version)
If (%Y/N = $no) { unset %Y/N | halt }
If (%Y/N = $yes) {
unset %Y/N
If ($did(acros,2).text = $hget(acros,$did(acros,1).seltext)) { did -r acros 2 }
hdel acros $did(acros,1).seltext
did -d acros 1 $did(acros,1).sel
}
}
on *:DIALOG:acros:sclick:5: {
%Y/N = $input(Are you sure you want to clear your Acronym list?,auwvyd,XCept Acronyms %xc.version)
If (%Y/N = $no) { unset %Y/N | halt }
If (%Y/N = $yes) {
unset %Y/N
did -r acros 1,2
hfree acros
hmake acros
}
}
on *:DIALOG:acros:sclick:6: {
If (!$did(acros,1).seltext) { halt }
%acro.edit = $input(Editing: $did(acros,1).seltext,eaui,XCept Acronyms %xc.version,$hget(acros,$did(acros,1).seltext))
If (!%acro.edit) { halt }
hadd -m acros $did(acros,1).seltext %acro.edit
did -ra acros 2 %acro.edit
unset %acro.edit
}
on *:INPUT:*: {
If (%acros = on) {
If (!$inpaste) && (!$ctrlenter) && ($left($1-,1) != $readini(mirc.ini,text,commandchar)) {
%i = 1
%t = $1-
%m = $0
While (%i <= %m) {
If ($hget(acros,$1)) { %v = $iif(%v,%v $xacro($hget(acros,$1)),$xacro($hget(acros,$1))) }
If (!$hget(acros,$1)) { %v = $iif(%v,%v $1,$1) }
%t = $2-
tokenize 32 %t
inc %i
}
haltdef
tokenize 32 %v
msg $active $1-
unset %v %t %i %m
}
}
}
alias xacro {
unset %x %0 %v %txt
tokenize 32 $1
%x = 1
%0 = $0
While (%x <= %0) {
%v = %v $+(15,$left($1,1),14,$mid($1,2,$len($1)))
%txt = $2-
tokenize 32 %txt
inc %x
}
return 3,1.9: $+ %v $+ 9:3.
}