for those who didnt read the title: this script isnt mine, it seemed good so i decided to put it on here :)

ok, this is the trackuser script i use, its a good one, i got it from: http://de.saegher.be/wim/files/trackusers.mrc

I thought it was good and deserved to be on here.

intructions:
Chuck into a new page of remotes o_O
/hmake trackusers 10

not too sure about those really, got this ages ago..

; Konerak version.
on *:start: {
  hmake trackusers 10
  if ($isfile(trackusers.dat)) {
    hload trackusers trackusers.dat
  }
}
on *:OPEN:?: {
  echo $color(topic) -t $nick * Now talking to: $address at $date $+ .
  if ($hget(trackusers,$address($nick,2))) {
    var %n = $ifmatch
    if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
    else { var %d = %n }
    if (!%d) { goto notknown }
    echo $color(topic) -t $nick # * Also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
  }
  else {
    :notknown
    if (-sBNC != $nick) {    
      echo $color(topic) -t $nick # * $nick doesn't have any other nicknames
    }
  }
}
on *:JOIN:#: {
  if ($me !== $nick) {
    if ($hget(trackusers,$address($nick,2))) {
      var %n = $ifmatch
      if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
      else { var %d = %n }
      if (!%d) { return }
      echo $colour(join) -ti2 $chan * $nick has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
      if (!$istok(%n,$nick,32)) {
        if ($numtok(%n,32) >= 15) %n = $gettok(%n,-14--1,32)
        hadd trackusers $address($nick,2) %n $nick
      }
    }
    else {
      hadd trackusers $address($nick,2) $nick
    }
  }
}
on *:NICK: {
  if ($hget(trackusers,$address($newnick,2))) {
    var %n = $ifmatch
    if (!$istok(%n,$newnick,32)) {
      if ($numtok(%n,32) >= 15) %n = $gettok(%n,-14--1,32)
      hadd trackusers $address($newnick,2) %n $newnick
    }
  }
  else {
    hadd trackusers $address($nick,2) $newnick
  }
}
menu Nicklist {
  Track Users
  .View Other Nicknames:{
    if (!$address($$1,2)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
    if ($hget(trackusers,$address($$1,2))) {
      var %n = $ifmatch
      if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
      else { var %d = %n }
      if (!%d) { goto notknown }
      echo $colour(join) -ti2 # * $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
    }
    else {
      :notknown
      echo $colour(join) -ti2 # * $$1 has not been known by any other nickname
    }
  }
  .-
  .Reset
  ..OK:hdel trackusers $address($$1,2)
}
ON *:EXIT: {
  if ($hget(trackusers)) { hsave -o trackusers trackusers.dat }
}
alias tu {
  if (!$address($$1,2)) { echo $colour(info) -a # IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
  if ($hget(trackusers,$address($$1,2))) {
    var %n = $ifmatch
    if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
    else { var %d = %n }
    if (!%d) { goto notknown }
    echo $colour(join) -a # $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
  }
  else {
    :notknown
    echo $colour(join) -a # $$1 has not been known by any other nickname
  }
}
alias gn {
  if ($hget(trackusers,$$1)) {
    var %n = $ifmatch
    if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
    else { var %d = %n }
    if (!%d) { goto notknown }
    echo $colour(join) -ti2 # * $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
  }
  else {
    :notknown
    echo $colour(join) -ti2 # * $$1 has not been known by any other nickname
  }
}
raw 312:*:{ tu $$2 }