;Fabric
;Made by BlueThen on May 9th, 2009.
;To install, paste the script in your Remotes (alt + r)
;Then type /fabric or right click the channel or status and click "Fabric"
menu channel,status {
  Fabric: Fabric
}
alias Fabric {
  window -paoCzdk0 +tnbL @Fabric -1 -1 400 400
  %fab.z = 1
  %fab.x = 12
  while (%fab.x) {
    %fab.y = 12
    while (%fab.y) {
      hadd -m X %fab.z $calc(16* %fab.x)
      hadd -m Z %fab.z $calc(16* %fab.y)
      hadd -m D %fab.z $fab.d($hget(x,%fab.z), $hget(z,%fab.z),96,96)
      inc %fab.z
      dec %fab.y
    }
    dec %fab.x
  }
  set %fab.a 1
  fab.frame
}
alias -l fab.frame {
  if ($window(@fabric)) {
    clear -n @fabric
    drawfill -n @fabric 1 1 1 1
    %fab.z = 144
    while (%fab.z) {
      %fab.y = $calc(150+15* $sin($calc(%fab.a + $hget(D, %fab.z)*3)).deg)
      %fab.r = $calc(127.52+127.52* $sin($calc(%fab.a + $hget(D, %fab.z)*3)).deg)
      drawdot -nr @fabric $rgb(%fab.r,%fab.r,%fab.r) 5 $fab.iso($hget(x,%fab.z),%fab.y,$hget(z,%fab.z)) 
      dec %fab.z
    }
    dec %fab.a 10
    drawline @fabric
    .timer 1 0 fab.frame
  }
  else {
    unset %fab.*
    hfree X
    hfree Z
    hfree D
  }
}
alias fab.iso return $calc(($1 - $3)*0.866+200) $calc(($1 + $3)*0.5- $2 +230)
alias fab.d return $calc((($3 - $1)^2+($4 - $2)^2)^0.5)