Ok well i decided to make a new memo system its a lot better than my older ones and is actually pretty self explanatory. When you get a memo it will open and list all the memo's you have in your inbox. From there you can either A. double click a memo in the list to open and read it B. single click a memo then click the read button to read it C. click a memo and click reply which will auto bring up a new edit area for you to put your reply in and it will auto put the persons nick who you're replying to in the top edit box where the nick goes then after filling out your memo click send and it will send it. and D. you can click a memo in the list then click delete. Also there is a New Memo button click that to open a new memo it will have a spot for you to put the nick you want to memo then the area for you to fill out the memo. Let me know what you think

raw 269 :*: { .timer 1 2 dialog -v,-md memos.system memos.system 
}  
raw 275 :*: { if (!$dialog(memos.system)) {
    dialog -v,-md memos.system memos.system 
  } 
}
raw 276 :*: { did -az memos.system 2 $2-  }
raw 277 :*: { if (!$dialog(memos.system)) {
    .timer 1 2 .dialog -v,-md memos.system memos.system
  }
  var %x = $5 | .set %memotime $asctime($ctime(%x 1/1/1), h:nn:ss TT) | did -az memos.system 1 $2-4 %memotime $6- 
}
raw 519 :*: { if ($dialog(memos.system)) {
    if ($2 == $me) {
did -r memos.system 12
      did -h memos.system 1,2,4-6,9 
      did -v memos.system 3,7-8,12-13
      did -r memos.system 13
      did -n memos.system 13
      did -a memos.system 13 enter a nick to send a memo to
      did -a memos.system 12 your nick must be registered before you can send a memo to someone

    }
    else {
      did -r memos.system 12
      did -h memos.system 1,2,4-6,9 
      did -v memos.system 3,7-8,12-13
      did -r memos.system 13
      did -n memos.system 13
      did -a memos.system 13 enter a nick to send a memo to
      did -a memos.system 12 your memo to $2 could not be sent because $2-
    }
  }
} 
Menu Menubar,Nicklist,Channel {
  .Memo System: dialog $iif($dialog(memos.System),-v,-md memos.System) memos.System 
}
Dialog memos.System {
  Title "MemoSystem"
  Size -1 -1 200 100
  Option dbu
  list 1, 02 02 140 90, hsbar vsbar
  edit "" ,2, 02 16 140 76, read multi autovs limit 370 hide
  button "Check memos ",3, 145 02 37 12 , hide
  button "Read ",4, 145 02 37 12 ,
  button "Reply ",5, 145 15 37 12 ,
  button "Delete ",6, 145 28 37 12 ,
  button "Send ",7, 145 15 37 12 , hide
  button "Cancel ",8, 145 28 37 12 , hide
  button "New Memo ",9, 145 41 37 12 ,
  edit "" ,12, 02 16 140 76, multi autovs limit 370 hide
  edit "" ,13, 02 02 140 10, hide
}
on *:Dialog:memos.system:*:*: {
  if ($devent == init) {
    refresh
  }
  if ($devent == dclick) {
    if ($did == 1) {
      did -v memos.system 2,3,13
      did -h memos.system 1,4
      did -m memos.system 13
      did -r memos.system 2,13
      did -a memos.system 13 Memo $gettok($did(1).seltext,1,32) from $gettok($did(1).seltext,2,32)
      .services memo $me read $gettok($did(1).seltext,1,46)
    }
  }
  if ($devent == sclick) {
    if ($did == 3) {
      did -r memos.system 1
      did -h memos.system 2,3,7-8,12-13
      did -v memos.system 1,4-6,9
      .services memo $me list
    }
    if ($did == 4) {
      if (!$did(1).sel) { 
        noop $input(Please select a memo in the list to read)    
      }
      else {
        did -v memos.system 2-3,13
        did -h memos.system 1,4
        did -r memos.system 2
        did -m memos.system 13
        did -r memos.system 2,13
        did -a memos.system 13 Memo $gettok($did(1).seltext,1,32) from $gettok($did(1).seltext,2,32)
        .services memo $me read $gettok($did(1).seltext,1,46)
      }
    }
    if ($did == 5) {
      if ($did(1).visible) && ($did(1).sel) { 
        did -r memos.system 12
        did -h memos.system 1,2,4-6 
        did -v memos.system 3,7-8,12-13
        did -r memos.system 13
        did -n memos.system 13
        did -a memos.system 13 $gettok($did(1).seltext,2,32)

      }
      elseif ($did(1).visible) && (!$did(1).sel) {
        noop $input(Please select a memo in the list to reply to)
      }
      else {
        .var %replynick $gettok($did(13).text,4,32)
        did -r memos.system 12
        did -h memos.system 1,2,4-6 
        did -v memos.system 3,7-8,12-13
        did -r memos.system 13
        did -n memos.system 13      
        did -a memos.system 13 %replynick
      }
    }
    if ($did == 6) {
      if (!$did(1).sel) {
        noop $input(Please select a memo in the list to delete)
      }
      elseif (!$did(1).visible) {
        .services memo $me delete $gettok($did(13).text,2,32)
        did -h memos.system 2,3,13
        did -v memos.system 1,4 
        did -r memos.system 1
        refresh
      }
      else {
        .services memo $me delete $gettok($did(1).seltext,1,46)
        did -r memos.system 1
        refresh
      }
    }
    if ($did == 7) {
      .services memo $did(13).text send $did(12).text
      did -r memos.system 1,12
      did -v memos.system 1,4-6,9 
      did -h memos.system 3,7-8,12-13
      refresh

    }
    if ($did == 8) {
      did -r memos.system 1,12
      did -v memos.system 1,4-6,9 
      did -h memos.system 3,7-8,12-13
      refresh
    }
    if ($did == 9) {
      did -r memos.system 12
      did -h memos.system 1,2,4-6,9 
      did -v memos.system 3,7-8,12-13
      did -r memos.system 13
      did -n memos.system 13
      did -a memos.system 13 enter a nick to send a memo to
    }

  }
}
alias refresh {
  .services memo $me list
}