With Multi Message System, you can:

!tell nickname your message goes here!

What it does:
You can stack up to 10 messages per nickname. When they say something in any channel that your script is in, the bot will message the channel with your previous message or messages.

Example usage:
[16:01:27] !tell ChanServ Missed you bud, have something to tell you
[16:01:28] newklear, Message captured for ChanServ.
[16:01:44] !tell ChanServ It is really important, so get hold of me asap!
[16:01:44] newklear, Additional Message captured for ChanServ.
[16:02:01] <&ChanServ> I am here
[16:02:01] ChanServ: Sent 33secs ago: "Missed you bud, have something to tell you" while on #ghostcore
[16:02:09] <&ChanServ> what was it ?
[16:02:09] ChanServ: Sent 25secs ago: "It is really important, so get hold of me asap!" while on #ghostcore

;*MULTI MESSAGE SYSTEM
;*by newklear 2017, irc.chatx.co.za
;*Usage: !tell nickname your message goes here
;*When that nickname says something, the bot will relay the message in the channel
;*Copy and paste the entire contents into mIRC script editor and save as whatever.mrc

on *:TEXT:!tell*:#: {
  if (%lasttell. [ $+ [ $address($nick,5) ] ] == 1) { halt }
  set -u10 %lasttell. [ $+ [ $address($nick,5) ] ] 1
  if (!$2) { msg $chan Syntax: !tell nickname leave your message here! | halt }
  if ($2 == $me) { msg $chan You can't send me a message, I see everything already :p | halt }
  if ($read(Tell.txt,w,$+(*,$2,*))) { 
    write -l $+ $calc($readn + 10) Tell.txt $2 $nick $ctime $chan $3-
    msg $chan $nick $+ , Additional Message captured for $2 $+ .
  } 
  else {
    write Tell.txt $2 $nick $ctime $chan $3-
    msg $chan $nick $+ , Message captured for $2 $+ .
  } 
}

on *:TEXT:*:#: {
  if ($read(Tell.txt,s,$nick)) { 
    if (%tell. [ $+ [ $address($nick,5) ] ] != 1) { timertell 1 5 notice $nick This is the 1st time you have received a message with a 24 hour period, to leave a message, Syntax: !tell nickname your message goes here! }
    set -u86400 %tell. [ $+ [ $address($nick,5) ] ] 1
    var %who $gettok($read(Tell.txt,s,$nick),1,32)
    var %time $gettok($read(Tell.txt,s, $nick),2,32)
    var %mchan $gettok($read(Tell.txt,s, $nick),3,32)
    var %msg $gettok($read(Tell.txt,s,$nick),4-,32)
    msg $chan $nick $+ : Sent $duration($calc($ctime - %time)) ago: < $+ %who $+ > " $+ %msg $+ " while on %mchan 
    write -ds $+ $nick Tell.txt
  }
}