I'm not sure if i posted this remote is wrong.. but i'm sure, it works pretty good and wanna share it with everyone.Btw, i didn't make this remote, i take this code from script acidmax2121_alpha5.

;Title: Chan history
;Team Nexgen 2001 by KnightFal

alias Chanhist {
  _vw joinhistory active $activecid 
  if ($dialog(joinhist) == $null) {  dialog -m joinhist joinhist }
  else clist
}
dialog joinhist {
  title "connect history"
  size $c.x $c.y 81 151
  option dbu
  button "Button", 5, 26 166 37 12, ok
  check "enable", 7, 4 1 30 9
  tab "channels", 10, 2 10 76 113
  list 1, 4 32 71 60, tab 10 sort size vsbar
  text "double click to join", 4, 16 25 46 7, tab 10
  text "network", 9, 7 97 65 8, tab 10 center
  box "", 8, 5 92 70 15, tab 10
  button "remove", 2, 7 109 30 10, disable tab 10
  button "clear list", 3, 41 109 30 10, tab 10
  tab "servers", 11
  list 12, 4 32 71 60, tab 11 sort size vsbar
  text "double click to connect", 13, 12 25 56 7, tab 11
  button "remove", 14, 7 95 30 10, disable tab 11
  button "clear list", 15, 41 95 30 10, tab 11
  text "", 16, 7 110 65 8, tab 11 center
  box "", 17, 5 105 70 15, tab 11
  radio "load on start", 18, 16 137 43 10
  radio "load on connect", 19, 16 128 50 10
  box "", 20, 2 123 77 26
}
on *:dialog:joinhist:init:*:{
  if ($_vr(joinhist,switch) == $null) { _vw joinhist switch on }
  if ($_vr(joinhist,load) == on) { did -c joinhist 19 } 
  else { did -c joinhist 18 }
  if ($_vr(joinhist,switch) == on) {
    _vw joinhistory active $cid 
    did -c joinhist 7 
    clist  
  }
}
on *:active:*: {
  if ($dialog(joinhist)) {
    scid $activecid | clist
  }
}
alias -l c.x {
  if ($_vr(joinhist,x) != $null) { return $_vr(joinhist,x) }
  else { return -1 }
}
alias -l c.y {
  if ($_vr(joinhist,y) != $null) { return $_vr(joinhist,y) }
  else { return -1 }
}
on *:dialog:joinhist:mouse:*: {
  _vw joinhist x $dialog(joinhist).x
  _vw joinhist y $dialog(joinhist).y
}
on *:dialog:joinhist:dclick:*:{
  if ($did == 1) { scid $activecid join $did(joinhist,1).seltext }
  if ($did == 12) { server -m $did(joinhist,12).seltext }
}
on *:dialog:joinhist:sclick:*:{
  ;  if ($did == 1) { did -e joinhist 2 | scid $_vr(joinhistory,active) | join $did(joinhist,1).seltext }
  if ($did == 1) { did -e joinhist 2 }
  if ($did == 2) { 
    if ($read(data\joinhist\ $+ $did(joinhist,9).text , w, * $+ $did(joinhist,1).seltext $+ *) != $null) { write -dw $+ $did(joinhist,1).seltext data\joinhist\ $+ $did(joinhist,9).text | clist2 }
    did -b joinhist 2 
    click 
  }
  if ($did == 3) { .remove data\joinhist\ $+ $did(joinhist,9).text | .timer -m 1 1 clist | did -b joinhist 2 | click } 
  if ($did == 10) { click }
  if ($did == 18) { 
    if ($_vr(joinhist,start) == on) { _vw joinhist start off | _vw joinhist load on }
    else { _vw joinhist start on | _vw joinhist load off }
    click 
  }
  if ($did == 19) { 
    if ($_vr(joinhist,load) == on) { _vw joinhist load off | _vw joinhist start on }
    else { _vw joinhist load on | _vw joinhist start off }
    click
  }
  if ($did == 7) { 
    if ($_vr(joinhist,switch) == on) { _vw joinhist switch off }
    else { _vw joinhist switch on | did -c joinhist 7 }
    click  
  }
  if ($did == 11) { slist | click }
  if ($did == 12) { did -e joinhist 14 | did -o joinhist 16 1 $readini data\joinhist\servers.ini $did(joinhist,12).seltext network }
  if ($did == 15) { .write -c data\joinhist\servers.txt | .timer -m 1 1 slist | did -b joinhist 14 | click } 
  if ($did == 14) { 
    if ($read(data\joinhist\servers.txt, w, * $+ $did(joinhist,12).seltext $+ *) != $null) { write -dw $+ $did(joinhist,12).seltext data\joinhist\servers.txt | slist }
    did -b joinhist 14
    click 
  }
}
on *:connect:{
  if ($_vr(joinhist,switch) == $null) { _vw joinhist switch on }
  if ($network != $null) { mkdir data\joinhist\ }
  if ($_vr(joinhist,load) == $null) { _vw joinhist load on }
  if ($_vr(joinhist,load) == on) && ($dialog(joinhist) == $null) { if ($_vr(joinhist,switch) == on) { chanhist } }
  elseif ($_vr(joinhist,load) == on) && ($dialog(joinhist) != $null) { if ($_vr(joinhist,switch) == on) { clist } }
  if ($read(data\joinhist\servers.txt, w, * $+ $server $+ *) == $null) && ($server != $null) { write -i1 data\joinhist\servers.txt $server | writeini data\joinhist\servers.ini $server network $network | if ($dialog(joinhist) != $null) { slist } }
}
on *:start:{
  if ($_vr(joinhist,switch) == $null) { _vw joinhist switch on }
  if ($network != $null) { mkdir data\joinhist\ }
  if ($_vr(joinhist,load) == $null) { _vw joinhist load on }
  if ($_vr(joinhist,start) == on) && ($dialog(joinhist) == $null) { if ($_vr(joinhist,switch) == on) { chanhist } }
  elseif ($_vr(joinhist,start) == on) && ($dialog(joinhist) != $null) { if ($_vr(joinhist,switch) == on) { clist } }
  if ($exists(msserver.ini) == $false) ms.write.server.file
  if ($_vr(MultiServ,PopupConnect) == on) ms.newconnect
}
on *:join:#: {
  if ($nick == $me) {  
    if ($_vr(joinhist,switch) == on) {
      if ($exists(data\joinhist\ $+ $network) == $false) && ($network != $null) { mkdir data\joinhist\ | write -c data\joinhist\ $+ $network }
      elseif ($exists(data\joinhist\ $+ $server) == $false) && ($network == $null) { mkdir data\joinhist\ | write -c data\joinhist\ $+ $server }
      if ($read(data\joinhist\ $+ $network, w, * $+ $chan $+ *) == $null) && ($network != $null) { write -i1 data\joinhist\ $+ $network $chan | if ($dialog(joinhist) != $null) { clist } }
      elseif ($read(data\joinhist\ $+ $server, w, * $+ $chan $+ *) == $null) && ($network == $null) { write -i1 data\joinhist\ $+ $server $chan | if ($dialog(joinhist) != $null) { clist } }
    }
  }
}
alias -l slist {
  did -r joinhist 12 
  var %aj1 = $lines(data\joinhist\servers.txt) 
  var %ajc = 1
  while (%ajc <= %aj1) { did -a joinhist 12 $read(data\joinhist\servers.txt,%ajc) | inc %ajc 1 }
}
alias -l clist {
  if ($network != $null) { did -o joinhist 9 1 $network }
  elseif ($network == $null) { did -o joinhist 9 1 $server }
  did -b joinhist 2  
  did -r joinhist 1 
  if ($network != $null) { var %aj1 = $lines(data\joinhist\ $+ $network) | var %se = $network }
  elseif ($network == $null) && ($server != $null) { var %aj1 = $lines(data\joinhist\ $+ $server) | var %se = $server }
  var %ajc = 1
  while (%ajc <= %aj1) { did -a joinhist 1 $read(data\joinhist\ $+ %se,%ajc) | inc %ajc 1 }
}
alias -l clist2 {
  did -b joinhist 2  
  did -r joinhist 1 
  var %aj1 = $lines(data\joinhist\ $+ $did(joinhist,9).text) | var %se = $did(joinhist,9).text 
  var %ajc = 1
  while (%ajc <= %aj1) { did -a joinhist 1 $read(data\joinhist\ $+ %se,%ajc) | inc %ajc 1 }
}
alias ms.debug return $false
alias ms-1.mrc.reset {
  remini data\setting.ini Multiserv
  sockclose MS*
  write -c data\multiserv.ini
  ms.write.server.file
  ;ms.load.setting
}