Ok i made this awhile back . What it does is allows you to make changes and edits of ur Variable's . ez to use copy/paste into a new remote click either in ur menubar or a channel to open. Enjoy...

dialog vls {
  title "Variable Manager"
  size -1 -1 126 73
  option dbu
  box "Variable List", 1, 2 1 64 71
  list 2, 4 10 60 49, size vsbar
  box "Edit/Add Variable", 3, 67 1 58 30
  edit "", 4, 69 10 54 9, autohs
  button "save", 5, 69 20 27 9, flat
  button "delete", 6, 96 20 27 9, flat
  box "Edit Variable's Info", 7, 67 32 58 40
  edit "", 8, 69 40 54 9, read autohs
  edit "", 9, 69 50 54 9, autohs center
  button "edit", 10, 69 61 54 9, flat
  text "", 11, 4 61 60 8, center
}
on *:load: { 
  echo 12 -a You Have Just Loaded Napa182's Variable Manager 
  echo 12 -a An Irc.EzzyChat.com Production 
}
menu menubar,channel {
  .Variable Manager:dialog $iif($dialog(vls),-v,-md vls) vls
}
alias -l varlist return didtok vls 2 32 $regsubex($str(.,$var(%*,0)),/(.)/g,$var(%*,\n) $chr(32))
alias -l varcount return did -ra vls 11 Total Var's $var(*,0)
on *:dialog:vls:init:0:{ did -b $dname 6,9,10 | $varcount | $varlist }
on *:dialog:vls:edit:4:{ did -r $dname 8,9 | did -b $dname 6 }
on *:dialog:vls:sclick:*:{
  if ($did = 2) { 
    did -e $dname 6,9,10
    did -ra $dname 4,8 $did(2).seltext
    did -ra $dname 9 $var($did(2).seltext,1).value
  }
  if ($did == 5) { 
    if (!$did(4).text || $did(4).text == $var($did(4).text,1)) {
      noop $iif(!$did(4).text,$input(No Variable Entered.,uho,ERROR!),$input(Variable Already Exists.,uho,ERROR!)) 
    } 
    else { 
      if ($input(Are You Sure You Want To ADD ( $+ $iif($left($did(4).text,1) != %,% $+ $did(4).text,$did(4).text) $+ ) To The Variable List,uqy,Are U Sure?) == $true) {
        set $+($iif($left($did(4).text,1) != %,%),$did(4).text) 
        did -r $dname 2,8
        did -e $dname 6,9,10
        did -ra $dname 4,8 $+($iif($left($did(4).text,1) != %,%),$did(4).text)
        $varcount
        $varlist
      }
    }
  }
  if ($did == 6) {   
    if ($input(Are You Sure You Want To Delete ( $+ $did(4).text $+ ) From The Variable List,uqy,Are U Sure?) == $true) {
      unset $did(4).text
      did -r $dname 2,4,8,9
      did -b $dname 6,9,10
      $varcount
      $varlist
    }
  }
  if ($did == 10) { set $did(8).text $did(9).text }
}