Usage:

Right Click on Menubar, Nicklist or Channel

or

/MCD

If you have any suggestions pls post a comment i will try to do it and make the dialog better :)

Menu Menubar,Nicklist,Channel {
  -
  MiniCmdsDialog { MCD }
  -
}
alias MCD { dialog $iif($dialog(MCD),-v,-am) MCD MCD }
dialog MCD {
  title "Mini Commands Dialog by Memoli"
  size -1 -1 185 235
  option dbu
  ;;;Event
  box Event, 3, 16 5 41 44
  radio "TEXT", 4, 20 15 30 10, group
  radio "ACTION", 5, 20 25 30 10
  radio "INPUT", 6, 20 35 30 10
  ;;;Command
  box "Command", 7, 64 5 49 44
  radio "Message", 8, 70 15 35 10, group
  radio "Echo", 9, 70 25 35 10
  radio "Describe", 23, 70 35 35 10
  ;;;Flood
  box "Flood", 10, 16 53 81 20
  edit "5", 12, 60 60 20 10, right
  text "Sec", 13, 80 60 15 10, center
  check "On", 11, 20 60 20 10
  check "Off", 18, 40 60 20 10
  ;;;MathText
  box "Matchtext", 19, 16 133 57 28
  edit "!Test", 20, 24 143 40 11, multi autohs
  ;;;Message
  box "Message", 14, 80 133 89 28
  edit "This is a Test", 15, 88 143 73 11, multi autohs
  ;;;Mini Command Event
  box "Mini Command Event", 2, 16 165 153 44
  edit "Press 'Submit Code' for Show the Code", 1, 24 176 137 11, multi autohs
  button "Submit Code", 16, 33 190 45 12
  button "Copy to Clipboard", 24, 105 190 47 12
  ;;;Operator
  box "Operator", 25, 16 77 153 52
  ;;;;;isop
  box "isop", 27, 24 85 65 36
  check "On", 26, 30 94 20 10
  check "Off", 28, 30 104 20 10
  edit "Nickname", 30, 51 89 35 10, autohs
  text "isop", 35, 60 99 15 10, center
  edit "Channel", 31, 51 109 35 10, autohs
  ;;;;;isin
  box "isin", 29, 96 85 65 36
  check "On", 33, 100 94 20 10
  check "Off", 34, 100 104 20 10
  edit "v1", 32, 125 89 33 10, autohs
  text "isin", 37, 135 99 15 10, center
  edit "v2", 36, 125 109 33 10, autohs
  ;;;ResetAll and Close
  button "Reset ALL", 17, 50 215 35 10
  button "Close", 21, 100 215 35 10
  ;;;About
  link "irc.g-revolutionx.com #GRX", 46, 95 227 90 8
  text "memoli94@hotmail.de", 22, 0 227 90 8, disable center
  ;;;Message Type
  box "Message Type", 42, 120 5 49 44
  radio "Channel", 43, 125 15 35 10, group
  radio "Private MSG", 44, 125 25 40 10
  edit "$nick", 45, 125 35 40 10, autohs
  ;;;Message Place
  box "Message Place", 38, 104 53 65 20
  radio "#", 39, 110 60 15 10, group 
  radio "?", 40, 130 60 15 10
  radio "*", 41, 150 60 15 10
}
On *:DIALOG:MCD:INIT:*:{
  ;;;Event
  if (%MCD.Event == TEXT) { 
    did -c MCD 4
  }
  elseif (%MCD.Event == ACTION) {
    did -c MCD 5 
  }
  elseif (%MCD.Event == INPUT) { 
    did -c MCD 6
  }
  ;;;Message Type
  if ($istok(%MCD.Cmd,$chr(35),32)) {
    did -c MCD 43
    did -m MCD 45
  }
  elseif ( $did(MCD,45) isin %MCD.Cmd ) {
    did -c MCD 44
    did -n MCD 45
  }
  ;;;Command
  if ($istok(%MCD.Cmd,Msg,32)) { 
    did -c MCD 8 
  }
  elseif ($istok(%MCD.Cmd,Echo,32)) { 
    did -c MCD 9
  }
  elseif ($istok(%MCD.Cmd,Describe,32)) {
    did -c MCD 23
  }
  ;;;Flood
  if (%MCD.Flood = 1) { 
    did -c MCD 11 
  }
  elseif (%MCD.Flood = $null) { 
    did -c MCD 18 
    did -m MCD 12 
  }
  ;;;isop
  if (%MCD.isop == 1) { 
    did -c MCD 26
  }
  elseif (%MCD.isop == $null) {
    did -c MCD 28
    did -m MCD 30,31
  }
  ;;;isin
  if (%MCD.isin == 1) {
    did -c MCD 33
  }
  elseif (%MCD.isin == $null) {
    did -c MCD 34
    did -m MCD 32,36
  }
  ;;;Message Place
  if (%MCD.Place == $null) {
    did -c MCD 39
  }
  elseif (%MCD.Place == $chr(35)) {
    did -c MCD 39
  }
  elseif (%MCD.Place == $chr(63)) {
    did -c MCD 40
  }
  elseif (%MCD.Place == $chr(42)) {
    did -c MCD 41
  }
}
on *:DIALOG:MCD:sclick:*:{
  ;;;Event
  if ($did == 4) { 
    set %MCD.Event TEXT
  }
  elseif ($did == 5) { 
    set %MCD.Event ACTION
  }
  elseif ($did == 6) {
    set %MCD.Event INPUT 
  }
  ;;;Command
  elseif ($did == 8) { 
    set %MCD.Cmd Msg
  }
  elseif ($did == 9) { 
    set %MCD.Cmd Echo
  }
  elseif ($did == 23) { 
    set %MCD.Cmd Describe
  }
  ;;;Flood
  elseif ($did == 11) { 
    set %MCD.Flood 1
    did -n MCD 12 
    did -u MCD 18
  } 
  elseif ($did == 18) { 
    set %MCD.Flood $null 
    did -m MCD 12 
    did -u MCD 11 
  }
  ;;;Submit Code
  elseif ($did == 16) {
    did -o MCD 1 1 $null 
    did -o MCD 1 1 on *: $+ %MCD.Event $+ : $+ $iif(!$istok(%MCD.Event,Input,32),$did(MCD,20),*) $+ : $+ $iif(%MCD.Place, $gettok(%MCD.Place,1,32), $chr(35) ) $+ : $chr(123) $iif(%MCD.Event == INPUT,if ( $+($,1) == $did(MCD,20) ) $chr(123), $null) $iif(%MCD.isin == 1, if ( $did(MCD,32) isin $did(MCD,36) ) $chr(123) ,$null) $iif(%MCD.isop == 1, if ( $did(MCD,30) isop $did(MCD,31) ) $chr(123) ,$null) $iif(%MCD.Flood == 1,if ( !%MCD.AF. $+ $did(MCD,20) ) $chr(123) .set $+(-u,$did(MCD,12)) $+(%,MCD.AF.,$did(MCD,20)) 1 $chr(124)) %MCD.Cmd $did(MCD,15) $chr(125) $iif(%MCD.flood == 1, $chr(125),$null) $iif(%MCD.Event == Input, $chr(125),$null)  $iif(%MCD.isin == 1, $chr(125),$null)  $iif(%MCD.isop == 1, $chr(125),$null) 
  }
  ;;;About
  elseif ($did = 46) {
    run iexplore.exe http://www.g-revolutionx.com/irc.html
  }
  ;;;Close 
  elseif ($did == 21) { 
    dialog -x MCD
  }
  ;;;Reset ALL
  elseif ($did == 17) { 
    dialog -x MCD 
    unset %MCD.*
    dialog -v,-md MCD MCD 
  }
  ;;;Copy to Clipboard
  elseif ($did == 24) { 
    clipboard $did(MCD,1)
  }
  ;;;isop
  elseif ($did == 26) {
    did -u MCD 28 
    did -n MCD 30,31
    set %MCD.isop 1
  }
  elseif ($did == 28) {
    did -u MCD 26
    did -m MCD 30,31
    set %MCD.isop $null
  }
  ;;;isin
  elseif ($did == 33) {
    did -u MCD 34
    did -n MCD 32,36
    set %MCD.isin 1
  }
  elseif ($did == 34) {
    did -u MCD 33
    did -m MCD 32,36
    set %MCD.isin $null
  }
  ;;;Message Type
  elseif ($did == 43) {
    did -u MCD 44
    did -m MCD 45
    set %MCD.Cmd $gettok(%MCD.Cmd,1,32) $chr(35)
  }
  elseif ($did == 44) {
    did -u MCD 43
    did -n MCD 45
    set %MCD.Cmd $gettok(%MCD.Cmd,1,32) $did(MCD,45)
  }
  ;;;Message Place
  elseif ($did == 39) {
    set %MCD.Place $chr(35)
  }
  elseif ($did == 40) {
    set %MCD.Place $chr(63)
  }
  elseif ($did == 41) {
    set %MCD.Place $chr(42)
  }
}