Use this script to make AGreets for nicks joining certain channels.
You can add/delete/clear nicks in your AGreet list via the @Window which you are able to open via right clicking in a chnanel and selecting "Open AGreet Mod". You can add or delete nicknames in your AGreet list in a nickname or query popup.
Also, a command I made not that long ago, is /greet
Command: /greet
Syntax: /greet [-ilcacdcl]
-i Gives info on one or mulitple AGreet nicks, the info being the greet for them.
For instance: /greet -i |XD|Bebop Wolf Shine would return
- AGreet Info.
<^>^<^>^<^>- 1) |XD|Bebop: No Info/Non-existent User.
- 2) Wolf: <~Wolf> wonder twin powers activate! <~Wolf> form of.... <~Wolf> minimized mIRC
- 3) Shine: bebop, your the shiznit <3
<^>^<^>^<^>
-l would list all the nicknames on your AGreet list.
-c:
-ca Adds a channel to your Channel Block List.
Your Channel Block List are the channels you do not wish to have the AGreet script trigger on.
-cd Deletes a channel from your Channel Block List.
-cl Lists the channels on your Channel Block List.
Screenshot:
alias Greet {
If (!$1) {
If ($group(#greet).status = On) { .disable #greet | goto end }
If ($group(#greet).status = Off) { .enable #greet | goto end }
:end
echo $color(info) -a * Bebop's Greet Script - $group(#greet).status
halt
}
If ($1) {
If (-l = $1) {
%i = 1
echo $color(info) -a * AGreet List.
echo $color(info) -a $readini(mirc.ini,text,linesep)
While ($ulist(*,70,%i)) { echo $color(info) -a * %i $+ ) $ulist(*,70,%i) | inc %i }
echo $color(info) -a $readini(mirc.ini,text,linesep)
}
If (-i = $1) {
tokenize 32 $2-
echo $color(info) -a * AGreet Info.
echo $color(info) -a $readini(mirc.ini,text,linesep)
%i = 1
While ($1) { echo $color(info) -a * %i $+ ) $1 $+ : $iif($ulist($1,70,1).info,$v1,No Info/Non-existent User.) | tokenize 32 $2- | inc %i }
echo $color(info) -a $readini(mirc.ini,text,linesep)
}
If (-c = $left($1,2)) && ($len($1) = 3) {
If ($right($1,1) = a) {
%greet!= = $addtok(%greet!=,$2-,32)
echo $color(info) -a $readini(mirc.ini,text,linesep)
echo $color(info) -a * Added Blocked Channels: $replace($2-,$chr(32),$chr(44) $+ $chr(32))
echo $color(info) -a $readini(mirc.ini,text,linesep)
}
If ($right($1,1) = d) {
%b = $2-
tokenize 32 $2-
While ($1) {
If ($istok(%greet!=,$1,32)) { %greet!= = $deltok(%greet!=,$findtok(%greet!=,$1,1,32),32) }
tokenize 32 $2-
}
echo $color(info) -a $readini(mirc.ini,text,linesep)
echo $color(info) -a * Deleted Blocked Channels: $replace(%b,$chr(32),$chr(44) $+ $chr(32))
echo $color(info) -a $readini(mirc.ini,text,linesep)
}
If ($right($1,1) = l) {
%i = 1
echo $color(info) -a * Blocked Channels
echo $color(info) -a $readini(mirc.ini,text,linesep)
While ($gettok(%greet!=,%i,32)) { echo $color(info) -a * %i $+ ) $v1 | inc %i }
echo $color(info) -a $readini(mirc.ini,text,linesep)
}
}
}
}
menu @Greet {
Delete:/Greet.Del
Add:/Greet.Add
Clear:/Greet.Clear
Copy:/clipboard $gettok($sline(@Greet,1),3-,32)
}
menu channel {
-
Open AGreet Mod:/Greet.Open
-
}
menu nicklist,query {
-
Add $$1 to Greet list:/Greet.Add $$1
Delete $$1 from Greet list:/.ruser 70 $$1 | echo $color(info) -a * Delete $$1 from Greet list.
Open AGreet Mod:/Greet.Open
-
}
alias Greet.Open window -edolCk0 @Greet -1 -1 700 200 | .timer 1 .01 /Greet.Play
alias -l Greet.Play {
%i = 1
While ($ulist(*,70,%i)) { aline @Greet $ulist(*,70,%i) - $ulist(*,70,%i).info | inc %i }
}
alias -l Greet.Add {
set %m $iif($1,$1,$$?="Nickname?")
set %g $$?="Greet for %m $+ ?"
.auser 70 %m %g
echo $color(info) -a * Added $qt(%m) with greet $qt(%g)
If ($window(@greet)) { aline @greet %m $+ : %g }
unset %m %g
}
alias -l Greet.Del {
If ($sline(@Greet,1)) {
%i = 1
While ($sline(@Greet,%i)) {
.ruser 70 $gettok($sline(@Greet,%i),1,32)
inc %i
}
dline @Greet $sline(@Greet,1).ln $+ - $+ $sline(@Greet,$sline(@Greet,0)).ln
}
}
alias -l Greet.Clear {
set %Y/N $input(Are you sure you wish to clear your Greet list? It will be lost forever.,yvgdw,@Greet,Bebop's Greet Script)
If (%Y/N = $no) { unset %Y/N | halt }
If (%Y/N = $yes) {
unset %Y/N
.rlevel 70
clear @Greet
}
}
#greet on
on 70:JOIN:#: { If (!$istok(%greet!=,#,32)) { msg # ( $+ $nick $+ ) $ulist($nick,70,1).info } }
#greet end