Just a little script to help with registering and identifying nicks with nickserv

Effective AutoID for as many nicks as you want to add

i was bored so i decided to submit something :) lol

;=============================================================
;=== Auto ID system by Urza                                ===
;=== Simple to use through popups                          ===
;=== Allows simple but effective AutoID for multiple nicks ===
;=== Also Added a nicklist popup for ghosting              ===  
;=============================================================

on *:connect: { /i $me }
on *:nick: { 
  if ($nick == $me) /i $newnick 
  elseif ($read(AutoID.txt,s,$newnick)) {
    msg $newnick Dont Use my nick
    .msg nickserv ghost $newnick $read(AutoID.txt,s,$newnick)
  }
}

alias i { if ($read(AutoID.txt,s,$1)) .msg Nickserv identify $read(AutoID.txt,s,$1) }
alias register.nick { 
  var %pass = $$?="Enter a case sensitive password. MUST be atleast 5 characers"
  .msg Nickserv register %pass $$?="Enter Your E-mail. A valid E-mail should be used for password retrieval purposes" 
  if ($input(Would you like to add $+(',$me,') To AutoID?,qy,Add to AutoID?) == $true) {
    write AutoID.txt $me %pass
    echo -ai2 $+(',$me,') Added to AutoID list with password %pass
  }
}
alias drop.nick { 
  .enable #dropnick
  .msg nickserv status $me
}
#dropnick off
on ^*:notice:$(STATUS $me *):?: { 
  if ($3 == 3) { 
    /msg nickserv status $me
    .msg Nickserv drop
    /write -ds $+ $me AutoID.txt
    echo -ai2 Nick $+(',$me,') Has been dropped
  }
  else echo -ai2 You must be identified to drop a nick.
  .disable #Dropnick 
}
#dropnick end
alias AutoID.IDNow { 
  if ($read(AutoID.txt,s,$me)) /i $me
  else .msg Nickserv identify $$?="Enter your password"
  echo -ai2 ID sent.
}
alias AutoID.Add {
  if ($read(AutoID.txt,s,$me)) { echo -ai2 The nick $+(',$me,') is already on AutoID list. | halt }
  write AutoID.txt $me $$?="Enter the Password for $+(',$me,') $+ . AutoID will use this password to automitcally Identify you each time you use this nick" 
  .msg Nickserv identify $! 
  echo -ai2 $+(',$me,') Added to AutoID list with password $!
}
alias AutoID.Del {
  if (!$read(AutoID.txt,s,$me)) { echo -ai2 The nick $+(',$me,') is not on AutoID list. | halt }
  $iif($input(Are you sure you want to remove the nick $+(',$me,') from AutoID?,yw,Verify Autonick Removal) == $true,/write -ds $+ $me AutoID.txt)
  echo -ai2 $+(',$me,') Removed from AutoID list
}
alias AutoID.List {
  if ($ini(settings.ini,AutoID) == 0) { echo -a **** AutoID list is currently Empty | halt }
  var %x = 1
  var %AutoID.Lines = $lines(AutoID.txt)
  if ($read(AutoID.txt,1) == $null) echo -a AutoID list is currently empty
  else {
    echo -a ******** AutoID List ********
    echo -a Nick $str(-,5) Password
    while (%x <= %AutoID.Lines) {
      var %nick = $gettok($read(AutoID.txt,%x),1,32)
      var %pass = $gettok($read(AutoID.txt,%x),2,32)
      echo -a %nick $str( ,$calc(11 - $len(%nick))) %pass
      inc %x
    }
  }
}
menu nicklist {
  Ghost $+(',$1,'): { .msg Nickserv ghost $1 $iif($read(AutoID.txt,s,$1),$read(AutoID.txt,s,$1),$$?="Enter password for $1") | /nick $1 }
}
menu channel {
  Nick Controls
  .Change nick: /nick $$?="Enter your new nick"
  .Register $+(',$me,'): { /Register.Nick }
  .Drop $+(',$me,'): { /Drop.Nick }
  .Autoghosting $iif($group(#autoghost).status == on,Off,On)
  .Identify
  ..Identify now: { /AutoID.IDNow }
  ..Add AutoID for $+(',$me,'): { /AutoID.Add }
  ..Remove AutoID for $+(',$me,'): { /AutoID.Del }
  ..View AutoID list: { /AutoID.List }
}