For the heck of it, I made an entirely new version of Clock. It's now a lot cleaner and smoother.
;Clock 2.0
;Made by BlueThen on July 20, 2008
;To install, paste this snippet in your remotes (Alt + R)
;Then type /clock2 or right click the channel or status and click "Clock2".
alias clock2 { echo -a Clock 2 made by BlueThen ( http://www.bluethen.com/ for more scripts and snippets )
window -paozCdk0 +ndL @Clock2 -1 -1 150 150 | window -paohCzdk0 +ndL @clock2.buf -1 -1 800 800 | unset %clock2.c | clock2.frame
}
menu channel,status {
Clock 2: clock2
}
alias clock2.frame {
if (%clock2.c != y) {
clear @clock2.buf | drawfill -r @clock2.buf $rgb(1,1,1) $rgb(1,1,1) 1 1 | drawdot @clock2.buf 1 300 400 450
drawdot -r @clock2.buf $rgb(150,100,0) 290 400 450 | drawline @clock2.buf 1 7 0 100 1000 100
drawfill -r @clock2.buf $rgb(120,70,0) $rgb(0,0,0) 1 1 | drawline -r @clock2.buf 1 7 670 100 670 -100
drawrect -rf @clock2.buf $rgb(130,80,10) 1 670 0 300 100 | drawtext @clock2.buf 1 Tahoma 100 697 -18 ×
%clock2.xy = 12
while (%clock2.xy) {
if (. isin $calc(%clock2.xy /3)) {
drawdot -r @clock2.buf $rgb(100,50,0) 8 $calc(400 + (270 * $cos($calc(30 * %clock2.xy)).deg)) $calc(450 + (270 * $sin($calc(30 * %clock2.xy)).deg))
}
else {
drawtext -r @clock2.buf $rgb(100,50,0) Tahoma 80 $calc((400 + (240 * $cos($calc((%clock2.xy * 30) -90)).deg)) - ($width(%clock2.xy ,Tahoma,80) /2)) $calc((450 + (240 * $sin($calc((30* %clock2.xy)-90)).deg)) - ($height(%clock2.xy ,Tahoma,80) /2)) %clock2.xy
}
dec %clock2.xy
}
drawline -r @clock2.buf $rgb(100,50,0) 8 400 450 $calc(400 +(200 * $cos($calc((6 * $asctime(s)) - 90)).deg)) $calc(450 +(200 * $sin($calc((6 * $asctime(s)) - 90)).deg))
drawline -r @clock2.buf $rgb(100,50,0) 12 400 450 $calc(400 +(200 * $cos($calc((6 * $asctime(n)) - 90)).deg)) $calc(450 +(200 * $sin($calc((6 * $asctime(n)) - 90)).deg))
drawline -r @clock2.buf $rgb(100,50,0) 16 400 450 $calc(400 +(150 * $cos($calc((30 * $asctime(h)) - 90)).deg)) $calc(450 +(150 * $sin($calc((30 * $asctime(h)) - 90)).deg))
drawtext -r @clock2.buf $rgb(80,30,0) Tahoma 80 30 0 $asctime(h:nn:ss TT)
drawcopy -m @clock2.buf 0 0 800 800 @clock2 0 0 150 150 | .timer 1 1 clock2.frame
}
else unset %clock2.c
}
on *:close:@clock2: clock2.close
menu @clock2 {
sclick: {
if ($calc($mouse.y * 5.3333) < 100) {
if ($calc($mouse.x * 5.3333) > 670) clock2.close
else {
set %clock2.dx $calc($window(@clock2).dx - $mouse.dx)
set %clock2.dy $calc($window(@clock2).dy - $mouse.dy) | .timermove -h 0 0 clock2.move
}
}
}
uclick: { .timermove off }
leave: { .timermove off }
}
alias -l clock2.move window @clock2 $calc($mouse.dx + %clock2.dx) $calc($mouse.dy + %clock2.dy)
alias -l clock2.close unset %clock2.* | set %clock2.c y | if ($window(@clock2)) window -c @clock2 | window -c @clock2.buf