Menu driven system to notify you if someone you're monitoring says something in a common channel. You can set the nick that the notifications go to (so it doesn't have to be you), Add/Remove nicks being monitored (includes a counter so you can see at a glance how many nicks are being monitored). Text and/or Sound notifications. Flood protection set for 60 seconds as a default
Certain settings require other settings to already be set. If the required setting isn't set, then the optional setting isn't shown. (Example: You can't see the Remove nick option if there aren't any nicks being monitored)

;Message from nick notifier
;Not guaranteed compatable with multiple connections
;Written by RusselB on Nov. 21, 2006
;E-mail: r.k.bairstow@gmail.com
;Use subject of Message from nick notifier
on *:start:{
  $iif(!$hget(Watch),.hmake Watch 10)
  $iif($exists(Watch.hsh),.hload Watch Watch.hsh)
  .hadd -m Watch $+($me,.Text) $iif($hget(Watch,$+($me,.Text)),$v1,$false)
  .hadd -m Watch $+($me,.Sound) $iif($hget(Watch,$+($me,.Sound)),$v1,$false)
  .hadd -m Watch $me $iif($hget(Watch,$me),$v1,$false)
}
on *:exit:{  .hsave -o Watch Watch.hsh }
on *:disconnect:{  .hsave -o Watch Watch.hsh }
menu * {
  Nick Notify
  .$iif($hget(Watch,$me),Change Default Notify Nick from $v1,Set Default Notify Nick) : .hadd -m Watch $me $$input(Notification Nick,e,Nick for default notification,$iif($hget(Watch,$me),$v1,$me))
  .Watch List has $calc($hget(Watch,0).item -3) nicks on it
  ..Add Nick to watch list : .hadd -m Watch $$input(Nick to watch,e,,$1) 60
  ..$iif($calc($hget(Watch,0).item -3),Remove nick from watch list) : .hdel Watch $$input(Nick to stop watching,e,,$1)
  .Text Notification $iif($hget(Watch,$+($me,.Text)),Off,On) : .hadd -m Watch $+($me,.Text) $iif($hget(Watch,$+($me,.Text)),$false,$true)
  .Sound Notification $iif($hget(Watch,$+($me,.Sound)),Off,On) : .hadd -m Watch $+($me,.Sound) $iif($hget(Watch,$+($me,.Sound)),$false,$sfile($+($mircdir,*.mp3)))
  .$iif($hget(Watch,$+($me,.Sound)),Change Music File from $v1) : $sfile($+($mircdir,*.mp3))
}
on *:text:*:#:{
  if $hget(Watch,$nick) == 0 {
    $iif($hget(Watch,$+($me,.Text)),.notice $hget(Watch,$me) $nick said $1- in $chan)
    $iif($hget(Watch,$+($me,.Sound)),.splay $v1)
    .hdec -c Watch $nick
  }
}