Typo's Deal Tracker is a really cool script that gathers and displays well over 1,000 separate offers from a Deal Of the Day (DOD) site and a great Deal Tracking forum.

The script has two sections, the first is 4 pages long and the second is 6 pages long. They both have really cool deals but they are displayed a little differently.

The first part is from a Deal Of The Day website and you will be linked directly to the items webpage.

The second page is from a Deal Tracking Forum and you will be linked to the thread where the offer is being discussed. You can link to the site that has the offer or view what everyone else is saying about the deal. These deals may possibly include rebates or promotional coupon codes which is why you are linked to the thread for the item.

If your interested in something just double click it and the webpage will be opened.

The deals you can expect to find can be for anything from electronics to clothes to computer parts to couches and so on. - The deals are updating all the time so you never know what your going to see next time you look.

Enjoy

Typo

And now one of the two older screenshot to show it before El's suggestion.

;Title  "Typos Deal Tracker"
menu nicklist,query,channel,status {
  -
  <[Typos Deal Tracker]>:{ 
    if ($dialog(DealTracker) == $null) { dialog -md DealTracker DealTracker | dod  }
    else {  dialog -ev DealTracker DealTracker) }
  }
  -
}
alias -l dod {
  set  %sdpage 1
  hmake dod 20
  sockopen dod www.onedaybuys.com 80
}
on *:sockopen:dod:{
  sockwrite -n $sockname GET /latest.php HTTP/1.0
  sockwrite -n $sockname Host: www.onedaybuys.com $+ $crlf $+ $crlf
}
on *:sockread:dod:{
  if ($dialog(DealTracker) != $null) {
    if (%linenum == $null) { set %linenum 1 }
    if (%linenum1 == $null) { set %linenum1 1 }
    if (%linenum2 == $null) { set %linenum2 1 }
    if ($sockerr) { return } 
    sockread %tempdod
    if ($sockbr == 0) { return }
    if (*dealhash[ $+ '* iswm %tempdod) {
      if (*['price']* iswm %tempdod) {
        var %price $htmlfree(%tempdod)
        var %tmplennum = $numtok(%price,32)
        tokenize 32 %price
        if ($remove($($ $+ %tmplennum,2),;,') isnum) {
          set %finprice. $+ %linenum1 $chr(36) $+ $remove($($ $+ %tmplennum,2),;,')
          inc -u6 %linenum1 1
        }
        else { dec %linenum2 2 }
      }
      elseif (*['vendorlink']* iswm %tempdod) && ([ %finprice. [ $+ [ $calc(%linenum1 -1) ] ] ] == $null) {
        set %finprice. $+ %linenum1 CheckForPrice 
        inc -u6 %linenum1 1
      }
      if (*['link']* iswm %tempdod) { 
        hadd dod %linenum2 http://www.OneDayBuys.com $+ $mid(%tempdod,$calc($pos(%tempdod,',5) + 1),$calc($pos(%tempdod,',6) - $pos(%tempdod,',5) - 1)) 
        inc -u6 %linenum2 2
      }
    }
    if (*class="product_title* iswm %tempdod) { 
      var %title $htmlfree(%tempdod)
      if (%title != $null) {
        did -az DealTracker 3 [ %finprice. [ $+ [ %linenum ] ] ] %title
        did -az DealTracker 3 $chr(32)
        inc -u6 %linenum 1
      }
    }
  }
}
on *:sockclose:dod:{
  sd
  unset %finprice.*
}
alias -l sd {
  set %sdpage 1
  hmake sd 20
  sockopen SlickDeals forums.slickdeals.net 80
}
on *:sockopen:SlickDeals:{
  sockwrite -n $sockname GET /forumdisplay.php?f=9&page= $+ %sdpage $+ &sort=lastpost&order=desc HTTP/1.0
  sockwrite -n $sockname Host: forums.slickdeals.net $+ $crlf $+ $crlf
}
on *:sockread:SlickDeals:{
  if ($dialog(DealTracker) != $null) {
    :start
    if ($sockerr) { echo -a Error. | return } 
    sockread %tempSlickDeals
    if ($sockbr == 0) { return } 
    if (%gonum == $null) { set %gonum 1 }
    if (*id="thread_title_* iswm %tempSlickDeals) { 
      hadd sd %gonum http://forums.slickdeals.net/showthread.php?sduid=195897&t= $+ $mid(%tempSlickDeals,$calc($pos(%tempSlickDeals,_,2) + 1),$calc($pos(%tempSlickDeals,",4) - $pos(%tempSlickDeals,_,2) - 1)))
      var  %result = $mid(%tempSlickDeals,$calc($pos(%tempSlickDeals,>,1) + 1),$len(%tempslickdeals)) 
      did -az DealTracker 4 $left(%result,$calc($len(%result) - 4))
      did -az DealTracker 4 $chr(32)
      inc %gonum 2 
    }
    goto start
  }
}
on *:sockclose:SlickDeals:{ 
  if ($dialog(DealTracker) != $null) {
    inc -u10 %sdpage
    if (%sdpage <= 33) { .timer 1 0 sockopen SlickDeals forums.slickdeals.net 80 }
  }
}
on *:dialog:DealTracker:close:0:{
  if ($sock(dod).status == active) { sockclose dod }
  if ($sock(SlickDeals).status == active) { sockclose sd }
  if ($hget(dod) == dod) { hfree dod }
  if ($hget(sd) == sd) { hfree sd }
  unset %gonum | unset %dodnum* %sdpage %tempslickdeals %tempdod %sdworking %dodworking %sdsiteaddr 
}
dialog DealTracker {
  title " Typos Deal Tracker"
  size -1 -1 195 179
  option dbu
  tab "    OneDayBuys.com One Day Deals    ", 1, 0 8 193 168
  list 3, 1 22 191 152, tab 1 size hsbar vsbar
  tab "      SlickDeals.net Forums       ", 2
  list 4, 1 22 191 152, tab 2 size hsbar vsbar
  text "Simply double click a deal to open the website.", 5, 1 1 192 9, center
}
on *:dialog:dealtracker:dclick:3:{ url -n $hget(dod,$did(3).sel) }
on *:dialog:dealtracker:dclick:4:{ url -n $hget(sd,$did(4).sel) }
;I did not write the htmlfree alias (below).
alias htmlfree {
  ;I cannot pin down who made this alias but it was not me.
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;)
  return %x
}
;Everything else in this script except for this alias was writen by me
;End of Typos Deal Tracker