This is a simple bombscript.
Just load it in the remotes of your bot
Type !bomb Nick
Language is dutch
;!bomb script by DjSxX
;For questions irc.chatters4all.nl
;join #radiocandymen for questions
On *:LOAD: {
writeini games.ini bomb min 15
writeini games.ini bomb max 60
writeini games.ini bomb status 0
}
on *:TEXT:*:#: {
if ($strip($$1) == !Bomb) {
if ($bomb == yes) { msg $chan er ligt al een bom | halt }
if ($$2) {
if ($$2 !ison $chan) {
msg $chan dacht je dat je dat ik iemand die hier niet is een bom ga geven >_> Als straf krijg jij er een!
set %nick $nick
}
if ($$2 ison $chan) {
if ($$2 == $me) {
msg $chan Grapjas :') Ik ga $$2 niet opblazen hoor ;)
msg $chan Als straf krijg jij er 1 $nick
set %nick $nick
}
else {
if ($nick($chan,$$2).idle > 300) { if ($nick != $me) {
msg $chan $$2 is al langer dan 5 minuten afwezig... Zo kan ik ook iemand opblazen hoor :S Laf hoor (A)
set %nick $nick }
else { set %nick $$2 }
}
else {
set %nick $$2
}
}
}
set %chan $chan
.writeini games.ini bomb status 1
var %rand $rand(1,4)
if (%rand == 1) { .set %bcolor Blauw }
if (%rand == 2) { .set %bcolor Rood }
if (%rand == 3) { .set %bcolor Oranje }
if (%rand == 4) { .set %bcolor Paars }
var %randmsg $rand(1,3)
if (%randmsg == 1) { describe %chan duwt %nick een huid-magnetische bom in zijn handjes }
if (%randmsg == 2) { describe %chan bind een bom rond %nick $+ 's nek }
if (%randmsg == 3) { describe %chan geeft %nick een automatisch-terugvliegende-als-je-ze-weggooit-bom }
.timermsg1 1 1 msg %chan %nick kan deze bom ontmantelen door een draad door te knippen! Er is een Blauwe, een Rode, een Oranje en een Paarse draad, ik denk dat je zal moeten gokken;) SUCCES!
.timermsg2 1 3 msg %chan %nick $+ : Type !cutwire <4ROOD|2BLAUW|7ORANJE|6PAARS> om een draad door te knippen, wees snel, want de bom kan elk moment ontploffen!
.timerstartcount 1 3 .timerexplode 1 $btime btimeover
}
}
if ($strip($$1) == !Cutwire) {
if ($bomb == yes) && (%nick == $nick) {
if ($$2 != Blauw) && ($$2 != Rood) && ($$2 != Oranje) && ($$2 != Paars) { msg %chan $$2 is een ongeldige kleur. | halt }
if ($$2 == %bcolor) {
msg %chan :O GEFELICITEERD %nick $+ ! Je hebt de bom ONTMANTELD!
.timerexplode off
bdone
}
if ($$2 != %bcolor) {
kick %chan %nick $bkaboom
msg %chan Voortaan zullen we het zonder %nick moeten doen :(
bdone
}
}
}
}
alias btimeover {
kick %chan %nick $bkaboom
msg %chan Tja, het lijkt erop dat %nick wat tijd tekort had (: Een kandidaat die het denkt wél te kunnen?
bdone
}
alias bdone {
unset %nick
unset %chan
unset %bcolor
writeini games.ini bomb status 0
}
alias bomb {
if ($readini(games.ini,bomb,status)==1) { return yes }
}
alias bkaboom {
return 8,1*K7AB4OO7M!8*
}
alias btime {
var %min $readini(games.ini,bomb,min)
var %max $readini(games.ini,bomb,max)
var %rand $rand($readini(games.ini,bomb,min),$readini(games.ini,bomb,max))
return %rand
}
Je hoeft hiervoor eigenlijk geen ini's te gebruiken je zou ook zoiets kunnen doen:
on *:TEXT:*:#: {
if ($1 == !bomb && $2 && !%game) {
set %game $true
if ($2 == $me) {
msg # Grapjas :') Ik ga mezelf niet opblazen hoor ;)
msg # Als straf krijg jij er 1 $nick
set %nick $nick
}
elseif ($2 !ison #) { msg # Dacht je dat je dat ik iemand die hier niet is een bom ga geven >_> Als straf krijg jij er een! | set %nick $nick }
elseif ($nick(#,$2).idle > 300) { msg # $2 is al langer dan 5 minuten afwezig... Zo kan ik ook iemand opblazen hoor :S Laf hoor (A) | set %nick $nick }
else set %nick $2
set %defuseWire $gettok(Blauw|Rood|Oranje|Paars,$r(1,4),124)
var %msg $r(1,3)
if (%msg == 1) describe # duwt %nick een huid-magnetische bom in zijn handjes
elseif (%msg == 2) describe # bind een bom rond %nick $+ 's nek
elseif (%msg == 3) describe # geeft %nick een boomerang-bom
timer 1 1 msg # %nick kan deze bom ontmantelen door een draad door te knippen! Er is een Blauwe, een Rode, een Oranje en een Paarse draad, ik denk dat je zal moeten gokken;) SUCCES!
timer 1 3 msg # %nick $+ : Type !cutwire <4ROOD|2BLAUW|7ORANJE|6PAARS> om een draad door te knippen, wees snel, want de bom kan elk moment ontploffen!
timerExplode 1 $r(15,62) bExplode # 1
}
if ($1 == !cutwire && $nick == %nick && %game) {
if (!$regex($2,/^(Rood|Blauw|Oranje|Paars)$/Si)) { msg # $2 is een ongeldige kleur. | halt }
if ($2 == %defuseWire) {
msg # :O GEFELICITEERD %nick $+ ! Je hebt de bom ONTMANTELD!
.timerExplode off
bFinish
}
else bExplode #
}
}
alias bExplode {
kick $1 %nick 8,1*K7AB4OO7M!8*
if ($2 = 1) timer 1 1 msg $1 Tja het lijkt erop dat %nick wat tijd tekort had $chr(40) $+ : Een kandidaat die het denkt wél te kunnen?
else timer 1 1 msg $1 Voortaan zullen we het zonder %nick moeten doen : $+ $chr(40))
bFinish
}
alias bFinish { unset %defuseWire %nick %game | timerExplode off }
Ik vond hem zo ook wel goed werken eigenlijk :) maar idd zonder ini's kan het ook