Tired of finding snippets on here and having to manually copy, paste, and load them? Well Your troubles are over! This is the LAST snippet you will EVER have to copy/paste! Just right click in ANY window and choose HAWKEE. If you have already copied the URL to your clipboard it will be displayed in the prompted dialog, but if not then a URL in the appropirate dialog will be displayed.

To Use:

1. Open the Script Editor (->Tools ->Script Editor)
2. Create a NEW file called HAWKEE (From Script Editor: ->File ->New)
3. Paste in this snippet and hit OK (or ->File ->Save)
4. Rightclick in any window and click HAWKEE.
5. Paste the desired snippet URL into the prompted dialog and it automatically downloads the snippet to whatever directory this snippet is saved to. You then have the option to load the snippet.

Comments/bug reports/feedback appreciated! TY!

;Hawkee Snippet Ripper v1.0 script by pope
;PEERCOMMONS chat.peercommons.net 6667
;#scripters.united
;
menu * { 
  HAWKEE: {
    if (hawkee.com/snippet !isin $cb(1)) {
      clipboard www.hawkee.com/snippet/XXX
    }
    set %hawkeepage $cb(1)
    dialog -mo hawkeepage hawkeepage
  }
}
;HAWKEE PAGE DIALOG
dialog hawkeepage {
  title "What Site?"
  size -1 -1 130 42
  option dbu 
  text "Enter The URL To The Snippet Here", 1, 23 5 85 10
  edit $cb(1), 2, 13 14 105 10, autohs
  button "Add", 3, 42  28 20 10, ok
  button "Close", 4, 68 28 20 10, cancel
}
on *:dialog:hawkeepage:edit:2:{
  set %hawkeepage $did(hawkeepage,2).text 
}
on *:dialog:hawkeepage:sclick:3: {
  if (hawkee.com/snippet/ !isin %hawkeepage) {
    dialog -mo invalidadd invalidadd
    halt
  }
  set %next 0
  set %hawkeepage $remove(%hawkeepage,http://,www,hawkee,.,com)
  if ($sock(gethawkee)) {
    .sockclose gethawkee
  }
  sockopen gethawkee www.hawkee.com 80
}
;INVALID PAGE DIALOG
dialog invalidadd {
  title "Invalid Address"
  size -1 -1 90 30
  option dbu 
  text "That's Not A Valid Hawkee Page", 1, 7 5 78 14
  button "Close", 2, 35 15 20 10, cancel
}
;LOAD DIALOG
dialog doneload {
  title "Script Successfully Saved!"
  size -1 -1 65 30
  option dbu 
  text "Load Into Remotes?", 1, 9 5 78 14
  button "Load", 2, 10 15 20 10, ok
  button "Close", 3, 35 15 20 10, cancel
}
on *:dialog:doneload:sclick:*: {
  if ($did == 2) {
    .load -rs $qt($scriptdir $+ %filename $+ .mrc)
    echo -a 4 %filename $+ .mrc Successfully Loaded!
  }
  if ($did == 3) {
    echo -a 4 %filename $+ .mrc Successfully Saved But Not Loaded!
  }
}
;
;SOCKET
on *:SOCKOPEN:gethawkee: {
  echo -a 4Saving Snippet. Download Time Varies Depending On Length Of Snippet...
  sockwrite -nt $sockname GET %hawkeepage HTTP/1.1
  sockwrite -nt $sockname Host: www.hawkee.com
  sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:gethawkee: {
  if ($sockerr) {
    echo -a -a SOCKET ERROR: $sockerr
    halt
  }
  else {
    var %hawkee
    sockread %hawkee
    if (<title> isin %hawkee) {
      set %filename $remove(%hawkee,<title>,- mIRC Code Snippet</title>,",/,\,:,*,?)
    }
    if (<h2> isin %hawkee) {
      tokenize 62 %hawkee
      write -l1 $qt($scriptdir $+ %filename $+ .mrc) ; $+ %filename by $remove($2,</h2) http://www.hawkee.com $+ %hawkeepage
      write -il2 $qt($scriptdir $+ %filename $+ .mrc) ;Downloaded From Hawkee Via Hawkee Snippet Ripper v1.0 http://www.hawkee.com/snippet/5705/
      dialog -mo doneload doneload
      sockclose gethawkee
    }
    if (</textarea isin %hawkee) {
      set %next 2
    }
    if (%next == 1) {
      write $qt($scriptdir $+ %filename $+ .mrc) $replace(%hawkee,&quot;,",&gt;,>,&lt;,<,&amp;,&)
    }
    if ((<textarea isin %hawkee) && (%next != 2)) {
      tokenize 62 %hawkee
      write -c $qt($scriptdir $+ %filename $+ .mrc) xxx
      write $qt($scriptdir $+ %filename $+ .mrc) $replace($2,&quot;,",&gt;,>,&lt;,<,&amp;,&)
      set %next 1
    }
  }
}