Auto Join

By Vickito on Dec 24, 2020

Esté es un AutoJoin o mejor conocido como 'Entrada Automatica'.
No hay mucho que decir, es simple y rápido de usar, solo debes ponerlo en tu mIRC o IRCap.
No te dará Error o Fallo (conocido como Glitch), no causará problemas con otros scripts.

Cualquier cosa, pueden dejarme un comentario.
Pasen una vida feliz.

/*
  AutoJoin

  He estado un tiempo trabajando en este AutoJoin (EntradaAutomatica),
  lo he mejorado, con menos codigos y más simple de usar.
  Se puede mejorar de miles de formas, pero eso queda en cada persona, 
  he hecho lo que podía con esté script.

  Cualquier cosa, eres o son libres de modificar y hacer los cambios que gusten.

  —Ultima actualización: Lunes 03 de Enero, del 2022.
  Att: Vickito.
  */

Alias Cmd {
  /set %DB $+(DB\,$network,\)
  /set %Auto $+(%DB,AutoJoin.txt)
  If ($exists(%DB) == $false) { /mkdir %DB }
  If ($1 == Ajoin) {
    if (%Ajoin:Bug == $null) {
      /set -z %Ajoin:Bug $calc($len(%Auto) * 4)
      /inc -u300 %Time:A 1
      while (%Time:A <= $lines(%Auto)) {
        If (%Time:B == $null) { /set -u60 %Time:B 5 }
        If ($me !ison $read(%Auto,%Time:A)) {
          /timer 1 %Time:B /join -n $read(%Auto,%Time:A)
          /set -u60 %Time:B $calc((%Time:B) + 5)
        }
        /inc %Time:A
      }
      /unset %Time:*
    }
  }
  Elseif ($1 == Lista) {
    if (%Lista:Bug [ $+ [ $2 ] ] == $null) {
      /set -z %Lista:Bug $+ $2 30
      If ($exists(%Auto) == $true) { /msg $2 Lista de AutoJoin: | /play $2 %Auto 2000 }
      Else { /msg $2 Lista de AutoJoin No existe. }
    }
  }
  Elseif ($1 == Add) {
    If ($3 == $null) { /msg $2 • $2 • Dame una sala para añadir. }
    Elseif ($3 != $null) {
      /set %Auto:Add $iif($chr(35) isin $3, $3, $chr(35) $+ $3)
      If ($read(%Auto, w, %Auto:Add) == $null) { 
        /write %Auto %Auto:Add
        /msg $2 • $2 • Listo, la sala %Auto:Add añadida en mi lista. 
        If ($me !ison %Auto:Add) { 
          /join -n %Auto:Add 
          /describe $3 Este canal esta en mi AutoJoin por %Auto:Add $+ . Si necesitas ayuda pon !Ayuda. 
        }
      }
      Elseif ($read(%Auto, w, %Auto:Add) != $null) { /msg $2 • $2 • Esa sala ya esta en mi lista. }
    }
    /unset %Auto:Add
  }
  Elseif ($1 == Del) {
    If ($3 == $null) { /msg $chan • $2 • Dame una sala para eliminar. }
    Elseif ($3 != $null) {
      /set %Auto:Del $iif($chr(35) isin $3, $3, $chr(35) $+ $3)
      If ($read(%Auto, w, %Auto:Del) != $null) { 
        /write -ds $+ $read(%Auto, w, %Auto:Del) %Auto 
        /msg $2 • $2 • Listo, la sala %Auto:Del eliminada de mi lista. 
        If ($me ison %Auto:Del) { /part %Auto:Del Este canal fue eliminado. Por: $2 $+ . }
      }
      Elseif ($read(%Auto, w, %Auto:Del) == $null) { /msg $2 • $2 • Esa sala no esta en mi lista. }
    }
    /unset %Auto:Del
  }
}
On *:CONNECT: { /Cmd Ajoin }
On *:TEXT:*:*: { 
  If ($level($nick) >= 100) {
    If ($1 == !Auto) || ($1 == .Auto) || ($1 == @Auto) {
      If ($2 == Lista) { /Cmd Lista $iif($nick ison $chan, $chan, $nick) }
      Elseif ($2 == Entra) { /Cmd Ajoin }
      Elseif ($2 == Add) { 
        if ($3 == $null) { /msg $iif($nick ison $chan, $chan, $nick) Debes especificar una sala. }
        else { /Cmd Add $iif($nick ison $chan, $chan, $nick) $3 }
      }
      Elseif ($2 == Del) { 
        if ($3 == $null) { /msg $iif($nick ison $chan, $chan, $nick) Debes especificar una sala. }
        else { /Cmd Del $iif($nick ison $chan, $chan, $nick) $3 }
      }
      Else { /msg $iif($nick ison $chan, $chan, $nick) • $nick • !Auto (Lista|Entra|Add|Del) }
    }
  }
}

Comments

Sign in to comment.
Are you sure you want to unfollow this person?
Are you sure you want to delete this?
Click "Unsubscribe" to stop receiving notices pertaining to this post.
Click "Subscribe" to resume notices pertaining to this post.