This would let you do a single or multiple whois on selected nicks in an active channel. Right-click on your nicklist & highlight/select nicks you want to /whois then select the option Multiple whois or Whois Nickname. Copy/Paste to your remotes section (ALT-R - FILE - NEW).

;================================================
; Custom Multiple Whois
; Version 1.0 
; Written by: xDaeMoN
; Email: xdaemon@xdaemon.us
; Usage: Right-click on your nicklist & highlight/select nicks 
;            you want to /whois then select the option Multiple 
;            whois or Whois Nickname.
;================================================

menu nicklist {
  -
  $iif($snick(#,0) > 1,Multiple Whois,Whois $snicks): mwhois
  -
}

alias mwhois {
  if ( !%w.chan ) set %w.chan $chan
  if ( !%w.nick ) set %w.nick 0
  inc %w.nick
  if ( $snick(%w.chan,%w.nick) ) {
    .enable #mwhois
    whois $v1 $v1
  }
  else unset %w.*
}

#mwhois off
;---Custom Output-----
raw 301:*: { echo -a $2 is away: $3- | halt }
raw 311:*: { echo -a $str(-,5) /whois $2 $str(-,5) | echo -a  | echo -a $2 is $+($3,@,$4-) | halt }
raw 313:*: { echo -a $2 is an IRCop: $5- | halt }
raw 312:*: { echo -a $2 using $3- | halt }
raw 330:*: { echo -a $2 $4- $3 | halt }
raw 317:*: { echo -a $2 has been idle $duration($3) $+ , signed on $asctime($4)  | halt }
raw 319:*: { echo -a $2 is on $numtok($3-,32) Channel(s): $3- | halt }
raw 318:*: { echo -a  | echo -a $str(-,5) End of /whois on $2 $str(-,5) | .disable #mwhois | mwhois | halt }
;---------------------------------
#mwhois end