Well I went with what Firstmate did at first but I wanted a fixed width font which i didn't find in a digital clock style. So I went and jacked the pictures used in the original script and made a toolbar clock.

(Update) I added 12/24 hour time. type /clock to start in 24 hour mode and /clock 12 to use 12 hour mode. You can switch back and forth while it's running and /clockoff stops and removes the clock. Also it'll set itself to start on start if you exit with it open.
(update 2) removed leading 0 when in 12 hour time.
(update 3 or so) clicking the clock switches it between 12/24 hour time and I fixed a little bug where the am/pm wouldn't show up if you started with 24 hour then switched to 12 while it was running

DOWNLOAD THESE PICTURES FOR MY SCRIPT
http://www.mediafire.com/?amb99ah60gqt0ns

alias clock {
  if (!$toolbar(clocksep)) toolbar -is clocksep
  if (!$window(@clock)) window -nBj2kpw0 +f @clock 0 0 117 22
  if (!$toolbar(clock)) toolbar -aux clock "" @clock 0 0 $iif($1 == 12,111,82) 16
  clear @clock
  set -l %time $asctime($iif($1 == 12,hhcnncsstt,HHcnncss))
  set -l %num 1
  while ($mid(%time,%num,1) != $null) {
    if ($mid(%time,1,1) != 0) || (%num != 1) || ($1 != 12) drawpic @clock $gettok(0 12 24 29 41 53 58 70 $iif($1 == 12,87 99),%num,32) 0 $scriptdir $+ $mid(%time,%num,1) $+ .jpg
    inc %num
  }
  toolbar -pu clock @clock 0 0 $iif($1 == 12,111,82) 16
  toolbar -l clock "/clockchange"
  .timerclock 0 1 clock $iif($1 == 12,$v1)
}
alias clockchange { clock $iif($timer(clock).com == clock 12,,12) }
alias clockoff {
  .timerclock off
  toolbar -d clocksep
  toolbar -d clock
  window -c @clock
}

on *:exit: if ($timer(clock)) set %startclock $timer(clock).com
on *:start: if (%startclock) { .timer 0 1 %startclock | unset %startclock }