just type in '/mp3player' ..please notify me if there are any errors, or if you have suggestions and/or comments

;My Audio Player
dialog mp3 {
  title "My Audio Player"
  size -1 -1 200 110

  list 1, -1 -1 200 100, vsbar hsbar extsel

  menu "&File", 11
  item "&Add file", 6, 11
  item "&Del file", 7, 11
  item break, 15, 11
  item "&Exit", 16, 11, ok

  menu "&Options", 10
  item "&Back", 2, 10
  item "&Play", 3, 10
  item "&Stop", 4, 10
  item "&Next", 5, 10

  menu "&Spam", 12
  item "Set action", 13, 12
  item break, 14, 12
  item "About", 17, 12

  check "repeat", 8, 150 85 50 25, right
  check "shuffle", 9, 95 85 50 25, right

}
on 1:dialog:mp3:menu:17:{
  msg $active 7This is Bizkwet's Audio Player
  msg $active 7Enjoy!!
}
on 1:dialog:mp3:menu:13:{
  set %msg $$?="Enter your message: (e.g. is currently listening to)"
}
on 1:dialog:mp3:sclick:9:{
  if (%shuffle == 1) set %shuffle 0
  else set %shuffle 1
}
on 1:dialog:mp3:sclick:8:{
  if (%repeat == 1) set %repeat 0
  else set %repeat 1
}
on 1:dialog:mp3:menu:2:{
  if (%i <= 1) echo -a * Error: First item in playlist
  else { 
    dec %i
    splay -p $read(listsong.txt,%i)
    spam
  }
}
on 1:dialog:mp3:menu:5:{
  if (%i >= $lines(listsong.txt)) echo -a * Error: End of playlist
  else {
    inc %i  
    splay -p $read(listsong.txt,%i)
    spam
  }
}
on 1:dialog:mp3:init:0:{
  if (%shuffle == 1) did -c mp3 9
  if (%repeat == 1) did -c mp3 8
  set %list 1
  while (%list <= $lines(listsong.txt)) {
    did -a mp3 1 $sound($read(listsong.txt,%list)).artist - $sound($read(listsong.txt,%list)).title
    inc %list 1
  }
}
on 1:dialog:mp3:menu:7:{
  write -dl [ $+ [ $did(mp3,1).sel ] ] listsong.txt
  did -d mp3 1 $did(mp3,1).sel
}
on 1:dialog:mp3:menu:4:{
  unset %i
  splay stop
}
on 1:dialog:mp3:menu:6:{
  set %song $sfile(/)
  write -a listsong.txt %song
  did -a mp3 1 $sound(%song).artist - $sound(%song).title
}
on 1:dialog:mp3:menu:3:{
  set %i $did(mp3,1).sel
  splay -p $read(listsong.txt,%i)
  spam
}
on 1:mp3end:{
  if (%shuffle == 1) {
    set %i $rand(1,$lines(listsong.txt))
    splay -p $read(listsong.txt,%i)
    spam
  }
  else {
    if (%i < $lines(listsong.txt)) {
      inc %i
      splay -p $read(listsong.txt,%i)
      spam
    } 
    else {
      if (%repeat == 1) {
        set %i 1
        splay -p $read(listsong.txt,%i)
        spam
      }
    }
  }
}
on 1:dialog:mp3:dclick:1:{
  set %i $did(mp3,1).sel
  splay -p $read(listsong.txt,%i)
  spam
}
alias spam {
  ame %msg 4 $sound($read(listsong.txt,%i)).artist - $sound($read(listsong.txt,%i)).title [ $duration($calc(($sound($read(listsong.txt,%i)).length)/1000)) ]  [ $sound($read(listsong.txt,%i)).bitrate $+ kbit ]   
}

alias mp3player { dialog -md mp3 mp3 }