This is my take on hxck's WTFD snippet
-- Orignal Snippet: http://www.hawkee.com/snippet/9111/

/wtfd:Set Public|Private On|Off
Public|Private - Enables|Disables the !dinner and !vdinner channel commands
On|Off - Turns the word censor on off

/wtfd [-v]
This command does the same as the !dinner and !vdinner commands except
the results are displayed locally(Not set to server)
if '-v' is specified, a vegaterian dish is returned.

Bug Fixes/Additions/Changes:

• Fixed onLoad Event(Replaced "$false" with off)
• Added 5sec flood protection

alias -l wtfd return whatthefu $+ ckshouldimakefordinner.com
alias -l wtfd:c return $replacex($1-,fu $+ ck,****,sh $+ it,****)
on *:LOAD: wtfd:Set Public off
on *:UNLOAD:{
  if ($sock(wtfd)) sockclose $v1
  unset %wtfd*
}

#wtfd on
on $*:TEXT:/^!v?dinner$/Si:#:{
  if ($sock(wtfd) || %wtfd:Flood) { return }
  sockopen wtfd $wtfd 80
  sockmark wtfd $iif(!v* iswm $1,/veg.php,/index.php) msg #
  set -eu5 %wtfd:Flood $true
}
#wtfd end
on *:SOCKOPEN:wtfd:{
  tokenize 32 $sock($sockname).mark
  if ($sockerr) $2- Dinner: Unable to connect.
  else {
    sockwrite -n $sockname GET $1 HTTP/1.1
    sockwrite -n $sockname Host: $wtfd
    sockwrite -n $sockname Connection: close
    sockwrite -n $sockname
  }
}
on *:SOCKWRITE:wtfd:{
  if ($sockerr) { 
    $gettok($sock($sockname).mark,2-,32) Dinner: Unable to request page 
    unset %wtfd:* 
  }
}
on *:SOCKREAD:wtfd:{
  tokenize 32 $sock($sockname).mark
  if ($sockerr) {
    $2- Dinner: Unable to read data.
    unset %wtfd:*
  }
  else {
    var %tmp 
    sockread %tmp
    while ($sockbr) {
      if ($regex(%tmp,^([^<>]+)<\/dl>)) set %wtfd:Line $regml(1)
      elseif ($regex(%tmp,^<dt><a href="([^"]+)"[^>]+>([^<>]+)<\/a><\/dt>$)) {
        set %wtfd:Link $regml(1)
        set %wtfd:Desc $regml(2)
      }
      sockread %tmp
    }
  }
}
on *:SOCKCLOSE:wtfd: {
  tokenize 32 $sock($sockname).mark
  if ($sockerr) $2- Dinner: Connection closed Unexpectedly
  else {
    $2- $iif(%wtfdc,$wtfd:c(%wtfd:line),%wtfd:line) $+ : %wtfd:desc
    $2- %wtfd:link
  }
  unset %wtfd:*
}

alias wtfd {
  if ($sock(wtfd)) echo -ac info2 * /wtfd: Socket in use, please wait
  else {
    sockopen wtfd $wtfd 80
    sockmark wtfd $iif($1 == -v,/veg.php,/index.php) echo -a * WTFD:
  }
}

alias wtfd:Set {
  if (!$regex($1-,/^(Private|Public) (on|off)$/i)) {
    echo -ac info2 * /wtfd:Set: Invalid parameters
  }
  else {
    $iif($1 == Public,.enable,.disable) #wtfd
    set %wtfdc $iif($2 == on,$true,$false)
    echo -ac info * /wtfd is now $1 and the word censor is $2
  }
}