Heres a little AutoJoin that i used in one of my scripts i made. Enjoy!

dialog ajoins {
  title "AutoJoin"
  size -1 -1 90 108
  option dbu
  text "AutoJoin", 1, 3 3 73 8
  button "Add network", 2, 3 14 42 12
  button "Delete network", 3, 46 14 42 12
  combo 4, 3 28 85 46, size drop
  button "Add channel", 5, 3 42 42 12
  button "Delete channel", 6, 46 42 42 12
  list 7, 3 55 84 50, size
}
alias -l addjoins {
  var %x 1
  while (%x <= $numtok(%ajoinnetworks,44)) {
    did -a ajoins 4 $gettok(%ajoinnetworks,%x,44)
    inc %x
  }
}
alias -l addchans {
  var %x 1
  while (%x <= $numtok(%ajoin [ $+ [ $did(4) ] ],44)) {
    did -a ajoins 7 $gettok(%ajoin [ $+ [ $did(4) ] ],%x,44)
    inc %x
  }
}
alias -l addtojoins {
  if (!$istok(%ajoinnetworks,$network,44)) { set %ajoinnetworks $addtok(%ajoinnetworks,$network,44) }
  set %ajoin [ $+ [ $network ] ] $addtok(%ajoin [ $+ [ $network ] ],$$chan,44)
}
on *:dialog:ajoins:init:0:{
  addjoins 
}
on *:dialog:ajoins:sclick:2:{
  if (!$istok(%ajoinnetworks,$network,44)) {
    set %ajoinnetworks $addtok(%ajoinnetworks,$network,44)
    did -r ajoins 4
    addjoins 
    did -r ajoins 7
  }
}
on *:dialog:ajoins:sclick:3:{
  set %ajoinnetworks $remtok(%ajoinnetworks,$did(4),1,44)
  if (%ajoin [ $+ [ $did(4) ] ] != $null) { unset %ajoin [ $+ [ $did(4) ] ] }
  did -r ajoins 4
  addjoins 
  did -r ajoins 7
}
on *:dialog:ajoins:sclick:4:{
  did -r ajoins 7
  var %x 1
  while (%x <= $numtok(%ajoin [ $+ [ $did(4) ] ],44)) {
    did -a ajoins 7 $gettok(%ajoin [ $+ [ $did(4) ] ],%x,44)
    inc %x
  }
}
on *:dialog:ajoins:sclick:5:{
  set %ajoin [ $+ [ $did(4) ] ] $addtok(%ajoin [ $+ [ $did(4) ] ],$$input(Channel to add,eo,Channel to add),44)
  did -r ajoins 7
  addchans 
}
on *:dialog:ajoins:sclick:6:{
  if ($did(7).seltext) {
    set %ajoin [ $+ [ $did(4) ] ] $remtok(%ajoin [ $+ [ $did(4) ] ],$did(7).seltext,44)
    did -r ajoins 7
    addchans 
  }
}
on *:connect:{
  if ($istok(%ajoinnetworks,$network,44)) { .timer 1 1 join %ajoin [ $+ [ $network ] ] }
}
alias joins dialog -m ajoins ajoins
menu menubar,channel {
  Autojoin
  .Autojoin Manager:/joins
  .Add active channel to autojoins:/addtojoins
}