A little script I wrote back in '06 and am still using to halt mIRC's default text. Feel free to make any changes to your liking. :-)

on ^*:JOIN:#:{
  if ($nick == $me) echo $colour(join) -t # -!- Now Talking in #
  else echo $colour(join) -t # -!- Joins: $nick $chr(171) $+ $address $+ $chr(187) #
  haltdef
}

on ^*:PART:#:{
  if ($nick == $me) halt
  echo $colour(part) -t # -!- Parts: $nick $chr(171) $+ $address $+ $chr(187) # $iif($1 != $null,Reason: $1-) 
  haltdef
}

on ^*:RAWMODE:#: {
  if ($nick == $me) echo $color(mode) -t # -!- Mode Set: $chr(171) $+ $nick $+ / $+ $chan $+ $chr(187) $1-
  else echo $color(mode) -t # -!- Mode Set: $chr(171) $+ $nick $+ / $+ $chan $+ $chr(187) $1-
  haltdef
}

on ^*:KICK:#:{
  if ($knick == $me) echo $colour(kick text) -t # -!- Channel Kick: You were kicked from # by $nick - $iif($1,$1-,No Reason)
  else echo $colour(kick text) -t # -!- Channel Kick: $chr(171) $+ $nick $+ / $+ $knick $+ $chr(187) -> $iif($1,$1-,No Reason) 
  haltdef
}

on ^*:INVITE:#:{ 
  echo $colour(invite) -t -!- Channel Invite: $nick $chr(171) $+ $address $+ $chr(187) invites you to join # 
  haltdef
}

on ^*:TOPIC:#:{
  if ($nick == $me) echo $colour(topic) -t -!- Topic Set: $chr(171) $+ $nick $+ / $+ # $+ $chr(187) changed topic to: $1- 
  echo $colour(topic) -t # -!- Topic Set: $chr(171) $+ $nick $+ / $+ # $+ $chr(187) $1- 
  haltdef
}

on ^*:TEXT:*:#:{
  if ($nick isreg $chan) {
    echo $color(text) -tml # $+($chr(2),$nick,$chr(2)) $+ : $1-
  }
  else {
    echo $color(text) -tml # $+($chr(2),$left($nick($chan,$nick).pnick,1),$nick,$chr(2)) $+ : $1-
  }
  haltdef
}

on ^*:TEXT:*:?:{
  echo $color(text) -tml $nick $+($chr(2),$nick,$chr(2)) $+ : $1-
  haltdef
}

on *:INPUT:*:{
  if (!$ctrlenter) && ($left($1,1) !== $readini(mirc.ini,text,commandchar)) {
    if ($nick isreg $chan) {
      echo $color(own text) -tml $target $+($chr(2),$nick,$chr(2)) $+ : $1-
      .msg $target $1-
    }
    else {
      echo $color(own text) -tml $target $+($chr(2),$left($nick($chan,$nick).pnick,1),$nick,$chr(2)) $+ : $1-
      .msg $target $1-
    }
    .haltdef
  }
}

on ^*:NICK: {
  if ( $newnick == $me ) echo $color(nick text) -set $me is now: $newnick 
  elseif ( $comchan($newnick,0) == 0 ) echo $color(nick text) -t -!- Nick Change: $nick -> $newnick
  var %x = 1
  while ( $comchan($newnick,%x) ) {
    echo $color(nick text) -t $comchan($newnick,%x) -!- Nick Change: $nick -> $newnick
    inc %x
  }
  haltdef
}

ON ^*:QUIT:{
  %chans. [ $+ [ $nick ] ] = $comchan($nick,0)
  while ( %chans. [ $+ [ $nick ] ] >= 1 ) {
    echo $color(quit) -t $comchan($nick,%chans. [ $+ [ $nick ] ] ) -!- Quits: $nick $chr(171) $+ $address $+ $chr(187) - $1-
    dec %chans. [ $+ [ $nick ] ]
  }
  unset %chans. [ $+ [ $nick ] ]
  haltdef
}