If you have been an mIRC hobbyist for any significant length of time, you may have come to the conclusion that its scripting language holds no more mysteries and poses no more challenges for you. You may even lament the time you spent learning this shoddy language, with its flippant parser and its highly limited scope with respect to today's technology. However, if you should decide to go deeper, past the 'what's and onto the 'why's, you will find that there's a lot more to know about this seemingly simple language than you've ever realized. But why would you want to know it to such a depth? Well, let's just say, if you learn mIRC script deeply then you have learned how NOT to build a scripting language :P

I've posted this snippet to celebrate the re-introduction of SwiftIRC's challenges - a subculture of the now dwindling global mIRC scripting scene - that features a bunch of like-minded enthusiasts coming together and battling it out on the client that we all know and love. Many of the challenges concern 'code shortening': a practice that, taken out of context, is largely useless. When placed in the context of these challenges, wherein a group of people all apply this practice to meet the same end, the results can be very interesting indeed. The mIRC scripting language, its syntax, features and the nature of its interpreter, are such that it enables you to conceal great complexity in just a few short lines. The same can be said for most languages of course, but mSL is quite unique in the informality of its syntax, the diversity of its standard library and the sheer number of features that behave, in certain subtle ways, contrary to one's intuition and often to their own intended purpose.

If any of this sounds interesting, then I welcome you to participate in our ongoing challenge '$valid_msl()', the details of which can be found at:

http://forum.swiftirc.net/viewtopic.php?f=35&t=24742

/*
{
  The following is a simple demonstration of what typically occurs in a 
  challenge based on the size of code.

  The challenge, in this case, is to create a custom identifier called
  $factorial, whose format is:

  $factorial(N)[.r]

  $factorial(N) should return the factorial of N; that is, the product of
  all positive integers <= N.

  For example, $factorial(4) = 24, since 4 * 3 * 2 * 1 = 24.

  If a property is given (tested only with 'r'), then the process is reversed
  such that the return value is the N whose factorial is the given number.

  For example, $factorial(24).r = 4, since $factorial(4) = 24.

  In this particular challenge, the contestants were not required to check 
  for erroneous input.
}
*/

; Method 1 (103 characters excluding indentation and new lines)

; A simple yet elegant method that very closely follows our intuition. This 
; is how I would code it in any every day situation, and I'm sure it closely
; resembles what many others scripters are capable of producing.

alias factorial {
  var %a 0,%b 1
  while %a < $1 {
    inc %a
    %b = %a * %b
    if $prop && %b = $1 return %a
  }
  return %b
}

; Method 2 (100 characters excluding indentation and new lines)

; 3 characters and several hours later, if you are sufficiently savvy about
; the various ins and outs of mIRC syntax, we may see the following method.
; The code has completely changed, and the result is now a very carefully and
; deliberately selected combination of characters that, thanks to certain
; facts about the language and its constituents, produces the desired output.

alias factorial {
  while $1 != $5 tokenize 32 $1 $calc($2+^) $calc((1+$2)*$3 1) $prop $3 $2-
  return $6
}