I recently got a little bored with my usual mIRC layout so I opted to make it look as minimalistic as possible (disabling the display of the menubar, toolbar, and switchbar).
Since I disabled the switchbar I wanted to retain a way to switch channels with the mouse so I decided to write up this little snippet.

I glanced through Hawkee and didn't see a snippet like it, so I figured I'd post it. It's not exactly the most practical snippet, but it's a simple alternative to the switchbar.

To install, just copy the snippet into your remotes tab. To use it, right click in any window, expand the Window Select menu > Channels or PM/Query submenu and select the window you'd like to activate.

Edit: Updated to include Query windows.

menu * {
  -
  Window Select
  .Channels
  ..$submenu($wm_fill(c,$1))
  .PM/Query
  ..$submenu($wm_fill(q,$1))
  -
}
alias -l wm_achk { 
  if ($scon($1) == $activecid && $2 isin $window($active)) { return $style(1) } 
}
alias -l wm_fill { 
  var %n = 0, %nc = $scon(0), %cm = 0, %qm = 0
  while (%n < %nc) {
    inc %cm | inc %n
    scon %n
    var %c = 0, %cc = $chan(0), %q = 0, %qc = $query(0)
    var %c_ [ $+ [ %cm ] ] $wm_achk(%n,Status) $&
      $+([,$network,]) Status $+ : scon %n $chr(124) window -a "Status Window"
    while (%c < %cc) { 
      inc %cm | inc %c
      var %c_ [ $+ [ %cm ] ] $wm_achk(%n,$chan(%c)) $&
        $chan(%c) $+ : scon %n $chr(124) window -a $chan(%c)
    }
    while (%q < %qc) { 
      inc %qm | inc %q
      var %q_ [ $+ [ %qm ] ] $wm_achk(%n,$query(%q)) $&
        $+([,$network,]) $query(%q) $+ : scon %n $chr(124) window -a $query(%q)
    }
  }
  return $iif($1 == c,%c_ [ $+ [ $2 ] ],%q_ [ $+ [ $2 ] ])
}