I downloaded UnrealIRCD and messed around with it a bit. Since I'm on 98, I had a hard time finding services. Thanks to the people here I was able to find Epona IRC Services. Well, I noticed Epona doesn't have a HostServ. So I made one! Its not the greatest but it does the job. =p

Stick it in its own remote and its good to go. I based it off of Anope's so it just waits for /msg's

Your Network must support /chghost and the bot must have IRCop access.

;mIRC HostServ written by DarkLordPazuzu
;Originally made on Unreal 3.2.3 
;The Bot Must Have IRCop Access and 
;Your Network Must Support /chghost inorder for this to work.

on *:TEXT:*:?:{
  if ($1 == set) && ($2 == $nick) && ($3) { 
    writeini -n vHosts.ini vHosts $nick $3 
    writeini -n oHosts.ini oHosts $nick $remove($address($nick,2),*!*@)
    echo -ts * $+ $nick $+ * $1-
    halt
  }
  if ($1 == set) && ($2 != $nick) { 
    msg $nick please sign onto that nickname before you set a vHost to it!
    echo -ts * $+ $nick $+ * $1-
    halt 
  }
  if ($1 == on) { 
    chghost $nick $readini(vHosts.ini, vHosts, $nick)
    echo -ts * $+ $nick $+ * $1-
    halt 
  }
  if ($1 == off) { 
    chghost $nick $readini(oHosts.ini, oHosts, $nick)
    echo -ts * $+ $nick $+ * $1-
    halt 
  }
  if ($1 == help) && (!$2) {
    notice $nick ON Activates your assigned vHost.
    notice $nick OFF Deactivates your assigned vHost.
    notice $nick SET assign vHost to your current nickname. example: /msg hostserv set HostServ I.Am.HostServ
  }
  if ($1 == help) && ($2 == on) {
    notice $nick Syntax: ON
    notice $nick Activates the vhost currently assigned to the nick in use.
    notice $nick When you use this command any user who performs a /whois
    notice $nick on you will see the vhost instead of your real IP address.
  }
  if ($1 == help) && ($2 == off) {
    notice $nick Syntax: OFF
    notice $nick Deactivates the vhost currently assigned to the nick in use.
    notice $nick When you use this command any user who performs a /whois
    notice $nick on you will see your real IP address.
  }
  if ($1 == help) && ($2 == set) {
    notice $nick Syntax: SET
    notice $nick Assigns a vhost of your choice to the nick in use.
    notice $nick When you use this command any user who performs a /whois
    notice $nick on you will see the vhost instead of your real IP address.
  }
}

on *:SNOTICE:*Client Connecting*:{
  if ($readini(vHosts.ini, vHosts, $nick)) {
    writeini -n oHosts.ini oHosts $nick $remove($address($nick,2),*!*@)
    chghost $nick $readini(vHosts.ini, vHosts, $nick)
    halt
  }
}

on *:open:?:{ .timer 1 3 closemsg $nick }