on *:load: { 
  .echo -aq $input(Author: SaNCaK $+ $crlf $+ $crlf $+ Addon: Ip Tracker $chr(40) $+ v5.4 $+ $chr(41) $+ $crlf $+ $crlf $+ Released at: 17/10/2016 $+ $crlf $+ $crlf $+ Contact: sancak@outlook.com.tr $+ $crlf $+ $crlf $+ Thank you for using this Addon,igo,Addon: Ip Tracker $chr(40) $+ v5.4 $+ $chr(41))
  .echo -s _____________________________________________________
  .echo -s 0,1 Loading 9,1Ip Tracker0,1 Add-On... 
  .echo -s 0,1 You are running mIRC $version on Windows $+ $os
  .echo -s ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
}
on *:unload: { 
  .echo -aq $input(Author: SaNCaK $+ $crlf $+ $crlf $+ Addon: Ip Tracker $chr(40) $+ v5.4 $+ $chr(41) $+ $crlf $+ $crlf $+ Released at: 17/10/2016 $+ $crlf $+ $crlf $+ Contact: sancak@outlook.com.tr $+ $crlf $+ $crlf $+ Unloading...,igo,Addon: Ip Tracker $chr(40) $+ v5.4 $+ $chr(41))
}
;############################  -«•»SaNCaK ScripT«•»-    ############################

menu nicklist {
  IP Tracker:dns $$1
}

on *:DNS: { 
  haltdef
  set %tracknick $nick
  set %trackip  $iaddress
  if ($iaddress == $null) set %trackip $naddress 
  set %Body  IP= $+ %trackip $+ &button=Search  ; prepare the body for the POST
  sockopen ip-tracker clientn.free-hideip.com 80
}

on *:SOCKOPEN:ip-tracker: {
  if ($sockerr) { 
    echo -a Error: $sock(tracert).wsmsg  
  }
  else {
    sockwrite -n $sockname POST /map/whatismyip.php HTTP/1.1
    sockwrite -n $sockname Host: clientn.free-hideip.com
    sockwrite -n $sockname User-Agent: Mozilla/5.0 (Windows NT 6.1; WOW64; rv:26.0) Gecko/20100101 Firefox/26.0
    sockwrite -n $sockname Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8
    sockwrite -n $sockname Accept-Language: en-US,en;q=0.5
    sockwrite -n $sockname Accept-Encoding: gzip, deflate
    sockwrite -n $sockname Referer: http://clientn.free-hideip.com/map/whatismyip.php
    sockwrite -n $sockname Connection: keep-alive
    sockwrite -n $sockname Content-Type: application/x-www-form-urlencoded
    sockwrite -n $sockname Content-Length: $len(%Body)
    sockwrite -n $sockname $crlf
    sockwrite -n $sockname %Body
  }
}

on *:SOCKREAD:ip-tracker: {
  if ($sockerr > 0) return 
  sockread %ip-tracker
  if $regex(%ip-tracker,/<td><div align="left">Country:([^<>]+)/)   { set %country $regml(1) }
  if $regex(%ip-tracker,/<td><div align="left">Region:([^<>]+)/)    { set %region $regml(1) }
  if $regex(%ip-tracker,/<td><div align="left">City:([^<>]+)/)      { set %city $regml(1) }
  if $regex(%ip-tracker,/<td><div align="left">Latitude:([^<>]+)/)  { set %lat $regml(1) } 
  if $regex(%ip-tracker,/<td><div align="left">Longitude:([^<>]+)/) { set %lon $regml(1) 
    ; We have collected all that we need
    sockclose ip-tracker
    echo -at 12=- %tracknick IP: 2 %trackip
    echo -at 12=- LongIP: 2 $longip(%trackip)   
    echo -at 12=- Country: 2 %country  
    echo -at 12=- Region: 2 %region
    echo -at 12=- City: 2 %city 
    echo -at 12=- Latitude: 2 %lat
    echo -at 12=- Longitude: 2 %lon
    echo -at 12=- Link: 2 http://maps.google.com/maps?ll= $+ $remove(%lat,$chr(32)) $+ , $+ $remove(%lon,$chr(32))
    timer 1 2 .run http://maps.google.com/maps?ll= $+ $remove(%lat,$chr(32)) $+ , $+ $remove(%lon,$chr(32))
    return
  }
}