They work great on any chat server, depending how the code is done, for instance a good friend of mine uses tinyurl to get the feeds. here's an example

on *:Join:*: { 
  if ($nick == $me) { 
    .timer.hawkee 0 15 hawkee 
 } 
}

; Menu =====================================================================================
menu channel {
  Feeder
    .$iif(%Feed.hknews. [ $+ [ $active ] ] == on,$style(1)) Hawkee: $iif(%Feed.hknews. [ $+ [ $active ] ] == on,unset %Feed.hknews. [ $+ [ $active ] ],set %Feed.hknews. [ $+ [ $active ] ] on)
    .-
  .Add All $chan : {
    set %Feed.hknews. [ $+ [ $active ] ] on
  }
  .Remove All $chan : unset %Feed.*. [ $+ [ $active ] ]
  .-
  .Clear Saved Topics: unset %Topic.*
}  

; Aliases ==================================================================================
alias striphtml {
  if (!$isid) || (!$1) return
  var %H = $1 , %T = $regsub(%H,/(<[^>]+>)/g,,%H)
  if ($chr(38) isin %H) {
    set %H $replacecs(%H,&#x26;,&,&quot;," ,&lt;,< ,&gt;,> ,&amp;,& ,&nbsp;,$iif($prop,$chr($prop),$chr(32)) ,&pound;,£ ,&sect;,$chr(36) ,&uml;,¨ ,&laquo;,« ,&raquo;,» ,&szlig;,ß, &Ntilde;,Ñ ,&ntilde;,ñ,&#39;,')
    set %H $replacecs(%H,&Agrave;,À ,&Aacute;,Á ,&Acirc;, ,&Atilde;,à ,&Auml;,Ä ,&Aring;,Å ,&AElig;,Æ ,&agrave;,à ,&aacute;,á ,&acirc;,â ,&atilde;,ã ,&auml;,ä ,&aring;,å ,&aelig;,æ)
    set %H $replacecs(%H,&Egrave;,È,&Eacute;,É,&Ecirc;,Ê,&Euml;,Ë,&egrave;,è,&eacute;,é,&ecirc;,ê,&euml;,ë,&Igrave;,Ì,&Iacute;,Í,&Icirc;,Î,&Iuml;,Ï,&igrave;,ì,&iacute;,í,&icirc;,î)
    set %H $replacecs(%H,&iuml;,ï,&Ograve;,Ò,&Oacute;,Ó,&Ocirc;,Ô,&Otilde;,Õ,&Ouml;,Ö,&Oslash;,Ø,&ograve;,ò,&oacute;,ó,&ocirc;,ô,&otilde;,õ,&ouml;,ö,&oslash;,ø,&Ugrave;,Ù,&Uacute;,Ú,&Ucirc;,Û,&Uuml;,Ü,&Yacute;,Ý,&ugrave;,ù,&uacute;,ú,&ucirc;,û,&uuml;,ü,&yacute;,ý,&yuml;,ÿ)
  }
  return %H
}
alias turl {
  var %s tinyURL. $+ $ticks
  sockopen %s tinyurl.com 80
  sockmark %s $1 $2 $4 $5 $3
}
on *:sockopen:TinyURL.*: { sockwrite -tn $sockname $+(GET /api-create.php?url= $+ $gettok($sock($sockname).mark,3,32) HTTP/1.1,$crlf,Host: tinyurl.com,$crlf,$str($crlf,2)) }
on *:sockread:TinyURL.*:{
  var %r | sockread %r
  if ($left(%r,7) == HTTP://) {
    var %f 1
    while ($chan(%f)) { 
      var %g $gettok($sock($sockname).mark,2,32) $+ . $+ $chan(%f)
      if (%FEED. [ $+ [ %g ] ] == on) && (($me isop $chan(%f)) || ($me ishop $chan(%f))) { 
        msg $chan(%f) $gettok($sock($sockname).mark,1,32) Topic Update: $striphtml($gettok($sock($sockname).mark,5-,32)) - %r $iif($gettok($sock($sockname).mark,4,32) != n/a,- by $striphtml($gettok($sock($sockname).mark,4,32))) 
      }
      inc %f
    }
  }
}
; Hawkee ======================================================================================
alias hawkee {
  if ($status != connected) { halt }
  sockclose hawkeeforum
  sockopen hawkeeforum hawkee.com 80
  if (%Topic.HAWKEE == $null) { set %Topic.HAWKEE on }
  set %hawkee.check 1
}
on *:sockopen:hawkeeforum: { 
  if ($sockerr) { sockclose $sockname | halt }
  sockwrite -n $sockname GET /comment.rss.php HTTP/1.1
  sockwrite -n $sockname Host: www.hawkee.com
  sockwrite -n $sockname $crlf
}
on *:sockread:hawkeeforum: {
  if ($sockerr > 0) return
  var %hawkee
  sockread %hawkee
  if (%hawkee == 0) || (%hawkee.check > 3) { 
    sockclose $sockname 
    if (%hawkee.linktemp != $null) && (%hawkee.linktemp != on) && (%hawkee.linktemp != %Topic.HAWKEE) {
      set %Topic.HAWKEE %hawkee.linktemp
      $turl(Hawkee,hknews,$striphtml(%hawkee.title),$replace(%hawkee.linktemp,&amp;,&),n/a)
    }
    unset %hawkee.* 
  }
  else {
    if (%hawkee.check == 1) var %hawkeer = /<item>/ig
    if (%hawkee.check == 2) var %hawkeer = /<title>(.*)<\/title>/ig
    if (%hawkee.check == 3) var %hawkeer = /<link>(.*)<\/link>/ig
    if ($regex(hawkeeforum, %hawkee, %hawkeer) > 0) {
      if (%hawkee.check == 2) set %hawkee.title $regml(hawkeeforum,1)
      if (%hawkee.check == 3) set %hawkee.linktemp $regml(hawkeeforum,1)
      inc %hawkee.check
    }
  }
}

The creator of this is err0r from TG007.net