Some users take a nick that is similar to an existing one and try to cheat the others.
This script will track their actions.

;
;---------> Follows a nick ::  by Lucyfero (a.k.a. Sky_Walker) <-----------
;
; Some users on IRC change their nick frequently to
; disturb normal discussion. Usually they take
; a nick that is similar to an existing one and
; try to cheat users. This script will track their
; actions. Actually it monitors a specific user 
; on a defined channel.
; To do its job the script assigns the level 666 to
; the user to monitor.
;
; Use: 1-Load in remote
;      2-Select a nick in nicklist
;      3-Right Mouse Button and 
;      4-Set Follow_Nick ON 
;
on +666:NICK: {
  haltdef
  set %follow.user $newnick
  /echo 9 -at *** (◣_◢) *** $chr(187) 8 The victim changes the nick in 11 $newnick
    .cline 8   %follow.chan   %follow.user 
  .beep 2
}

on +666:JOIN:%follow.chan: {
  haltdef
  set %follow.user $nick
  /echo 9 -at *** (◣_◢) *** $chr(187) 8 The victim joins in as %follow.user
  .cline 8   %follow.chan   %follow.user 
  .beep 3
}
on +666:PART:%follow.chan: parted
on +666:QUIT:%follow.chan: parted
on +666:EXIT:%follow.chan: parted

on +666:TEXT:*:%follow.chan: {
  haltdef
  /echo 9 -at 4 *** (◣_◢) *** $chr(187) 8 The victim says :: 11 $1-
}

on ME:*:PART:%follow.chan: { 
  if %follow.user  {
    ruser 666 %follow.user 2
    unset %follow.*
  }
}

alias -l parted {
  /echo 9 -at *** (◣_◢) *** $chr(187) 8 The victim has left %follow.chan :: 11 $1-
}

alias -l do_it {
  echo 9 -at *** (◣_◢) *** $chr(187) 8 Let's follow $$1 
  if %follow.user { 
    .cline $color(Nick text) %follow.chan %follow.user 
    .ruser 666 %follow.user 2
  }
  .guser 666 $$1 2 
  set %follow.user $$1
  set %follow.chan $chan   
  .cline 8 %follow.chan %follow.user
}

alias -l undo_it {
  echo 9 -at *** (◣_◢) *** $chr(187) 4 Disabled ! 
  if %follow.user {
    .ruser 666 %follow.user 2  
    .cline $color(Nick text) %follow.chan %follow.user 
    unset %follow.*
  }
}

menu nicklist,Channel {
  Follow_Nick %follow.user
  .ON $$1: do_it $$1
  .OFF : undo_it $$1
}