Botserv Copy-Cat Skript copies users text in a channel with a 10 second delay between each user.

Pointless Script unless you enjoy the occassional humour every now and then.
Use once, twice have a laugh but after that add it to your white-elephant script folder for reference to other scripts in the future.

Instructions:

1. Load into your Remote Section as a new file in your Script Editor "Alt + R"

Usage:
Aliases: - /cchelp ; /ccname ; /ccchan ; /ccon ; ccoff or F Key Setup (F9 and F10 Default)
Menu: Command Menu Bar

;**************Botserv copy-cat script**********
; Services Botserv Skript that copies text entered in chose channel.
; Set bot name used by botserv services.
; Set channel name in the Input Box as #channelname.
; You can use the alises /cchelp /ccon and /ccoff etc. or the menu in your menu (Command) bar.
; Edit Your F keys if you like for ease of use.
; *NB - Do not abuse, for this I have added flood protection of 10 Seconds per user - Usage: ;Just to freak people out ;)

on *:LOAD:{ 
  echo -a Botserv Copy-Cat Skript Installed.
  echo -a You can use the alises /cchelp /ccon and /ccoff etc. or the menu in your menu (Command) bar
  echo -a Remember to set a channel and the name of the services (botserv) bot.
}
on *:UNLOAD: {
  .unset %cc*
  echo -a Botserv Copy-Cat Script Uninstalled.
}

;Aliases - You can edit the F key values for ease of use
alias F9 { enable #copy-cat }
alias F10 { disable #copy-cat }
alias cchelp { echo Copy Cat Aliases: /ccon /ccoff /ccname /ccchan } 
alias ccon { enable #copy-cat }
alias ccoff { disable #copy-cat }
alias ccname { set %ccbotname $?="Enter Bot Name?" | echo 4 Copy Cat Bot name set to %ccbotname }
alias ccchan { set %ccchannel $?="Enter Channel?" | echo 4 Copy Cat channel set to %ccchannel }

menu menubar { 
  -
  Botserv Copy-Cat Script
  .$iif($group(#copy-cat).status iswm on, Copy-Cat is ON, Copy-Cat is OFF) 
  ..Set Botname:set %ccbotname $?="Enter Bot Name?" | echo 4 Copy Cat Bot name set to %ccbotname
  ..Set Channel:set %ccchannel $?="Enter Channel?" | echo 4 Copy Cat channel set to %ccchannel
  ..Turn copycat off:disable #copy-cat
  ..Turn copycat on:enable #copy-cat
  .About Botserv Copy-Cat Skript:echo -a 14Created by 4Kasbah 2008
  -
}

#copy-cat off
on *:ACTION:*:%ccchannel: { 
  if (!%ccbotname) { echo -a 4Please Enter a Services Bot Nick | halt }
  if ( %ccflood [ $+ [ $address($nick,2) ] ] != on) {
    if ($nick == %ccbotname) { halt }
    var %text $replace($1-,%ccbotname,$nick)
    bs say $chan %text
    set -u10 %ccflood [ $+ [ $address($nick,2) ] ] on
  }
}
on *:TEXT:*:%ccchannel: { 
  if (!%ccbotname) { echo -a 4Please Enter a Services Bot Nick | halt }
  if ( %ccflood [ $+ [ $address($nick,2) ] ] != on) {
    if ($nick == %ccbotname) { halt }
    var %text $replace($1-,%ccbotname,$nick)
    bs say $chan %text
    set -u10 %ccflood [ $+ [ $address($nick,2) ] ] on
  }
}
#copy-cat end