previous | next

Future ASCII (Unicode) Font for mIRC.

Become the envy of your friends and enemies! Adored by fans; Promoted by ops!
Add this snippet to your Aliases.

Click the ♡ if you like this.

;# Future Font for mIRC. Based on font from TOIlet @ Caca Labs
;# /fut <text>
;# /fut [-m|-n target] <text> -- to message or notice target(s).
;# /fut [-cmd ["]custom["]] <text> -- send by arbitrary command.
;# Bold and Reverse control codes, work. Color support coming...
fut {
  var %cmd = say
  while (-* iswm $1) { ; -switches
    if ($1 == -cmd) && ($regex($2-,/(?:"([^"]*)"|\S+)(.*)/)) {
      var %cmd = $regml(1) | tokenize 32 $regml(2)
    }
    elseif ($1 == -m) { var %cmd = msg $2    | tokenize 32 $3- }
    elseif ($1 == -n) { var %cmd = notice $2 | tokenize 32 $3- }
    else { break } ; unknown switch.
  }
  var %a, %b1, %b2, %b3
  %a = $chr(32) $+ !"#$%&'()*+,-./0123456789:;<=>?@ $+ $&
    ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`{|}~ÄÖÜß卐卍†‡…—·☐ $+ $chr(127)
  %b1 = ..,.╻,╻╻,╺╋╋╸,┏┳┓,┏┓╻,┏┓..,╻,┏╸,╺┓,╻.╻,.╻.,..,...,..,.╻,
  %b2 = ..,.╹,..,╺╋╋╸,┗╋┓,┏━┛,┃╺╋╸,.,┃.,.┃,╺╋╸,╺╋╸,..,╺━╸,..,┏┛,
  %b3 = ..,.╹,..,....,┗┻┛,╹┗┛,┗━┛.,.,┗╸,╺┛,╹.╹,.╹.,.┛,...,.╹,╹.,
  %b1 = %b1 $+ ┏━┓,╺┓.,┏━┓,┏━┓,╻.╻,┏━╸,┏━┓,┏━┓,┏━┓,┏━┓,..,..,.┏╸,...,╺┓.,┏━┓,┏━┓,
  %b2 = %b2 $+ ┃┃┃,.┃.,┏━┛,╺━┫,┗━┫,┗━┓,┣━┓,..┃,┣━┫,┗━┫,.╹,.╹,╺┫.,╺━╸,.┣╸,.╺┛,┃┣┛,
  %b3 = %b3 $+ ┗━┛,╺┻╸,┗━╸,┗━┛,..╹,┗━┛,┗━┛,..╹,┗━┛,┗━┛,.╹,.┛,.┗╸,╺━╸,╺┛.,.╹.,┗━╸,
  %b1 = %b1 $+ ┏━┓,┏┓.,┏━╸,╺┳┓,┏━╸,┏━╸,┏━╸,╻.╻,╻,.┏┓,╻┏.,╻..,┏┳┓,┏┓╻,┏━┓,┏━┓,┏━┓,┏━┓,
  %b2 = %b2 $+ ┣━┫,┣┻┓,┃..,.┃┃,┣╸.,┣╸.,┃╺┓,┣━┫,┃,..┃,┣┻┓,┃..,┃┃┃,┃┗┫,┃.┃,┣━┛,┃┓┃,┣┳┛,
  %b3 = %b3 $+ ╹.╹,┗━┛,┗━╸,╺┻┛,┗━╸,╹..,┗━┛,╹.╹,╹,┗━┛,╹.╹,┗━╸,╹.╹,╹.╹,┗━┛,╹..,┗┻┛,╹┗╸,
  %b1 = %b1 $+ ┏━┓,╺┳╸,╻.╻,╻.╻,╻.╻,╻.╻,╻.╻,╺━┓,┏━.,╻.,.━┓,┏┓,...,.┓,.┏╸,╻,╺┓.,...,
  %b2 = %b2 $+ ┗━┓,.┃.,┃.┃,┃┏┛,┃╻┃,┏╋┛,┗┳┛,┏╋┛,┃..,┗┓,..┃,..,...,..,.┫.,┃,.┣.,┏━┛,
  %b3 = %b3 $+ ┗━┛,.╹.,┗━┛,┗┛.,┗┻┛,╹.╹,.╹.,┗━╸,┗━.,.╹,.━┛,..,╺━╸,..,.┗╸,╹,╺┛.,...,
  %b1 = %b1 $+ ┏━┓┏━╸,┏━┓┏━╸,╻.╻┏━╸,┏━┓┏━┓,╻┏╸,╺┓╻,.╻.,.╻.,...,.....,..,...,┏┓
  %b2 = %b2 $+ ┣━┫┣╸.,┃.┃┣╸.,┃.┃┣╸.,┗━┓┗━┓,┗╋┓,┏╋┛,╺╋╸,╺╋╸,...,╺━━━╸,┏┓,┏━┓,┃┃
  %b3 = %b3 $+ ╹.╹┗━╸,┗━┛┗━╸,┗━┛┗━╸,┗━┛┗━┛,╺┛╹,╹┗╸,.┃.,╺╋╸,╹╹╹,.....,┗┛,┗━┛,┗┛
  var %s = $replace($upper($1-),`\,卐,`/,卍,`T,†,--,—,$chr(160),$chr(32))
  var %i = 1, %n = 3
  while (%i <= %n) {
    %cmd $replace($regsubex(%s,/(*UTF8)(.)/g, $& 
      $iif($gettok(%b [ $+ [ %i ] ],$poscs(%a,\t),44),$v1,\t)),.,$chr(160))
    inc %i
  } 
  if (!$event) && (!$editbox($active)) editbox -ap /fut
} ; by Raccoon 2016 

I'll just sit back and watch the world burn.

Enjoy! ;)