• You can control the Winamp from your mIRC Toolbar. In Settings there's an Announcer option,
  it's up to you whether use it or not.

• Winamp Toolbar NOTE: It works with the original mIRC's toolbar, if you have any custom
  toolbar it won't work... (Or you can modify it and add these items to your own Toolbar.)

You can download the full package from [HERE](http://deadcell.eu5.org/mSL/DCAmp v1.2.rar)

; *******************
; DCAmp v1.2
; *******************
alias DCAmp.About { .echo -aq $input(DCAmp v1.1 by MaSOuD. $+ $crlf $+ $crlf $+ Read the 'Readme.txt' for instruction and contacts. $+ $crlf $+ $crlf $+ Enjoy! : $+ $chr(41),oi8vg,About DCAmp) }
alias -l DC.Dir { return $qt($+($scriptdir,$iif($1,$1-))) }
alias -l DCR { return $readini($DC.Dir(Winamp.ini),$1,$iif($2,$2)) }
alias -l DCW { .writeini -n $DC.Dir(Winamp.ini) $1- }
alias -l DCRe { .remini $DC.Dir(Winamp.ini) $1- }
alias -l Load.Image { did -g $$1- }
alias -l DC.Imgs { return $DC.Dir(Images\ $+ $iif($1-,$1-)) }
alias -l DC.DialogIco { return $DC.Imgs($+($1,-,$DCR(Settings,Icons),.ico))  }
alias -l DC.Dll { return $DC.Dir(DLLs\ $+ $iif($1-,$1-)) }
alias -l MDX { return $dll($DC.Dll(MDX.dll),$1,$2-) }
alias -l Bars { return $noqt($DC.Dll(Bars.mdx)) }
alias -l Mp3mIRC {
  if ($1) { dll $DC.Dll(Mp3mIRC.dll) $1- }
  else { return $DC.Dll(Mp3mIRC.dll) }
}

alias -l Swamp {
  if ($1) { dll $DC.Dll(Swamp.dll) $1- }
  else { return $DC.Dll(Swamp.dll) }
}

alias DCVol { dialog $iif($dialog(DCVol),-v,-m DCVol) DCVol }
dialog DCVol {
  size -1 -1 65 114
  option dbu
  icon $DC.DialogIco(Volume)
  title "Volume"
  text "Master", 1, 8 7 40 9
  list 2, 12 16 11 80, size
  check "Mute", 3, 5 98 25 10, push
  text "Wave", 4, 40 7 40 9
  list 5, 43 16 11 80, size
  check "Mute", 6, 35 98 25 10, push
  box "", 7, 2 0 61 112
  box "", 8, 2 0 31 112
}

on *:dialog:DCVol:*:*:{
  if ($devent == init) {
    MDX SetMircVersion $version
    MDX MarkDialog $dname
    MDX SetFont $dname 1,4 ANSI 13 700 Tahoma
    MDX SetBorderStyle $dname 3,6 clientedge
    MDX SetControlMDX $dname 2,5 trackbar vertical noticks > $Bars
    MDX SetBorderStyle $dname 2,5
    did -i $dname 2 1 params $calc(65535 - $vol(master)) 0 65535
    did -i $dname 5 1 params $calc(65535 - $vol(wave)) 0 65535
    if ($vol(master).mute) did -c $dname 3
    if ($vol(wave).mute) did -c $dname 6
  }
  if ($devent == sclick) {
    if ($did == 2) { var %WM = $DCAmp.Vol(2) | vol -v %WM }
    elseif ($did == 3) { vol $+(-vu,$DCAmp.Mute(3)) }
    elseif ($did == 5) { var %WM = $DCAmp.Vol(5) | vol -w %WM }
    elseif ($did == 6) { vol $+(-wu,$DCAmp.Mute(6)) }
  }
}

alias DCAmp {
  if (!$isfile($DC.Dir(Winamp.ini))) {
    DCW Settings TB 1
    DCW Settings Icons 3
    DCW Settings Status 1
    DCW Settings Method 3
    DCW Settings Target 2
    DCW Settings Msg $DCAmp.Msg
    var %x = C:\Program Files\Winamp\winamp.exe
    if ($isfile($qt(%x))) { DCW Settings Path %x }
  }
  dialog $iif($dialog(DCAmp),-v,-m DCAmp) DCAmp
}

dialog DCAmp {
  title "Winamp Control"
  size -1 -1 186 156
  option dbu
  icon $DC.DialogIco(Settings)
  list 1, -6 -1 207 30, size
  list 2, 4 4 25 25, size
  text "Winamp Controller", 3, 30 5 170 15
  text "Is it your favorite media player? Enjoy it!", 4, 30 19 170 8
  tab "General", 5, 3 30 181 109
  box " Winamp ", 6, 7 47 173 38, tab 5
  text "Please locate the Winamp's executable file:", 7, 13 58 154 8, tab 5
  edit "", 8, 18 67 132 10, disable tab 5 autohs
  button "...", 9, 152 66 17 12, tab 5
  box " Toolbar ", 10, 7 87 173 48, tab 5
  check "Enable Toolbar", 11, 13 98 90 10, tab 5
  text "Icon Pack:", 12, 14 117 29 10, tab 5
  combo 13, 44 116 50 39, tab 5 size drop
  icon 14, 96 113 16 16,  $DC.Imgs(None.bmp), 0, tab 5 noborder
  text "Toolbar Items:", 19, 127 94 47 8, tab 5
  list 20, 125 103 50 28, tab 5 size check
  tab "Announcement", 15
  box "", 16, 7 47 173 88, tab 15
  check "Enable Announcer", 17, 13 57 62 10, tab 15
  text "Method:", 18, 78 59 26 8, tab 15 right
  combo 21, 106 58 69 50, tab 15 size drop
  text "Message:", 22, 9 77 28 8, tab 15 right
  edit "", 23, 16 86 125 10, tab 15 autohs
  button "Preview", 24, 143 85 32 12, tab 15
  text "Send To:", 25, 9 106 28 8, tab 15 right
  combo 26, 17 115 48 50, tab 15 size drop
  text "Channels:", 28, 71 106 28 8, tab 15
  combo 29, 70 115 77 50, tab 15 size drop
  button "+", 30, 149 114 12 12, tab 15
  button "-", 31, 163 114 12 12, tab 15
  button "&Tags", 32, 4 142 37 12
  button "&OK", 33, 107 142 37 12
  button "&Cancel", 34, 145 142 37 12, cancel
}

on *:dialog:DCAmp:*:*:{
  if ($devent == init) {
    MDX MarkDialog $dname
    MDX SetMircVersion $version
    MDX SetBorderStyle $dname 1,2 Simple
    MDX SetControlMDX $dname 2 Toolbar Flat NoDivider Wrap List Arrows > $Bars
    MDX SetColor $dname 1,2,3,4 background $rgb(199,199,199)
    MDX SetColor $dname 1,2,3,4 textbg $rgb(199,199,199)
    MDX SetColor $dname 3 text $rgb(65,141,255)
    MDX SetColor $dname 4 text $rgb(0,0,0)
    MDX SetFont $dname 3 +a 25 700 Ringbearer
    MDX SetFont $dname 4 +a 14 700 Arial
    did -i $dname 2 1 BmpSize 32 32
    did -i $dname 2 1 SetImage Icon Normal $noqt($DC.Imgs(Winamp.ico))
    did -a $dname 2 +a 1 $chr(9) $+ Winamp Controller
    did -b $dname 1,2
    DCAmp.Init
  }
  if ($devent == sclick) {
    if ($did == 9) { DCAmp.SetPath }
    elseif ($did == 32) { DCAmp.Tags }
    elseif ($did == 13) { Load.Image $dname 14 $DC.Imgs($+(Play-,$did(13).sel,.ico)) }
    elseif ($did == 24) {
      var %x = $did(21).sel
      if (%x == 1) { echo $color(action) -atg * $me $replace($did(23),<c>,$chr(3),<b>,$chr(2),<u>,$chr(31),<r>,$chr(22),<o>,$chr(15),<Song>, MetallicA - The Unforgiven III,<Len1>,7:46,<Len2>,7m 46s,<Kbps>,192,<kHz>,44.1,<Chnl>,Stereo) }
      elseif (%x == 2) { echo $color(normal) -atg $+(<,$me,>) $replace($did(23),<c>,$chr(3),<b>,$chr(2),<u>,$chr(31),<r>,$chr(22),<o>,$chr(15),<Song>, MetallicA - The Unforgiven III,<Len1>,7:46,<Len2>,7m 46s,<Kbps>,192,<kHz>,44.1,<Chnl>,Stereo) }
      elseif (%x == 3) { echo $color(info) -atg $replace($did(23),<c>,$chr(3),<b>,$chr(2),<u>,$chr(31),<r>,$chr(22),<o>,$chr(15),<Song>, MetallicA - The Unforgiven III,<Len1>,7:46,<Len2>,7m 46s,<Kbps>,192,<kHz>,44.1,<Chnl>,Stereo) }
    }
    elseif ($did == 30) {
      var %x = #$$?="Enter a channel name. (You can use #Chan@Network for network specific items.)"
      if (%x != $null) { did -a $dname 29 %x }
    }
    elseif ($did == 31) {
      if ($did(29).sel != $null) { did -d $dname 29 $did(29).sel }
    }
    elseif ($did == 33) {
      var %w = DCW Settings,%r = DCRe Settings
      if ($did(8) != $null) && (*\*\* iswm $did(8)) { %w Path $did(8) }
      else { %r Path }
      %w TB $did(11).state
      %w Icons $did(13).sel

      var %a = 1,%items
      while ($did(20,%a) != $null) {
        if ($did(20,%a).cstate == 1) { %items = $addtok(%items,$did(20,%a),32) }
        inc %a
      }

      if (%items != $null) { %w TBItems %items }
      else { %r TBItems }

      %w Status $did(17).state
      %w Method $did(21).sel
      %w Msg $iif($did(23) == $null,$DCAmp.Msg(Def),$v1)
      %w Target $did(26).sel
      var %x = 1,%chans
      while ($did(29,%x) != $null) { %chans = $addtok(%chans,$v1,32) | inc %x }
      if (%chans != $null) { %w Channels %chans }
      else { %r Channels }
      .timerDCAmp $iif($did(17).state == 1, 0 1 DCAmp.Check,off)
      dialog -c $dname
      DCAmp.TB
    }
  }
}

alias DCAmp.Init {
  didtok DCAmp 13 44 Gray,Light Blue,Ocean
  didtok DCAmp 20 32 PrevTrack Play Pause Stop NextTrack Volume Settings Winamp
  didtok DCAmp 21 44 Action,Message,Echo on Active
  didtok DCAmp 26 32 All Active Selected
  did -a DCAmp 8 $iif($DCR(Settings,Path) != $null,$v1,Unknown! Click the '...' button to set it)
  var %x = $iif($DCR(Settings,Icons) isnum 1-,$v1,1),%c = did -c DCAmp
  %c 13 %x
  var %a = 1,%items = $DCR(Settings,TBItems)
  while ($did(20,%a) != $null) {
    if ($istok(%items,$v1,32)) { did -s $dname 20 %a }
    inc %a
  }
  if ($DCR(Settings,TB) == 1) { %c 11 }
  if ($DCR(Settings,Status) == 1) { %c 17 }
  if ($DCR(Settings,Method) != $null) { %c 21 $v1 }
  if ($DCR(Settings,Channels) != $null) { didtok DCAmp 29 32 $v1 }
  if ($DCR(Settings,Target) != $null) { %c 26 $v1 }
  did -a DCAmp 23 $DCAmp.Msg
  Load.Image DCAmp 14 $DC.Imgs($+(Play-,%x,.ico))
  DCAmp.TB
}

alias DCAmp.SetPath {
  :Again
  var %tmp = $sfile(C:\ *.exe,Open 'Winamp.exe',Open)
  if (%tmp == $null) halt
  if ($right(%tmp,10) == winamp.exe) { .echo -aq $input(Thank You!,oi8vg,Winamp) }
  else { .echo -aq $input(Invalid file!,wovg,Winamp) | goto Again }
  if ($dialog(DCAmp)) { did -ra DCAmp 8 %tmp }
  else { DCW Settings Path %tmp }
}

alias DCAmp.Tags {
  var %msg =  Mp3 Tags: $+ $crlf $+ $&
    <Song> returns Song/Title. $+ $crlf $+ $&
    <Len1> returns Length (3:10) $+ $crlf $+ $&
    <Len2> returns Length (3m 10s) $+ $crlf $+ $&
    <Kbps> returns Bitrate. $+ $crlf $+ $&
    <kHz> returns Samplerate. $+ $crlf $+ $&
    <Chnl> returns Stereo/Mono. $+ $crlf $+ $crlf $+ $&
     Control Codes: $+ $crlf $+ $&
    <c> instead of Ctrl+K (Color) $+ $crlf $+ $&
    <b> instead of Ctrl+B (Bold) $+ $crlf $+ $&
    <u> instead of Ctrl+U (Underline) $+ $crlf $+ $&
    <i> instead of Ctrl+I (Italic) $+ $crlf $+ $&
    <r> instead of Ctrl+R (Reverse) $+ $crlf $+ $&
    <o> instead of Ctrl+O (Plain)
  .noop $input(%msg,ok60,Tags)
}

alias DCAmp.Run {
  var %winamp = $qt($DCR(Settings,Path))
  if ($isfile(%winamp)) { run %winamp }
}
alias DCAmp.Vol { return $calc(65535 - $gettok($did(DCVol,$1,1).text,1,32)) }
alias DCAmp.Mute { return $iif($did(DCVol,$1).state == 1, 1, 2) }
alias DCAmp.Nav {
  if ($istok(Play Stop Pause NextTrack PrevTrack,$1,32)) {
    if ($dll($Mp3mIRC,WinampStatus,3) isnum 0-3) { Swamp WinAmpCmd $1 }
  }
}

alias -l DCAmp.TBI { return $istok($DCR(Settings,TBItems),$1,32) }

alias DCAmp.TB {
  if ($DCR(Settings,TBItems) == $null) return
  if ($DCR(Settings,TB) == 1) {
    toolbar -r
    toolbar -is _Winampsep
    var %i = $DCR(Settings,Icons)
    if ($DCAmp.TBI(PrevTrack)) { toolbar -az1 W.Prev "Previous Track" $DC.Imgs($+(Prev-,%i,.ico)) "/DCAmp.Nav PrevTrack" }
    if ($DCAmp.TBI(Play)) { toolbar -az1 W.Play "Play" $DC.Imgs($+(Play-,%i,.ico)) "/DCAmp.Nav Play" }
    if ($DCAmp.TBI(Pause)) { toolbar -az1 W.Pause "Pause" $DC.Imgs($+(Pause-,%i,.ico)) "/DCAmp.Nav Pause" }
    if ($DCAmp.TBI(Stop)) { toolbar -az1 W.Stop "Stop" $DC.Imgs($+(Stop-,%i,.ico)) "/DCAmp.Nav Stop" }
    if ($DCAmp.TBI(NextTrack)) { toolbar -az1 W.Forw "Next Track" $DC.Imgs($+(Next-,%i,.ico)) "/DCAmp.Nav NextTrack" }
    if ($DCAmp.TBI(Volume)) { toolbar -az1 W.Vol "Volume Control" $DC.Imgs($+(Volume-,%i,.ico)) "/DCVol" }
    if ($DCAmp.TBI(Settings)) { toolbar -az1 W.Settings "Settings" $DC.Imgs($+(Settings-,%i,.ico)) "/DCAmp" }
    if ($DCAmp.TBI(Winamp)) {
      if ($isfile($qt($DCR(Settings,Path)))) { toolbar -az1 Winamp "Run Winamp" $DC.Imgs(Winamp.ico) "/DCAmp.Run" }
      else { toolbar -az1 NoWinamp "Set Winamp's Executable File..." $DC.Imgs(NoWinamp.ico) "/DCAmp.SetPath" }
    }
    toolbar -is Winampsep
  }
}

alias DCAmp.Logo { return $+($chr(15),[dC wC],$chr(15)) }
alias DCAmp.Msg {
  var %def = Winamp plays <u>-=-<u> <b><Song><b> <u>-=-<u> (<Len1> - <Kbps>Kbps - <kHz>kHz - <Chnl>)
  if ($1 == Def) { return %def }
  else { return $iif($DCR(Settings,Msg) == $null,%def,$v1) }
}
alias DCAmp.Check {
  set %DCAmp.New $dll($Mp3mIRC,MP3Song,3)
  if ($DCR(Settings,Status) == 1) { DCMp3 }
}

alias -l ReplaceCodes { return $replace($1-,<c>,$chr(3),<b>,$chr(2),<u>,$chr(31),<r>,$chr(22),<o>,$chr(15)) }
alias DCMp3 {
  if ($dll($Mp3mIRC,WinampStatus,3) == 0) || (%DCAmp.Old == %DCAmp.New) return
  if (%DCAmp.Old == $null) && ($dll($Mp3mIRC,MP3Song,3) != $null) { set %DCAmp.Old $dll($Mp3mIRC,MP3Song,3) }
  if ($dll($Mp3mIRC,WinampStatus,3) == 1) && ($dll($Mp3mIRC,MP3Song,3) != $null) {
    set %DCAmp.Old $dll($Mp3mIRC,MP3Song,3)
    var %Mp3.T = $dll($Mp3mIRC,MP3Song,3)
    var %Mp3.L1 = $dll($Mp3mIRC,MP3Lenght,3)
    var %Mp3.L2 = $replace($duration($dll($Swamp,WinAmpGet,TRACKTIME)),hrs,h,hr,h,mins,m,secs,s,sec,s)
    var %Mp3.B = $iif($dll($Swamp,WinAmpGet,BITRATE) == 0,N/A,$v1)
    var %Mp3.C = $iif($dll($Swamp,WinAmpGet,CHANNELS) == 2,Stereo,Mono)
    var %Mp3.S = $dll($Swamp,WinAmpGet,SAMPLERATE)
    if (%Mp3.S == STREAM) { %Mp3.S = Stream }
    elseif (%Mp3.S == 0) { %Mp3.S = N/A }
    elseif (%Mp3.S == 22) { %Mp3.S = 22.05 }
    elseif (%Mp3.S == 44) { %Mp3.S = 44.1 }
    var %Mp3.Go = $ReplaceCodes($replace($DCAmp.Msg,<Song>,%Mp3.T,<Len1>,%Mp3.L1,<Len2>,%Mp3.L2,<Kbps>,%Mp3.B,<kHz>,%Mp3.S,<Chnl>,%Mp3.C)) $DCAmp.Logo
    var %method = $DCR(Settings,Method),%target = $DCR(Settings,Target)
    if (%method == 3) {
      var %s = $false
      if ($left($active,1) == @) || ($active !ischan) { %s = $true }
      echo $color(info) $iif(%s,-stg,-atg) %Mp3.Go
    }
    if ($istok(1 2,%method,32)) {
      if (%target == 1) { scon -at1 $iif(%method == 1,ame,amsg) %Mp3.Go }
      elseif (%target == 2) {
        if ($active ischan) { $iif(%method == 1,me,say) %Mp3.Go }
        else { echo $color(info) -stg %Mp3.Go }
      }
      elseif (%target == 3) {
        var %chans = $DCR(Settings,Channels)
        if ($numtok(%chans,32) > 0) {
          var %x = 1,%y = 0,%c = $iif(%method == 1,describe,msg)
          while ($gettok(%chans,%x,32)) {
            tokenize 64 $v1
            if ($2 == $null) { scon -at1 $!iif($me ison $1, %c $1 %Mp3.Go , noop) }
            else { scon -at1 $!iif($me ison $1 && $!network == $2 , %c $1 %Mp3.Go , noop) }
            inc %x
          }
        }
      }
    }
  }
  DCAmp.DF
}

alias DCAmp.DF { dll -u $Mp3mIRC | dll -u $Swamp }
alias DCAmp.Start {
  if ($DCR(Settings,Status) == 1) { .timerDCAmp 0 1 DCAmp.Check }
  if ($DCR(Settings,TB) == 1) { DCAmp.TB }
}

on *:Start:{ DCAmp.Start }
on *:Active:*:{ DCAmp.TB }
on *:Load:{
  echo 2 -agt * DCAmp v1.1 successfully loaded.
  DCAmp.Start
  .timer.ams 1 1 DCAmp
}

on *:Unload:{
  .timerDCAmp off
  unset %DCAmp*
  DCAmp.DF
  toolbar -r
}

menu Status,Channel,Menubar {
  -
  Winamp
  .<< Previous Track:DCAmp.Nav PrevTrack
  .l> Play:DCAmp.Nav Play
  .[][] Pause:DCAmp.Nav Pause
  .[] Stop:DCAmp.Nav Stop
  .>> Next Track:DCAmp.Nav NextTrack
  .-
  .Run Winamp:DCAmp.Run
  .-
  .Volume:DCVol
  .Settings:DCAmp
  .-
  .Unload?
  ..Are you sure?
  ...YES!:.unload -rs $qt($script)
  .-
  .About:DCAmp.About
  -
}

; EOF.