A simple IRC Messenger.

Load it in your remote section, and right click at status window to load the messenger dialog.

dialog m {
  title "IRC Messenger v1.0"
  size -1 -1 99 202
  option dbu
  list 1, 0 2 99 96, sort size vsbar
  list 2, 0 97 99 88, sort size vsbar
  button "Add Notify", 3, 2 188 31 12
  button "Del Notify", 4, 64 188 32 12
  button "Refresh", 5, 36 188 25 12
}
alias msgr { $iif(!$dialog(m),dialog -mdho m m) | mnick }
alias mnick {
  var %num = $notify(0), %find = 1, %online = 0, %offline = 0
  did -r m 1 | did -r m 2
  while %find <= %num {
    if ($notify(%find).ison) { did -a m 1 $notify(%find) | inc %online }
    else { did -a m 2 $notify(%find) | inc %offline }
    inc %find
  }
  did -ai1 m 1 $chr(5) ONLINE $chr(40) $+ %online $+ $chr(41) $chr(5)
  did -ai1 m 2 $chr(5) OFFLINE $chr(40) $+ %offline $+ $chr(41) $chr(5)
  $iif(!$dialog(m).active,dialog -v m)
}
on *:dialog:m:sclick:5:mnick
on *:dialog:m:dclick:1:$iif($chr(5) !isin $did($did).seltext,query $did($did).seltext)
on *:dialog:m:sclick:3:{ .notify $$?="Enter Notify Nickname" | mnick }
on *:dialog:m:sclick:4:{ .notify -r $$?="Enter Nickname To Remove" | mnick }
menu menubar,status {
  IRC Messenger:$iif($server,msgr,echo -s 4You Didn't Connect To Server Yet)
}
on *:NOTIFY:$iif(!$dialog(m),msgr,mnick)
on *:UNOTIFY:$iif(!$dialog(m),msgr,mnick)