Kirby's PasteBin Uploader/Downloader

By Kirby on May 19, 2009

Hey guys. I haven't posted a snippet in a while, so here's one!
For a while I've been working with sockets and dialogs, and more recently, regular expressions; but this one has been very interesting for me.

I script often, so I have to use PasteBin consistently. I've also seen a few PasteBin scripts here on Hawkee, such as Pastebin (Uploader) by H_M and PasteBin Saver/Script Loader by NIGathan.
They both work effectively, but one is an uploader, and another is a downloader.

Then I thought to myself, "Why not combine both?"
Well here it is: a PasteBin Uploader and Downloader.

Onto the code.

[size=24]"So, how can I use this?"[/size]
[size=18]Syntax: /pastebin to open up the dialog.[/size]
I've tried to make it as user-friendly as possible, but maybe it's not for some of you. So, here's some elaboration!
As you can see in the screen-shot below, the dialog itself is pretty massive. Plus, there are no tabs.

[size=24]"So, how does uploading and downloading work?"[/size]
For uploading, you can upload existing files or paste them directly into the large edit box. You can add your name, a custom sub-domain name (for private pasting), how you want PasteBin to read your paste (72 languages to choose from), when you want your paste to expire, and much more!
For downloading, you can do two things. Firstly, you can simply preview it. Previewing is simply looking at the paste; no saving to your files or anything. This can be useful because if you save every single time to view a paste, it can waste your hard disk space. Secondly, you can download it. All files are downloaded to a folder called "PasteBin" in your mIRC Directory. If the paste was private, separate folders inside the folder "PasteBin" will be created, along with a modification of a file name depending on the type of paste (language syntax highlighting). You can also check the "Load to remotes?", to...load the paste to your remotes.

[size=24]"What other features are available?"[/size]
The dialog is pretty much this: An uploading section A downloading section An information box A very large edit box A few buttons all around
Here are some features:
Choose own name for uploading Options of private pasting (custom sub-domain names) 72 language highlighting options Selection of post expiry Importing (browsing) existing files Option to load paste to remote Clearing the screen Copying selected text or all text to the clipboard "Go to Nth line..." option* many more!
So, I guess it's pretty self-explanatory.

[size=18]*** Note: If you haven't used PasteBin before, I suggest following that link and testing it out for yourself before you test this dialog.[/size]

One more thing I would like note:
[size=28]Use mIRC Version 6.34+[/size] [size=20]or many parts will not work! Enhancements with storage of variables and many other updates have been made in the newer versions, so hence, users with older mIRC versions will experience problems![/size]

Some people I would like to give credits to:

  • Firstmate for giving me crucial advice on a "on sockwrite" event, which allows faster + safer pasting (especially on large pastes).
  • Blitzjager for taking a nice screen-shot for me (since my theme is terrible).

Here's a picture:
Image

Enjoy!

alias pastebin dialog $iif($dialog(pastebin),-v,-m) pastebin pastebin

alias -l ab2word { var %x PasteBin\languages.txt, %y PasteBin\abbreviations.txt | noop $read(%y,w,$1) | return $iif($read(%x,$readn),$v1) }
alias -l between { noop $regex($1,/\Q $+ $2 $+ \E(.*?)\Q $+ $3 $+ \E/gi) | return $regml($4) }
alias -l hex { return $regsubex($1-,/([^\d\w])/gi,$+(%,$base($asc(\1),10,16))) }
alias -l pwrite { var %x $1 | tokenize 124 $2- | write $+(PasteBin\,%x) $* }
alias -l uber { return $replace($regsubex($regsubex($1,/&#(x?([a-f\d]*));/gi,$chr($iif($left(\1,1) == x,$base(\2,16,10),\2))),/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null),&lt;,<,&gt;,>,&quot;,",&amp;,&) }
alias -l word2ab { var %x PasteBin\languages.txt, %y PasteBin\abbreviations.txt | noop $read(%x,w,$1) | return $iif($read(%y,$readn),$v1) }

menu * {
  PasteBin Uploader/Downloader : pastebin
}

dialog pastebin {
  title "Pastebin Uploader / Downloader"
  size -1 -1 454 375
  option dbu
  box "Upload:", 1, 5 2 232 84
  text "Name:", 2, 14 11 16 8
  edit "", 3, 33 10 67 10, autohs limit 24 center
  text "Private sub-domain:", 4, 109 11 49 8
  edit "", 5, 160 10 68 10, autohs limit 50 center
  text "Syntax highlighting:", 6, 26 25 48 8
  combo 7, 81 24 75 62, sort size drop
  check "Private Paste?", 8, 171 24 45 10
  button "Browse file...", 9, 11 51 42 12
  edit "", 10, 61 52 170 10, autohs center
  text "How long should your post be retained?", 11, 19 39 96 8
  radio "a day", 12, 126 38 24 10
  radio "a month", 13, 157 38 30 10
  radio "forever", 14, 195 38 28 10
  button "Preview!", 15, 53 68 50 12
  button "Upload!", 16, 135 68 50 12
  box "Download:", 17, 237 2 213 37
  text "Pastebin URL:", 18, 244 10 34 8
  edit "", 19, 280 9 106 10, autohs center
  check "Load to remotes?", 20, 393 9 52 10
  button "Preview", 21, 273 22 50 12
  button "Download!", 22, 362 22 50 12
  edit "", 23, 5 90 443 261, multi return hsbar vsbar
  box "Information:", 24, 237 36 213 50
  text "", 25, 243 43 201 39
  button "Close Dialog", 26, 38 356 60 14
  button "Clear Screen", 27, 142 356 60 14
  button "Copy to Clipboard", 28, 248 356 60 14
  button "Go to line...", 29, 353 356 60 14
  link "", 30, 256 49 188 7
}

on *:dialog:PasteBin:*:*: {
  if ($devent == init) {
    $iif(!$isdir(PasteBin),mkdir PasteBin)
    if (!$isfile(PasteBin\abbreviations.txt)) || (!$isfile(PasteBin\languages.txt)) {
      $iif($input(Please wait while 72 languages and their abbreviations are being downloaded.,io,Please wait... :-D),dialog -x PasteBin PasteBin)
      hadd -m PasteBin Ticks $ticks | hadd -m PasteBin Version Load
      sockopen pastebin pastebin.com 80
    }
    $iif($dialog(PasteBin),did -a PasteBin 25 $+(Status: Ready!,$crlf,Credits: PasteBin Software developed by Paul Dixon))
    if ($isfile(PasteBin\languages.txt)) {
      loadbuf -o PasteBin 7 Pastebin\languages.txt
      did -c PasteBin 7 47 | did -c PasteBin 13 | did -b PasteBin 5,15-16,21-22
    }
    hadd -m PasteBin Expiry m
  }
  if ($devent == sclick) {
    if ($did == 8) { did $iif($did(8).state,-e,-b) PasteBin 5 }
    if ($did == 9) {
      if ($sfile(*.txt,Choose a file to upload)) {
        var %x 1, %y $did(23).lines, %z $qt($v1)
        while (%x <= %y) {
          if ($did(23,%x)) {
            $iif($input(It appears that text exists in the box. Are you sure you want to continue?,yi,Warning!),did -r PasteBin 23,halt)
            break
          }
          inc %x
        }
        loadbuf -o PasteBin 23 %z
        did -ra PasteBin 10 %z | did -e PasteBin 16 | did -c PasteBin 10 1 | did -cf PasteBin 23 1
      }
    }
    if ($did isnum 12-14) {
      hadd -m PasteBin Expiry $mid($gettok($did($did),$numtok($did($did),32),32),1,1)
      did -a PasteBin 25 $+(Status: Ready!,$crlf,Post Expiry ~ $did($did),:,$chr(32),Good for $iif($did == 12,IRC or IM conversations,$iif($did == 13,email conversations / temporary data,$iif($did == 14,long term archival of useful snippets))))
    }
    if ($did == 15) {
      var %x 1, %y $did(23).lines, %z $qt($did(10))
      while (%x <= %y) {
        if ($did(23,%x)) {
          $iif($input(It appears that text exists in the box. Are you sure you want to continue?,yi,Warning!),did -r PasteBin 23,halt)
          break
        }
        inc %x
      }
      loadbuf -o PasteBin 23 %z
      did -ra PasteBin 10 %z | did -r PasteBin 30 | did -e PasteBin 16 | did -c PasteBin 10 1 | did -cf PasteBin 23 1
    }
    if ($did == 16) {
      savebuf -o PasteBin 23 Pastebin\pb.tmp
      hadd -m PasteBin Ticks $ticks | hadd -m PasteBin Version Upload
      hadd -m PasteBin Tags $+(parent_id=&format=,$word2ab($did(PasteBin,7)),&paste=Send&poster=,$did(PasteBin,3),&expiry=,$hget(PasteBin,Expiry),&code2=)
      sockopen pastebin $+($regsubex($iif(!$did(5).enabled,$null,$iif($did(5) == .,$null,$iif($did(5),$v1,$null))),(^\.(.+)\.$|^(.+)\.$|^\.(.+)$|^(.+)$),$+(\2,.)),pastebin.com) 80
      did -a PasteBin 25 Status: Submitting data towards $+($regsubex($iif(!$did(5).enabled,$null,$iif($did(5) == .,$null,$iif($did(5),$v1,$null))),(^\.(.+)\.$|^(.+)\.$|^\.(.+)$|^(.+)$),$+(\2,.)),pastebin.com) ...
      did -b PasteBin 16,23 | did -r PasteBin 30
    }
    if ($did == 20) { $iif($regex($did(19),^http:\/\/((.*)\.)?(pastebin)\.com\/(\w+)),did $iif($did(20).state,-b,-e) PasteBin 21) }
    if ($did isnum 21-22) {
      var %x 1, %y $did(23).lines
      while (%x <= %y) {
        if ($did(23,%x)) {
          $iif($input(It appears that text exists in the box. Are you sure you want to continue?,yi,Warning!),did -r PasteBin 23,halt)
          break
        }
        inc %x
      }
      noop $regex($did(19),http:\/\/((.*)\.)?(pastebin|pastebin)\.com\/(.*))
      $iif($regml(4),$iif(!$isdir($+(PasteBin\,$regml(2))),mkdir $+(Pastebin\,$regml(2))))
      $iif($did == 22,$iif($isfile($+(PasteBin\,$iif($regml(4),$+($regml(2),\)),$iif($regml(4),$v1,$regml(2)),.txt)),$iif(!$input(The file $qt($iif($regml(4),$v1,$regml(2))) in directory $qt($iif($regml(4),$+(PasteBin\,$regml(2)),PasteBin)) already exists. If you continue the file will be overwritten. Are you sure you want to continue?,yi,Warning!),halt,.remove $+(PasteBin\,$iif($regml(4),$+($regml(2),\)),$iif($regml(4),$v1,$regml(2)),.txt))))
      noop $regex($did(19),http:\/\/((.*)\.)?(pastebin|pastebin)\.com\/(.*))
      hadd -m PasteBin Ticks $ticks | hadd -m PasteBin Version Download | hadd -m PasteBin Method $iif($did == 21,Preview,Download)
      sockopen pastebin pastebin.com 80 | sockmark pastebin $iif($regml(4),$regml(2) $v1,$regml(2))
      did -b PasteBin 15-16,19-23 | did -a PasteBin 25 Status: Connecting to $did(19) ... | did -r PasteBin 30
    }
    if ($did == 26) { dialog -x PasteBin PasteBin }
    if ($did == 27) { did -r PasteBin 3,5,10,19,23 | did -b PasteBin 15-16,21-22 | did -u Pastebin 8,12-14,20 | did -c PasteBin 7 47 | did -c PasteBin 13 | did -a PasteBin 25 $+(Status: Cleared screen!) }
    if ($did == 28) {
      if ($did(23).seltext) {
        did -a PasteBin 25 $+(Status: Copied selected text to clipboard!,$crlf,Size: $bytes($len($v1),b) bytes,$crlf,Number of lines: $iif($count($v1,$crlf),$v1,1))
        clipboard $v1 | halt
      }
      clipboard $null
      var %x 1, %y $did(23).lines
      while (%x <= %y) {
        var %z $calc(%z + ($len($did(23,%x)) + 2))
        clipboard -an $did(23,%x)
        inc %x
      }
      did -a PasteBin 25 $+(Status: Copied all text to clipboard!,$crlf,Size: $bytes(%z,b) bytes,$crlf,Number of lines: $did(23).lines)
    }
    if ($did == 29) {
      var %x $input(Enter a line number $iif($did(23).lines == 1,$null,from 1 to $did(23).lines) to go to...,ei,Go To Line)
      did -cf PasteBin 23 $iif($abs(%x) isnum 1- $did(23).lines,$v1,$iif($abs(%x) > $did(23).lines,$v2,$iif(!$abs(%x),1)))
    }
    if ($did == 30) { clipboard $did(30) }
  }
  if ($devent == rclick) && ($did == 30) { clipboard $did(30) }
  if ($devent == dclick) && ($did == 30) { run $did(30) }
  if ($devent == edit) {
    if ($did == 3) && ($regex($did(3),/[^\w\-]/ig)) { did -ra PasteBin 3 $regsubex($did(3),/([^\w\-])/ig,$null) }
    if ($did == 5) {
      if ($regex($did(5),/[^\w\-\.]/ig)) || ($regex($did(5),/\.{2}/)) { did -ra PasteBin 5 $regsubex($regsubex($did(5),/[^\w\-\.]/ig,$null),/\.{2}/g,.) }
    }
    if ($did == 10) { did $iif($isfile($qt($did(10))),-e,-b) PasteBin 15 }
    if ($did == 19) { did $iif($regex($did(19),^http:\/\/((.*)\.)?(pastebin)\.com\/(\w+)),-e,-b) PasteBin 21-22 }
    if ($did == 23) {
      did $iif($did(23),-e,-b) PasteBin 16
      did -a PasteBin 25 $+(Status: Ready!,$crlf,Note: To highlight particular lines,$chr(44),$chr(32),prefix each line with @@)
    }
  }
  if ($devent == close) { hfree PasteBin | unset %pb }
}

on *:sockopen:pastebin: {
  if ($hget(PasteBin,Version) == Download) || ($hget(PasteBin,Version) == Load) {
    tokenize 32 $sock(pastebin).mark
    sockwrite -n $sockname GET $+(/,$iif(!$1,$null,$iif(!$2,$1,$2))) HTTP/1.1
    sockwrite -n $sockname Host: $+($iif(!$1,$null,$iif($2,$+($1,.))),pastebin.com)
    sockwrite -n $sockname $crlf
  }
  elseif ($hget(PasteBin,Version) == Upload) {
    var %x 1, %y $did(PasteBin,23).lines
    while (%x <= %y) {
      var %z $calc(%z + $len($hex($did(PasteBin,23,%x))))
      inc %x
    }
    sockwrite -n $sockname POST /pastebin.php HTTP/1.1
    sockwrite -n $sockname Host: $+($regsubex($iif(!$did(Pastebin,5).enabled,$null,$iif($did(PasteBin,5) == .,$null,$iif($did(PasteBin,5),$v1,$null))),(^\.(.+)\.$|^(.+)\.$|^\.(.+)$|^(.+)$),$+(\2,.)),pastebin.com)
    sockwrite -n $sockname Content-Type: application/x-www-form-urlencoded
    sockwrite -n $sockname Content-length: $calc($len($hget(PasteBin,Tags)) + %z + (3 * %y))
    sockwrite $sockname $crlf
    sockwrite $sockname $hget(PasteBin,Tags)
    hinc -m PasteBin Buffer
  }
}

on *:sockwrite:pastebin: {
  if ($hget(PasteBin,Version) == Upload) && ($hget(PasteBin,Buffer) <= $did(PasteBin,23).lines) {
    sockwrite $sockname $+($hex($did(PasteBin,23,$hget(PasteBin,Buffer))),%,0A)
    hinc -m PasteBin Buffer
  }
}

on *:sockread:pastebin: {
  tokenize 32 $sock(pastebin).mark
  sockread %pb
  if (!$1) {
    if ($regex(%pb,<select name="format">)) && ($hget(PasteBin,Version) == Load) {
      var %x $regsubex($between(%pb,$+($str(-,28),</option>),</select>,1),/<option value="(.*?)">(.*?)</option>/g,$+(\1,$chr(124))), %y $regsubex($between(%pb,$+($str(-,28),</option>),</select>,1),/<option value="(.*?)">(.*?)</option>/g,$+(\2,$chr(124)))
      pwrite abbreviations.txt %x | pwrite languages.txt %y
      sockclose pastebin
      dialog -m PasteBin PasteBin
      did -a PasteBin 25 $+(Status: Downloaded text files,$crlf,Total estimated time: $calc(($ticks - $hget(PasteBin,Ticks))/1000) seconds)
    }
    elseif ($regex(%pb,Location:(.*))) && ($hget(PasteBin,Version) == Upload) {
      sockclose pastebin
      did -a PasteBin 25 $+(Status: File uploaded,$crlf,Link:,$crlf,Size: $bytes($file(PasteBin\pb.tmp),b) bytes,$crlf,Number of lines: $did(PasteBin,23).lines,$crlf,Total estimated time: $calc(($ticks - $hget(PasteBin,Ticks))/1000) seconds)
      did -a PasteBin 30 $regml(1) | did -e PasteBin 16,23 | did -cf Pastebin 23 1
      .remove PasteBin\pb.tmp
    }
  }
  elseif ($1) {
    if ($regex(%pb,<title>(.*)\s+pastebin\s+-)) { hadd -m PasteBin Type $regml(1) | did -a PasteBin 25 Status: Buffering $did(PasteBin,19) ... }
    if ($regex(%pb,<h1>(.*)<br/><a href="#")) { hadd -m PasteBin Info $uber($regml(1)) }
    if ($regex(%pb,<div class="de[\d]">(.*)</div>)) || ($regex(%pb,<li class="li[\d]"><div class="de[\d]">(.*)</div>)) {
      hadd -m PasteBin Directory $qt($+(PasteBin\,$iif($2,$+($1,\)),$iif(!$2,$1,$2),$iif(!$2,$+($iif($hget(PasteBin,Type),$+($chr(32),$+($chr(40),$v1,$chr(41)))),$iif($did(PasteBin,20).state,.mrc,.txt)),$iif($did(PasteBin,20).state,.mrc,.txt))))
      var %x $uber($regml(1))
      $iif($hget(PasteBin,Method) == Download,write $hget(PasteBin,Directory) $+($replace(%x,&nbsp;,$iif($count(%x,&nbsp;) != $numtok(%x,32),$chr(32))),$crlf))
      did -a PasteBin 23 $+($replace(%x,&nbsp;,$iif($count(%x,&nbsp;) != $numtok(%x,32),$chr(160))),$crlf)
    }
    if ($regex(%pb,</h1><ul><li>(.*)</li>)) || ($regex(%pb,(.*)<P>)) {
      sockclose pastebin
      did -a PasteBin 25 $+(Status: Ready!,$crlf,Error: Could not download $qt($+(http://,$iif($2,$1),pastebin.com/,$iif($2,$v1,$1))) - $regml(1))
      did -e PasteBin 16,19-23 | did -f PasteBin 23
    }
    if ($regex(%pb,<select name="format">)) {
      sockclose pastebin
      did -e PasteBin 16,19-23 | did -i PasteBin 23 1 | did -d PasteBin 23 1 | did -d PasteBin 23 $did(PasteBin,23).lines
      did -a PasteBin 25 $+(Status: $iif($hget(PasteBin,Method) == Download,$iif($did(PasteBin,20).state,Loaded script $+($chr(35),$script(0),:),Downloaded to:) $hget(PasteBin,Directory),Now previewing),$crlf,Link:,$crlf,PasteBin Type: $iif($hget(PasteBin,Type),$v1,None),$crlf,PasteBin Info: $hget(PasteBin,Info),$crlf,Total estimated time: $calc(($ticks - $hget(PasteBin,Ticks))/1000) seconds)
      did -a PasteBin 30 $did(PasteBin,19) | did -c PasteBin 19 1 | did -cf Pastebin 23 1
      $iif($did(PasteBin,20).state,.load -rs $qt($+($mircdir,$noqt($hget(PasteBin,Directory)))))
    }
  }
}

Comments

Sign in to comment.
Saigyouji   -  Jun 04, 2010

Oh I see. Thanks for letting me know.

 Respond  
sunslayer   -  Jun 03, 2010

@Saigyouji
www.pastebin.com changed owners and the site has been completely remade this snippet doesn't work anymore

 Respond  
Saigyouji   -  Jun 03, 2010

Kirby. 72 languages are being downloaded... that message appears forever. I've waited for 12 hours already.

 Respond  
sixkilur   -  Sep 22, 2009
  • /did: invalid parameters (line 201, pastebin3.mrc)

  • /did: invalid parameters (line 201, pastebin3.mrc)
  • /did: invalid parameters (line 201, pastebin3.mrc)
  • /did: invalid parameters (line 201, pastebin3.mrc)
  • /did: invalid parameters (line 201, pastebin3.mrc)
  • /did: invalid parameters (line 201, pastebin3.mrc)
    wich would be this line
did -a PasteBin 25 $+(Status: Downloaded text files,$crlf,Total estimated time: $calc(($ticks - $hget(PasteBin,Ticks))/1000) seconds)

does that 72 times the abbrev.txt creation i think
i was able to change the line 209
did -a to did -f and it seems to be working good now. nice script
could use some work.

 Respond  
SudsyUncle   -  May 28, 2009

/me is too lazy to edit for width

 Respond  
Kirbeh_Pr0nz   -  May 28, 2009

coughtoo widecough x3

 Respond  
iCub   -  May 28, 2009
&& 10/10 P.S- Needs more porn
 Respond  
SudsyUncle   -  May 28, 2009

for those with mini screens:

dialog pastebin {
  title "Pastebin Uploader / Downloader"
  size -1 -1 454 204
  option dbu
  box "Upload:", 1, 5 2 232 84
  text "Name:", 2, 14 11 16 8
  edit "", 3, 33 10 67 10, autohs limit 24 center
  text "Private sub-domain:", 4, 109 11 49 8
  edit "", 5, 160 10 68 10, autohs limit 50 center
  text "Syntax highlighting:", 6, 26 25 48 8
  combo 7, 81 24 75 62, sort size drop
  check "Private Paste?", 8, 171 24 45 10
  button "Browse file...", 9, 11 51 42 12
  edit "", 10, 61 52 170 10, autohs center
  text "How long should your post be retained?", 11, 19 39 96 8
  radio "a day", 12, 126 38 24 10
  radio "a month", 13, 157 38 30 10
  radio "forever", 14, 195 38 28 10
  button "Preview!", 15, 53 68 50 12
  button "Upload!", 16, 135 68 50 12
  box "Download:", 17, 237 2 213 37
  text "Pastebin URL:", 18, 244 10 34 8
  edit "", 19, 280 9 106 10, autohs center
  check "Load to remotes?", 20, 393 9 52 10
  button "Preview", 21, 273 22 50 12
  button "Download!", 22, 362 22 50 12
  edit "", 23, 5 90 443 91, multi return hsbar vsbar
  box "Information:", 24, 237 36 213 50
  text "", 25, 243 43 201 39
  button "Close Dialog", 26, 44 187 60 14
  button "Clear Screen", 27, 148 187 60 14
  button "Copy to Clipboard", 28, 254 187 60 14
  button "Go to line...", 29, 359 187 60 14
  link "", 30, 256 49 188 7
}
 Respond  
Kirbeh_Pr0nz   -  May 28, 2009

wait.....still too big :P

 Respond  
Kirbeh_Pr0nz   -  May 28, 2009

ooooh ok thx

 Respond  
MaxEvans   -  May 28, 2009

Neptune^ posted this, and it works really well. I had the same problem, I have a widescreen resolution and I couldn't see the bottom buttons. But this one fixes it. Here's the code again.

dialog pastebin {
  title "Pastebin Uploader / Downloader"
  size -1 -1 386 283
  option dbu
  box "Upload:", 1, 2 0 226 72
  text "Name:", 2, 11 9 16 8
  edit "", 3, 30 8 67 10, autohs center limit 0
  text "Private sub-domain:", 4, 101 10 49 8
  edit "", 5, 152 9 68 10, autohs center limit 0
  text "Highlighting:", 6, 11 22 33 8
  combo 7, 44 20 75 60, size drop
  check "Private Paste?", 8, 122 21 45 10
  button "Browse file...", 9, 184 45 42 11
  edit "", 10, 12 46 170 10, autohs center
  text "How long should your post be retained?", 11, 12 35 96 8
  radio "a day", 12, 110 34 24 10
  radio "a month", 13, 134 34 30 10
  radio "forever", 14, 165 34 28 10
  button "Preview!", 15, 11 57 50 12
  button "Upload!", 16, 63 57 50 12
  box "Download:", 17, 231 0 153 30
  text "Pastebin URL:", 18, 238 7 34 8
  edit "", 19, 274 6 106 10, autohs center
  check "Load to remotes?", 20, 238 17 52 10
  button "Preview", 21, 299 17 40 11
  button "Download!", 22, 340 17 40 11
  edit "", 23, 2 74 382 195, multi return hsbar vsbar
  box "Information:", 24, 231 30 153 42
  text "", 25, 237 37 144 32
  button "Close Dialog", 26, 139 270 60 12
  button "Clear Screen", 27, 201 270 60 12
  button "Copy to Clipboard", 28, 263 270 60 12
  button "Go to line...", 29, 325 270 60 12
  link "", 30, 250 43 125 7
}
 Respond  
Kirbeh_Pr0nz   -  May 28, 2009

Im not good with dialogs, is there a way to make it vertically smaller? i cant see the bottom buttons. o_o;

 Respond  
Kirby   -  May 27, 2009

WorldDMT said:

u can use isin and $remove dont need to use a regex for a smal thing like thatAlthough this controversy is quite over, I'd also like to add the reason why I prefer using $regex in my sockread is because not only do I use it for detection, it's easier for me to make the use of a single $regml(N) than using many $gettok and $htmlfree.

 Respond  
Ayon   -  May 24, 2009

:)

 Respond  
Kirby   -  May 24, 2009

[size=20]@Kirbeh_Pr0nz[/size]
The reason why

http://pastebin.blahblah.com/blah

doesn't work is because that would mean that "blahblah.com" would be the domain, and not "pastebin.com".

 Respond  
^Neptune   -  May 24, 2009

Ayon, shut the fύck up.

 Respond  
Kirbeh_Pr0nz   -  May 23, 2009

I love it! coughalittletoobigcough but i love it.
one fault i found=> when ever i tried to enter pastebin url, it wouldnt wirk, i think due to the fact that it only accepts "http://blahblah.pastebin.com/blah" format. yet, some urls have "http://pastebin.blahblah.com/blah" format, which the snippet wont read.
is there anything i need to do to get it to work?

 Respond  
Prelude   -  May 23, 2009

Ayon
Comments: 4

mIRC Snippet: Kirby's PasteBin Uploader/Downloader
Posted on May 21, 2009 5:15 am
great one!

btw why complain about the size? how hard is it to change the size yourself?

That was a direct comment to ^Neptune about the size:

^Neptune
Comments: 556

mIRC Snippet: Kirby's PasteBin Uploader/Downloader
Posted on May 20, 2009 9:51 am
Dialog is WAY too big, it won't even fit on my screen.

Then you go on to say:

@Blitzjager: Yeah if you re-arrange the words, strip and add some letters it sais "I have nothing else to do, than to sit on hawkee and bash on other peoples comments"

So who has nothing better to DO then sit on hawkee and bash other pplz comment?, dumb dumb you where the first to DO it. As for my so called ''bashing'' of your comment LOL hardly what i would consider ''bashing''kid...

Also i ve made constructive comments on here cause i know kirby and he did a good job, it's the ppl like YOU who start dumb shiit and go on to bash other ppls comments that trigger me to reply, lack of self control...maybe, but you bring it on yourself after all ;).

Also i am not making scripts, i posted 1 pos snippet in god knows how long i've been here, im here to support the REAL scriptors (like kirby), not big mouth lil shiits that just think they are clever, or ppl who post crap and do not take criticism and help, that just post to post and fail at that simple task.

So instead of tryin to go back and forth with me, you could have just said its a good code ETC, even hell threw in a dialog edit of your own... Till the next time kids....

 Respond  
Blubble   -  May 23, 2009

Very nice script I must say. 9/10 + like
EDIT: Removed something after reading rest of the comments.

 Respond  
Ayon   -  May 23, 2009

@Prelude: Yeah I'm a nerd :) not afraid to admit that, but hey... you're making scripts as well ;) as long as you do any types of programming you are considered a nerd :) No shame in that.. It's a part of living in 2009 :)

@Blitzjager: Yeah if you re-arrange the words, strip and add some letters it sais "I have nothing else to do, than to sit on hawkee and bash on other peoples comments"

 Respond  
Blitzjager   -  May 23, 2009

Do the capitalized words make a hidden message?

 Respond  
Prelude   -  May 22, 2009

lol@

Ayon
Comments: 6

mIRC Snippet: Kirby's PasteBin Uploader/Downloader
Posted on May 22, 2009 12:16 pm
@Prelude: haha... why redo everything? why not just copy paste the dialog source into an editor? then you wont have to do nothing else than move the items around to fit your liking... or is copy paste to hard for you moron? ;)

Took me about 30 seconds to make it fit my screen more properly than the original :)

Actually tosser it took me less then 10 seconds to edit this in DE you fuúckin fag, it WASN'T a comment about ME and my ability to edit this, it was IN GENERAL, for those who would still like to USE this code but DO NOT have a editor, cause frankly NOT all of us use mirc to SCRIPT (or live on IRC like some;))...so for those who DO NOT, it is unlikely they OWN a dialog EDITOR to EDIT so in turn they WOULD have to edit by trial and error;p, which tbh they should NOT have to, gd nerd why dont you scroll the fuúck UP and see i pasted the fuúcking EDIT in the same comment, for those who DO NOT have a editor for dialogs to COPY AND PASTE, or you can sit at your comp and run your face... you're just another reason stupid ppl should breathe (or breed) you pick ;). Fuúckin IRC kiddies...

Stick to IRC kid, it's about the only thing you may be good at, A+ ;), have a goodin'

 Respond  
MaxEvans   -  May 22, 2009

Only one thing I would like added to this is a field for your name so you could delete the post like on the site. The rest is really great.

 Respond  
ProIcons   -  May 22, 2009

Well maybe i am Crazy:D

10/10

 Respond  
Ayon   -  May 22, 2009

@MaxEvans: x2

 Respond  
MaxEvans   -  May 22, 2009

@Rev I'd like to see you try to make something like this. This is a very helpful script to a lot of us. Including me.

 Respond  
Ayon   -  May 22, 2009

@Prelude: haha... why redo everything? why not just copy paste the dialog source into an editor? then you wont have to do nothing else than move the items around to fit your liking... or is copy paste to hard for you moron? ;)

Took me about 30 seconds to make it fit my screen more properly than the original :)

 Respond  
RevJohn Straub   -  May 21, 2009

this script isnt kirbyish

 Respond  
Blitzjager   -  May 21, 2009

I agree. :P

 Respond  
Firstmate   -  May 21, 2009

Why do you say that Rev?

 Respond  
Are you sure you want to unfollow this person?
Are you sure you want to delete this?
Click "Unsubscribe" to stop receiving notices pertaining to this post.
Click "Subscribe" to resume notices pertaining to this post.