Update: 2016.09.24
;a My nicknames - 2016.09.24 - [by Mi9]
; http://hawkee.com/snippet/17199/
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
;
menu menubar,channel,status {
My Nicknames
.Random Nickname:rand-nick
.-
.Add nickname...:add-nick
.-
.$rf-nick(1):nick $edit-nick(1)
.$rf-nick(2):nick $edit-nick(2)
.$rf-nick(3):nick $edit-nick(3)
.$rf-nick(4):nick $edit-nick(4)
.$rf-nick(5):nick $edit-nick(5)
.$rf-nick(6):nick $edit-nick(6)
.$rf-nick(7):nick $edit-nick(7)
.$rf-nick(8):nick $edit-nick(8)
.$rf-nick(9):nick $edit-nick(9)
.-
.Remove
..$rf-nick(1):{ rem-nick 1 }
..$rf-nick(2):{ rem-nick 2 }
..$rf-nick(3):{ rem-nick 3 }
..$rf-nick(4):{ rem-nick 4 }
..$rf-nick(5):{ rem-nick 5 }
..$rf-nick(6):{ rem-nick 6 }
..$rf-nick(7):{ rem-nick 7 }
..$rf-nick(8):{ rem-nick 8 }
..$rf-nick(9):{ rem-nick 9 }
..-
..$iif(%mynicks,A l l):{ if ($input(Are you sure?,8,Removing all nickmane)) rem-nick }
.-
.Set Recovery Mode $+ $chr(58) $iif($group(#rn.UNOTIFY) == on,$remove($group(#rn.UNOTIFY).name,#rn.)) $iif($group(#rn.Nick-JPQ) == on,$remove($group(#rn.Nick-JPQ).name,#rn.)):{
if $group(#rn.UNOTIFY) == on { .disable #rn.UNOTIFY | .enable #rn.Nick-JPQ }
else { .disable #rn.Nick-JPQ | .enable #rn.UNOTIFY }
}
.Add Nickname for Recovery:{
set %recover.nick $$?="Enter Nickname for Recovery"
if ($notify == $false) .notify on
if ($notify(%recover.nick) == $null) { .notify %recover.nick | notify }
echo 4 ::: %recover.nick nickname was added to be recovered when it's possible.
}
.$iif(%recover.nick != $null,Cancel $chr(91) %recover.nick $chr(93) recovery,):{
if ($notify(%recover.nick) && $?!="Remove %recover.nick from notify list?" == $true) .notify -r %recover.nick
echo 4 ::: Cancel %recover.nick recovery.
unset %recover.nick
}
}
alias rand-nick { tnick User $+ - $+ $upper($rand(a,z)) $+ $rand(0,9) $+ $rand(0,9) $+ $rand(0,9) }
alias rf-nick { if ($gettok(%mynicks,$1,59)) return $1 $+ . $gettok($ifmatch,-1,44) }
alias add-nick {
:next
if ($numtok(%mynicks,59) > 8) { echo 2 Sorry, nickname list is full. | return }
var %add.nick $$?="Enter nickname"
set %mynicks $addtok(%mynicks,%add.nick,59)
echo 5 Added nick: %add.nick
if ($numtok(%mynicks,59) < 8) && ($input(Do you want to add another nickname?,8,Adding a nick)) goto next
}
alias edit-nick { if ($gettok(%mynicks,$1,59)) return $gettok($ifmatch,1,44) }
alias rem-nick {
if ($gettok(%mynicks,$1,59)) {
echo 5 The nickname [ [ $gettok($ifmatch,-1,44) ] ] was removed.
set %mynicks $deltok(%mynicks,$1,59)
}
else unset %mynicks
}
#rn.UNOTIFY on
on *:UNOTIFY:{ if (%recover.nick != $null && $me != %recover.nick && $nick == %recover.nick) nick %recover.nick }
#rn.UNOTIFY end
#rn.Nick-JPQ off
alias -l cfprot { if $timer(. $+ $me).type == online halt | else .timer. $+ $me 1 10 return }
on *:NICK:{ if (%recover.nick != $null && $me != %recover.nick) { cfprot | nick %recover.nick } }
on *:JOIN:#:{ if (%recover.nick != $null && $me != %recover.nick) { cfprot | nick %recover.nick } }
on *:PART:#:{ if (%recover.nick != $null && $me != %recover.nick) { cfprot | nick %recover.nick } }
on *:QUIT:{ if (%recover.nick != $null && $me != %recover.nick) { cfprot | nick %recover.nick } }
#rn.Nick-JPQ end
;z