This snippet will keep track of the total amout of users on a channel. The owner can view from the Popup, or users in the chan can type !Peak to have it sent to the chan.

Copy and paste into new remotes file. Once you or someone joins a channel it will start keeping track.

menu Channel {
  Peak Users
  .Peak  $peak($Chan):halt
}

raw 366:*:if ($nick($2,0)) && ((!$hget(peaks,$2)) || ($GetTok($hget(peaks,$2),1,32) < $nick($2,0))) { hadd -m peaks $2 $nick($2,0) $ctime }

alias -l peak {
  if ($hget(peaks,$1)) {
    tokenize 32 $v1
    return $1 ( $+ $asctime($2,mm/dd/yy) $+ )
  }
  else { return Unknown }
}

alias -l loadpeaks {
  if ($hget(peaks)) { hfree peaks }
  hmake peaks 
  if ($isfile($ScriptDirpeaks.tbl)) { hload -b peaks $ScriptDirpeaks.tbl }
}

alias -l PeakSave if ($hget(peaks)) { hsave -ob peaks $ScriptDirpeaks.tbl }

on *:EXIT:if ($hget(peaks)) { hsave -ob peaks $ScriptDirpeaks.tbl }

on *:JOIN:#:if ($Nick != $me) && ($nick($chan,0)) && ((!$hget(peaks,$chan)) || ($GetTok($hget(peaks,$chan),1,32) < $nick($chan,0))) { hadd -m peaks $chan $nick($chan,0) $ctime }

on *:CONNECT:.timerPeak 0 60 /PeakSave

on *:START:loadpeaks

on *:TEXT:!peak:#:{
  if ($Peak($Chan) != Unknown) { 
    var %temp = $v1
    tokenize 32 $v1
    .msg $chan Peaks users of $1 occurred at $mid($2,2,$calc($len($2) - 2)) $+ . 
  }
}