BotServ talker

By log2 on Aug 21, 2006

Well the comments explain it all, but the jist is:
Paste in fresh script
Right click
Fill in Information
hit talk

What it does, it let's you talk through a bot if you channel has one from the bot server on your network...
NOTES:

  • You must own the channel and be bot operator
  • The server you're on MUST have botserv (not necisarilly called that)
  • The Bot Server and Channel must be specified once only (Unless you switch servers or want a different channel)
; ----------------------------------------------------------------------------
; This is called BoTalk by Log2 Stew
; What it is, it let's you communicate through the botserv
; bot, or whatever the botserv is on your server
; NOTE: BotServ on my server let's you get a bot that will always be
;       In the channel when you are
;       This let's you communicate through the bot that they place in there!
; ----------------------------------------------------------------------------
; It's quite easy to use, there is no set up, all you have to do is place this
; Code in a new script and then hit yes if it asks you to initialize it
; Then right click in the channel that you own
; The script will do the rest, it will pop up in a dialog for you to say
; NOTE: You need to fill in the server name and the channel the first time
;       You use it, but after that it's a breeze
; Lastly... Enjoy :D
; ---------------------------------------------------------------------------
menu channel {
  Bot Talk:/dialog -md botalk botalk
}
dialog botalk {
  title "Bot Talk By Log2"
  size -1 -1 250 130
  radio "Say Normally",1,10 10 100 20
  radio "Describe",2, 10 30 100 20
  edit "",3, 10 70 230 20
  text "Message for Judge to say:",4, 13 55 200 15
  button "Say Message!",5, 150 12 90 20
  button "Cancel",6, 150 34 90 20, cancel
  text "Bot Server:",7, 12 92 100 15
  edit "",8, 10 106 90 17
  text "Channel:",9, 122 92 100 15
  edit "",10, 120 106 120 17
}
on 1:DIALOG:botalk:init:0: {
  did -c botalk 1
  did -f botalk 3
  did -t botalk 5
  if (%log2talk == $null || !%log2talk) {
    set %log2talk
  }
  if (%log2chan == $null || !%log2chan) {
    set %log2chan
  }
  did -a botalk 8 %log2talk
  did -a botalk 10 %log2chan
}
on 1:DIALOG:botalk:sclick:5: {
  if ($did(botalk,10) != $null) {
    if ($left($did(botalk,10),1) == $chr(35)) {
      set %log2chan $did(botalk, 10)
    }
    else {
      set %log2chan $chr(35) $+ $did(botalk,10)
    }
    if ($did(botalk, 8) != $null) {
      set %log2talk $did(botalk, 8)
      if ($did(botalk,3) != $null) { 
        if ($did(botalk,1).state == 1) {
          $talk(1, $did(botalk,3))
        }
        else if ($did(botalk,2).state == 1) {
          $talk(2, $did(botalk,3))
        }
        did -r botalk 3
      }
      else {
        did -a botalk 3 You need a message
      }
    }
    else {
      did -a botalk 8 No Server
    }
  }
  else {
    did -a botalk 10 Need a Channel
  }
}
alias talk {
  if ($isid) {
    if ($1 == 1) {
      return / $+ %log2talk say %log2chan $2-
    }
    else if ($1 == 2) {
      return / $+ %log2talk act %log2chan $2-
    }
    else {
      return echo -a Not Working
    }
  }
}

Comments

Sign in to comment.
Are you sure you want to unfollow this person?
Are you sure you want to delete this?
Click "Unsubscribe" to stop receiving notices pertaining to this post.
Click "Subscribe" to resume notices pertaining to this post.