previous | next

Emboss ASCII (Unicode) Fonts for mIRC.

Because odds are people just aren't paying attention to anything you say.
Add this snippet to your Aliases.

Click the ♡ if you like this.

;# Emboss Fonts for mIRC. Based on font from TOIlet @ Caca Labs
;# /emb <text>  and  /enb2 <text>
;# /emb [-m|-n target] <text> -- to message or notice target(s).
;# /emb [-cmd ["]custom["]] <text> -- send by arbitrary command.
;# Bold and Reverse control codes, work. Color support coming...
;# The missing characters # $ % are not a perfect compromise.
emb2 { emb -2 $1- } 
emb {
  var %cmd = say
  while (-* iswm $1) { ; -switches
    if ($1 == -cmd) && ($regex($2-,/(?:"([^"]*)"|\S+)(.*)/)) {
      var %cmd = $regml(1) | tokenize 32 $regml(2)
    }
    elseif ($1 == -m) { var %cmd = msg $2    | tokenize 32 $3- }
    elseif ($1 == -n) { var %cmd = notice $2 | tokenize 32 $3- }
    elseif ($1 == -2) { var %emb2 = $true    | tokenize 32 $2- }
    else { break } ; unknown switch.
  }
  var %a, %b1, %b2, %b3
  %a = $chr(32) $+ !"&'()*+,-./#$%—0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`{|}~
  %b1 = ..,.┃,┛┛,┏┛┃.,┛,.┛,━.,┛.┛,.┃.,.,..,..,..┛,.╻╻.,┏┳┓,┏┓╻,....,
  %b2 = ..,.┛,..,┃━┏┛,.,┃.,.┃,━┏┛,━┏┛,.,━┛,..,.┛.,╺┏┏╸,┗╋┓,┏━┛,━━━┛,
  %b3 = ..,.┛,..,━━┛.,.,.┛,━.,┛.┛,.┛.,┛,..,.┛,┛..,╺┏┏╸,┗┻┛,╹┗┛,....,
  %b1 = %b1 $+ ┏━┃,━┃.,━━┃,━━┃,┃.┃,┏━┛,┏━┛,┏━┃,┏━┃,┏━┃,..,..,..┛,...,┛..,┏━┃,┏━┃,
  %b2 = %b2 $+ ┃┛┃,.┃.,┏━┛,━━┃,━━┃,━━┃,┏━┃,..┃,┏━┃,━━┃,.┛,.┛,┛..,━━┛,..┛,..┛,┃┛┛,
  %b3 = %b3 $+ ━━┛,━━┛,━━┛,━━┛,..┛,━━┛,━━┛,..┛,━━┛,━━┛,.┛,.┛,..┛,━━┛,┛..,.┛.,━━┛,
  %b1 = %b1 $+ ┏━┃,┏━.,┏━┛,┏━.,┏━┛,┏━┛,┏━┛,┃.┃,┛,.┛,┃.┃,┃..,┏┏.,┏━.,┏━┃,┏━┃,┏━┃.,┏━┃,
  %b2 = %b2 $+ ┏━┃,┏━┃,┃..,┃.┃,┏━┛,┏━┛,┃.┃,┏━┃,┃,.┃,┏┛.,┃..,┃┃┃,┃.┃,┃.┃,┏━┛,┃.┃.,┏┏┛,
  %b3 = %b3 $+ ┛.┛,━━.,━━┛,━━.,━━┛,┛..,━━┛,┛.┛,┛,━┛,┛.┛,━━┛,┛┛┛,┛.┛,━━┛,┛..,━━━┛,┛.┛,
  %b1 = %b1 $+ ┏━┛,━┏┛,┃.┃,┃.┃,┃┃┃,┃.┃,┃.┃,━━┃,┏┛,┛..,━┃,.┛.,...,┛.,.┏┛,┃,━┃.,.┛.┛
  %b2 = %b2 $+ ━━┃,.┃.,┃.┃,┃.┃,┃┃┃,.┛.,━┏┛,┏┛.,┃.,.┛.,.┃,┛.┛,...,.┛,━┃.,┃,.┏┛,┛.┛.
  %b3 = %b3 $+ ━━┛,.┛.,━━┛,.┛.,━━┛,┛.┛,.┛.,━━┛,━┛,..┛,━┛,...,━━┛,..,.━┛,┛,━┛.,....
  var %s = $replace($upper($1-),$chr(160),$chr(32),Ä,AE,Ö,OE,Ü,UE,ß,SS,--,—)
  var %i = 1, %n = 3
  while (%i <= %n) {
    if (%emb2) var %b $+ %i $replace(%b [ $+ [ %i ] ],━,═,┃,║,┏,╔,┛,╝)
    %cmd $replace($regsubex(%s,/(*UTF8)(.)/g, $& 
      $iif($gettok(%b [ $+ [ %i ] ],$poscs(%a,\t),44),$v1,\t)),.,$chr(160))
    inc %i
  } 
  if (!$event) && (!$editbox($active)) editbox -ap /emb $+ $iif(%emb2,2)
} ; by Raccoon 2016