Also Known As

By tye
Platform:  mIRC
Published  Sep 29, 2003
Updated  Jun 18, 2006
This snippet uses hash tables to track which nicknames a user has used. It displays a user's nicknames when they join a channel or when you request the information through the nicklist popup. This snippet uses mask type 3 to track users. ; Paste into the remotes section of mIRC (Alt+R).
; After the code has been pasted either restart mIRC
; or type '/hmake trackusers 10' into your Status Window
; Tye @ DALnet #mIRC/Undernet #hawkee.com, #mIRC.net
; tye at tye.ca
ON *:START: {
hmake trackusers 10
if ($isfile(trackusers.dat)) {
hload trackusers trackusers.dat
}
}
on *:JOIN:#: {
if ($hget(trackusers,$address($nick,3))) {
var %n = $ifmatch
if ($istok(%n,$nick,32)) { var %d = $deltok(%n,$findtok(%n,$nick,1,32),32) }
else { var %d = %n }
if (!%d) { return }
echo $colour(info) -ti2 $chan * $nick has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
if (!$istok(%n,$nick,32)) {
hadd trackusers $address($nick,3) %n $nick
}
}
else {
hadd trackusers $address($nick,3) $nick
}
}
on *:NICK: {
if ($hget(trackusers,$address($newnick,3))) {
var %n = $ifmatch
if (!$istok(%n,$newnick,32)) {
hadd trackusers $address($newnick,3) %n $newnick
}
}
else {
hadd trackusers $address($nick,3) $newnick
}
}
menu nicklist {
Track Users
.View Other Nicknames:{
if (!$address($$1,3)) { echo $colour(info) -ti2 # * IAL not updated for $$1 $+ , performing userhost lookup | userhost $$1 | return }
if ($hget(trackusers,$address($$1,3))) {
var %n = $ifmatch
if ($istok(%n,$$1,32)) { var %d = $deltok(%n,$findtok(%n,$$1,1,32),32) }
else { var %d = %n }
if (!%d) { goto notknown }
echo $colour(info) -ti2 # * $$1 has also used the nickname $+ $iif($numtok(%d,32) > 1,s:,:) %d
}
else {
:notknown
echo $colour(info) -ti2 # * $$1 has not been known by any other nickname
}
}
.Reset:hdel trackusers $address($$1,3)
}
ON *:EXIT: {
if ($hget(trackusers)) { hsave -o trackusers trackusers.dat }
}

Comments

Sign in to comment.
raz-away   -  May 10, 2009
hi i am getting the following error and was wondering if anyone else came across this. This code is EXCELLENT - thanks

/hadd: no such table 'trackusers' (line 2280, first.mrc)

this is from the status window in MirC
 Respond  
Virus   -  May 25, 2008
The only time I get any info on users is when I request it, can you see any reason I don\'t get the \"on JOIN\" info?
 Respond  
jko224   -  Jul 22, 2006
Been using this script for quiet a long time & love it. Any chance of adding a popup so you can manually enter a nick to check other nicks used? This would be helpfull when a certian nick has left the channel & still allow you to look it up.
 Respond  
Monkey   -  Jun 22, 2006
Can anyone tell me how I can ad a log to this script?
 Respond  
grinch157   -  Mar 26, 2004
tye, is there a way to have this do the reverse and track a ip by nick(s)?
 Respond  
tye   -  Jan 13, 2004
The snippet adds an item named \'Track Users\' to the nicklist popup (when you right click a user\'s name). I don\'t know what you\'re talking about when you say it \'vetoes use of the normal pop-up menu\'. It doesn\'t do anything to stop you from using your popup menus.
 Respond  
VVhispers   -  Jan 13, 2004
Tye, this is a good script and I love it for use when someone joins under a different nickname than usual...But the script vetoes use of the normal pop-up menu when you right-click someone\'s name...Now, typing in \"/notify JimBob\" or \"/ignore JimBob\" really isn\'t that hard, it\'s still a bit less convenient to not have it...
 Respond  
tye   -  Dec 30, 2003
Many people have successfulyl used this script and I thoroughly tested it before I posted it here. If you are having problems using it send me message or email me at tye@mirc.net and I will help you set it up. You say the code shows some errors. Would you please show me what errors are in the code?
 Respond  
Kurumizawa   -  Dec 29, 2003
Stupid script that\'s not works. Author should add some useful help vecause the code shows some errors
 Respond  
Are you sure you want to unfollow this person?
Are you sure you want to delete this?
Click "Unsubscribe" to stop receiving notices pertaining to this post.
Click "Subscribe" to resume notices pertaining to this post.